Funktion aus anderer Datei ausführen

[RTausD]

Hallo allerseits,

ich muss aus einer Datei eine Funktion ausführen, die in einer anderen Datei angelegt ist.

Grundsätzlich bekomme ich das mit nachfolgendem Befehl hin.

Code: Alles auswählen

Call Application.Run("'Testdatei.xlsm'!Testfunktion")


Wenn ich allerdings eine Variable übergeben möchte (s.u.) bricht das Makro mit Fehler ab.

Code: Alles auswählen

Call Application.Run("'Testdatei.xlsm'!Testfunktion(Testvariable)")


Der Fehlercode und die Fehlerbeschreibung lauten wie folgt:

Laufzeitfehler '1004':

Das Makro "Testdatei.xlsm'!Testfunktion(Testvariable)" kann nicht ausgeführt werden. Das Makro ist möglicherweise in dieser Arbeitsmappe nicht verfügbar, oder alle Makros wurden deaktiviert.

Die Makros sind natürlich nicht deaktiviert und die Funktion ist auch in der Datei enthalten.

Hat jemand eine Idee, was ich ihr tun könnte/muss?

VIELEN DANK im Voraus

Rolf

[slowboarder]

Hi
probiers mal nach dem Schema:

Code: Alles auswählen

Application.Run "Dateiname!Makroname", ÜbergabeParameter

Gruß Daniel

[d'r Bastler]

Moin Rolf,

klappt so:

Mappe Snd.xlsb / allg. Modul:

Code: Alles auswählen

Sub Sender()
Dim sText As String
sText = "Called by " & ThisWorkbook.Name
    Application.Run "Rec.xlsb!Receiver", sText
End Sub

Mappe Rec.xlsb / allg. Modul:

Code: Alles auswählen

Sub Receiver(sText As String)
    MsgBox sText,, ThisWorkbook.Name
End Sub

Hier der einfachheit halber im selben Verzeichnis. Beide Mappen müssen geöffnet sein.

Hier noch als Mappen:

Schöne Grüße

[snb]

Code: Alles auswählen

Sub M_snb()
   ' Makro in 'DieseArbeitsmappe'

   Application.Run "Testdatei.xlsb!DieseArbeitsmappe.M_snb"
   
   ' Makro in 'Sheet1'
   
   Application.Run "Testdatei.xlsb!Sheet1.M_snb"
   
   ' Makro im 'Macomodul'
   
   Application.Run "Testdatei.xlsb!M_snb"
   
   ' Makro im Click-event der ActiveX control 'CommandButton1"
   
   Workbooks("testdatei.xlsb").Sheets(1).CommandButton1 = True
End Sub

[RTausD]

Hallo Slowboarder und d'r Bastler,

VIELEN DANK für den Tipp.
So wird zumindest schon einmal die Variable an die aufgerufene Funktion übergeben.

Nur kommt leider nichts zurück.
In der Funktion wird die Variable bearbeitet/geändert.
Wenn die Funktion beendet wird, hat die Variable in dem aufrufenden Makro aber noch den Wert von vor dem Aufruf der Funktion.

Hat jemand eine Idee, woran das liegt bzw. was ich tun muss, damit das aufrufende Makro die geänderte Variable zurück erhält?

@snb
Ich verstehe leider nicht ganz, wo in Deinem Codebeispiel eine Variable übergeben wird.
Soweit ich es sehe, wird hier auch nur ein Makro aufgerufen.

Viele Grüße

Rolf

[slowboarder]

Hi
snb hat auch nicht auf deine Frage geantwortet, sondern dir allgemein gezeigt, wie du ein Makro aufrufen musst, wenn es sich in einer anderen Mappe befindet und das noch unterschieden nach den unterschiedlichen Modulen, in denenen das Makro stehen kann (DieseArbeitsmappe, Tabellenblattmodul, allgemeines Modul). Auf die von dir gestellte Frage mit der Variablenübergabe ist er nicht eingegangen.

zu deiner aktuellen Frage:

die Variablenübergabe bei Application.Run erfolgt immer "byVal" und niemals "byRef".
Dh du übergibst immer nur den Wert, aber nicht die Variable selbst. Eine Veränderung der übergebenen Variablen ist somit nicht möglich.
Wenn du ein Ergebnis benötigst, dann geht das nur so, dass du das Makro als Funktion schreibst und den Rückgabewert nutzt.

also:

Code: Alles auswählen

Function XXX(Eingabewert) as ???
...
XXX = Rückgabewert
End Function

und dann in der anderen Mappe:

Code: Alles auswählen

x = Application.Run("Dateiname!XXX", Übergabeparameter)

damit erhält x den Rückgabewert aus der Funktion XXX in der anderen Mappe.

Gruß Daniel

[d'r Bastler]

Moin Rolf,

Daniels Vorschlag umgesetzt:

Mappe Snd.xlsb / Allg. Modul

Code: Alles auswählen

Option explicit

Sub Sender()
Dim sText As String
sText = "Called by " & ThisWorkbook.Name
    Application.Run "Rec.xlsb!Receiver", sText
End Sub

Sub Result(iVocals As Integer)
MsgBox "Der Text enthält " & iVocals & " Vokale", , ThisWorkbook.Name
End Sub

Mappe Rec.xlsb / Allg. Modul

Code: Alles auswählen

Option Explicit

Sub Receiver(sText As String)
    MsgBox sText, , ThisWorkbook.Name
    Vocals sText
End Sub

Function Vocals(sText As String)
Dim i As Integer, iVocals As Integer
For i = 1 To Len(sText)
        Select Case Mid(sText, i, 1)
            Case "a", "e", "i", "o", "u", "y"
                iVocals = iVocals + 1
        End Select
Next i
Application.Run "Snd.xlsb!Result", iVocals
End Function


Die Function in Rec.xlsb kann man sicher auch ohne Umweg über die Sub ansprechen und ist natürliche funktional Pillepalle. Brauchte nur einen Rückgabewert
Danke Daniel! Wieder was gelernt ...

Grüße

Nachtrag, sorry! hatte das "y" vergessen ...

[DerHoepp]

Moinsen,

noch einfacher finde ich den direkten Aufruf von Public-Membern der ohnehin vorhandenen Objekte. Das Codebehind eines Workbook-Objekts verhält sich wie eine Klassendefinition. Ein Public-Member darin lässt sich also einfach mit einem Nachfolgenden Punkt aufrufen:

Code: Alles auswählen

Option Explicit
'erste Arbeitsmappe, ThisWorkbook
Public Function getValue(parameter as Variant) As Boolean
   getValue = True
End Function

'Aufrufende Mappe
Option Explicit
Sub Testen ()
   With Workbooks.Open("ErsteArbeitsmappe.xlsm")
      Debug.Print .getValue("Haus")
      .Close False
   End With
End Sub

Viele Grüße
derHöpp

[snb]

Ein Public-Member darin lässt sich also einfach mit einem Nachfolgenden Punkt aufrufen:

Stimmt ganz genau.
Weil es grundsätzlich ein Private Object ist (darum der Punkt) läuft es auch ohne 'Public'.

[slowboarder]

Moinsen,

noch einfacher finde ich den direkten Aufruf von Public-Membern der ohnehin vorhandenen Objekte. Das Codebehind eines Workbook-Objekts verhält sich wie eine Klassendefinition. Ein Public-Member darin lässt sich also einfach mit einem Nachfolgenden Punkt aufrufen:

wenn du schreiben würdest: Erstelle die Funktion nicht in einem allgemeinen Modul sondern im Modul "DieseArbeitsmappe", dann kannst du sie aus einer anderen Mappe heraus aufrufen", dann würde man auch verstehen was du meinst.

bei der Methode funktioniert auch die die Variablenübergabe "byRef".

Gruß Daniel

[snb]

behind eines Workbook-Objekts

Wer richtig lesen kann ist im Vorteil.

[d'r Bastler]

wer lesen kann ...

Und wer gleich verständlich erklärt ist noch besser.
Danke Daniel für die Übersetzung!

Grüße

[DerHoepp]

Moin,

@Daniel du hast recht, manchmal formuliere ich zu kompliziert und ich komme aus der objektorientierten Sichtweise nicht mehr heraus.

Weil es grundsätzlich ein Private Object ist (darum der Punkt) läuft es auch ohne 'Public'.

Ich hab es jetzt nicht ausprobiert, aber es würde mich wundern, wenn sich Private-Member eines Objektes sich aufrufen ließen. Kann es sein, dass du meinst, dass alle Properties, Functions und Subs eines Codemoduls standardmäßig Public sind?

Viele Grüße
derHöpp

[slowboarder]

"Public" ist default, dh es wird "Public" angenommen, wenn keine expliziten Angaben gemacht werden.
"Private" Subs oder Functions können nur von Subs oder Functions verwendet werden, welche sich im selben Modul befinden.
Gruß Daniel

[RTausD]

Hallo allerseits,

VIELEN DANK für Euere Hinweise.

Für meine Zwecke war die Lösung von Slowboarder das Einfachste.

Grüße

Rolf