WENN UND ODER mit mehreren wahren Bedingungen

Moderator: ModerationP

WENN UND ODER mit mehreren wahren Bedingungen

Beitragvon hillo » 28. Okt 2021, 12:17

Hallo Ihr Lieben,

ich habe folgendes Problem, dass ich versuche so gut wie möglich zu beschreiben:

Für eine Mitgliederdatei im Verein, möchte ich die Briefanrede (Spalte H) für einzelne Personen vorgeben.

Die Mitglieder im Verein sind unterschiedlichen Geschlechts und haben einen unterschiedlichen Status im Verein.

Das Geschlecht ist in Spalte I eingetragen und kann

[*]m
[*]w
[*]d
[*]unbekannt

sein.

Bei der Briefanrede soll es die folgenden Möglichkeiten geben:

[*]m = Lieber oder Sehr geehrter
[*]w = Liebe oder Sehr geehrte
[*]d/unbekannt = Liebe*r oder Sehr geehrte*r

Weiterhin haben die einzelnen Mitglieder einen unterschiedlichen Status im Verein. Sie können "Aktive" (BS), "Alumni" (BM) oder "Andere" Mitglieder sein. Diese sind in der jeweiligen Spalte mit Nullen und Einsen eingetragen.

In meiner Formel soll also ausgedrückt werden:

Wenn das Geschlecht "w" ist UND der Status "Aktive=1" ODER "Alumni=1", dann soll die Briefanrede "Liebe" sein.
Wenn das Geschlecht "m" ist UND der Status "Aktive=1" ODER "Alumni=1", dann soll die Briefanrede "Lieber" sein.
Wenn das Geschlecht "d/unbekannt" ist UND der Status "Aktive=1" ODER "Alumni=1", dann soll die Briefanrede "Liebe*r" sein.

Wenn das Geschlecht "w" ist UND der Status "Aktive=0" UND "Alumni=0", dann soll die Briefanrede "Sehr geehrte" sein.
Wenn das Geschlecht "m" ist UND der Status "Aktive=0" UND "Alumni=0", dann soll die Briefanrede "Sehr geehrter" sein.
Wenn das Geschlecht "d/unbekannt" ist UND der Status "Aktive=0" UND "Alumni=0", dann soll die Briefanrede "Sehr geehrte*r" sein.

Gibt es eine kombinierte WENN UND ODER Formel mit der ich da weiter kommen könnte oder ist das nicht darstellbar?

Liebe Grüße
hillo
 

Re: WENN UND ODER mit mehreren wahren Bedingungen

Beitragvon steve1da » 28. Okt 2021, 12:27

Hola,
so?
Code: Alles auswählen
=WENN(J2+K2>0;"Liebe"&WENN(I2="m";"r";WENN(ODER(I2="unbekannt";I2="d");"*r";""));WENN(J2+K2=0;"Sehr geehrte"&WENN(I2="m";"r";WENN(ODER(I2="unbekannt";I2="d");"*r";""))))
Gruß,
steve1da
Benutzeravatar
steve1da
Moderator
 
Beiträge: 31692
Registriert: 24. Sep 2003, 10:54

Re: WENN UND ODER mit mehreren wahren Bedingungen

Beitragvon HKindler » 28. Okt 2021, 12:41

Hi,

mein Vorschlag:
Code: Alles auswählen
Tabellenblattname: Tabelle1
┌———┬———————┬—————————┬———————┬———┬———┬———————————————————————————————┐
│   │   A   │    B    │   C   │ D │ E │               F               │ by Rₐⁿgₑ²ᵀₑˣT
├———┼———————┼—————————┼———————┼———┼———┼———————————————————————————————┤
│ 1 │Name   │Vorname  │m/w/d/?│BS │BM │Anrede                         │
├———┼———————┼—————————┼———————┼———┼———┼———————————————————————————————┤
│ 2 │Name 1 │Vorname 1│m      │  0│  0│Sehr geehrter Herr Name 1      │
├———┼———————┼—————————┼———————┼———┼———┼———————————————————————————————┤
│ 3 │Name 2 │Vorname 2│w      │  0│  0│Sehr geehrte Frau Name 2       │
├———┼———————┼—————————┼———————┼———┼———┼———————————————————————————————┤
│ 4 │Name 3 │Vorname 3│d      │  0│  0│Sehr geehrte*r Frau/Herr Name 3│
├———┼———————┼—————————┼———————┼———┼———┼———————————————————————————————┤
│ 5 │Name 4 │Vorname 4│m      │  1│  0│Lieber Vorname 4               │
├———┼———————┼—————————┼———————┼———┼———┼———————————————————————————————┤
│ 6 │Name 5 │Vorname 5│w      │  1│  0│Liebe Vorname 5                │
├———┼———————┼—————————┼———————┼———┼———┼———————————————————————————————┤
│ 7 │Name 6 │Vorname 6│d      │  1│  0│Liebe*r Vorname 6              │
├———┼———————┼—————————┼———————┼———┼———┼———————————————————————————————┤
│ 8 │Name 7 │Vorname 7│m      │  0│  1│Lieber Vorname 7               │
├———┼———————┼—————————┼———————┼———┼———┼———————————————————————————————┤
│ 9 │Name 8 │Vorname 8│w      │  0│  1│Liebe Vorname 8                │
├———┼———————┼—————————┼———————┼———┼———┼———————————————————————————————┤
│ 10│Name 9 │Vorname 9│d      │  0│  1│Liebe*r Vorname 9              │
└———┴———————┴—————————┴———————┴———┴———┴———————————————————————————————┘
Rₐⁿgₑ²ᵀₑˣT hat geschrieben:Verwendete Formeln:
F2: =WENN((C2="m");WENN(D2+E2;"Lieber "&B2;"Sehr geehrter Herr "&A2);WENN(C2="w";WENN(D2+E2;"Liebe "&B2;"Sehr geehrte Frau "&A2);WENN(D2+E2;"Liebe*r "&B2;"Sehr geehrte*r Frau/Herr "&A2)))
©2017 Sabina Anajiwna Yermakova-Bièla
Gruß,
Helmut

----------------------------
Windows 10 Enterprise (64 Bit) / Office 365 ProPlus (32 Bit)
Benutzeravatar
HKindler
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 6463
Registriert: 04. Jul 2013, 09:02
Wohnort: Schwarzwald

Re: WENN UND ODER mit mehreren wahren Bedingungen

Beitragvon HKindler » 28. Okt 2021, 13:31

Noch ein Vorschlag:
Code: Alles auswählen
Tabellenblattname: Tabelle2 (4)
┌———┬———————┬—————————┬————————┬———┬———┬———————————————————————————————┬—————┬—————┬—————————————————————————┬————————┐
│   │   A   │    B    │   C    │ D │ E │               F               │  G  │  H  │            I            │   J    │ by Rₐⁿgₑ²ᵀₑˣT
├———┼———————┼—————————┼————————┼———┼———┼———————————————————————————————┼—————┼—————┼—————————————————————————┼————————┤
│ 1 │Name   │Vorname  │m/w/d/? │BS │BM │Anrede                         │     │mwd  │nicht aktiv              │aktiv   │
├———┼———————┼—————————┼————————┼———┼———┼———————————————————————————————┼—————┼—————┼—————————————————————————┼————————┤
│ 2 │Name 1 │Vorname 1│m       │  0│  0│Sehr geerhter Herr Name 1      │     │     │Sehr geehrte*r Frau/Herr │Liebe*r │
├———┼———————┼—————————┼————————┼———┼———┼———————————————————————————————┼—————┼—————┼—————————————————————————┼————————┤
│ 3 │Name 2 │Vorname 2│w       │  0│  0│Sehr geehrte Frau Name 2       │     │m    │Sehr geerhter Herr       │Lieber  │
├———┼———————┼—————————┼————————┼———┼———┼———————————————————————————————┼—————┼—————┼—————————————————————————┼————————┤
│ 4 │Name 3 │Vorname 3│d       │  0│  0│Sehr geehrte*r Frau/Herr Name 3│     │w    │Sehr geehrte Frau        │Liebe   │
├———┼———————┼—————————┼————————┼———┼———┼———————————————————————————————┼—————┼—————┼—————————————————————————┼————————┤
│ 5 │Name 4 │Vorname 4│m       │  1│  0│Lieber Vorname 4               │     │     │                         │        │
├———┼———————┼—————————┼————————┼———┼———┼———————————————————————————————┼—————┼—————┼—————————————————————————┼————————┤
│ 6 │Name 5 │Vorname 5│w       │  1│  0│Liebe Vorname 5                │     │     │                         │        │
├———┼———————┼—————————┼————————┼———┼———┼———————————————————————————————┼—————┼—————┼—————————————————————————┼————————┤
│ 7 │Name 6 │Vorname 6│?       │  1│  0│Liebe*r Vorname 6              │     │     │                         │        │
├———┼———————┼—————————┼————————┼———┼———┼———————————————————————————————┼—————┼—————┼—————————————————————————┼————————┤
│ 8 │Name 7 │Vorname 7│m       │  0│  1│Lieber Vorname 7               │     │     │                         │        │
├———┼———————┼—————————┼————————┼———┼———┼———————————————————————————————┼—————┼—————┼—————————————————————————┼————————┤
│ 9 │Name 8 │Vorname 8│w       │  0│  1│Liebe Vorname 8                │     │     │                         │        │
├———┼———————┼—————————┼————————┼———┼———┼———————————————————————————————┼—————┼—————┼—————————————————————————┼————————┤
│ 10│Name 9 │Vorname 9│d       │  0│  1│Liebe*r Vorname 9              │     │     │                         │        │
└———┴———————┴—————————┴————————┴———┴———┴———————————————————————————————┴—————┴—————┴—————————————————————————┴————————┘
Rₐⁿgₑ²ᵀₑˣT hat geschrieben:Verwendete Formeln:
F2: =INDEX($I$2:$J$4;VERGLEICH(C2;$H$2:$H$4;1);ODER(D2;E2)+1)&INDEX(A2:B2;ODER(D2;E2)+1)
oder auch bei ganz neuem Excel
F2: =LET(x;ODER(D2;E2)+1;INDEX($I$2:$J$4;VERGLEICH(C2;$H$2:$H$4;1);x)&INDEX(A2:B2;x)
©2017 Sabina Anajiwna Yermakova-Bièla

Man beachte in der rechten Tabelle, dass am Ende der Texte ein Leerzeichen steht, ebenso steht in H2 ein Leerzeichen.
Gruß,
Helmut

----------------------------
Windows 10 Enterprise (64 Bit) / Office 365 ProPlus (32 Bit)
Benutzeravatar
HKindler
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 6463
Registriert: 04. Jul 2013, 09:02
Wohnort: Schwarzwald

Re: WENN UND ODER mit mehreren wahren Bedingungen

Beitragvon slowboarder » 28. Okt 2021, 14:06

Hi

In diesem Fall gehts einfach so:

Code: Alles auswählen
=Wenn(BS2+BM2=0;"Sehr geehrte";"Liebe")&Wenn(I2="w";"";Wenn(I2="m";"r";"*r"))


Lassen sich die verschiedenen Anreden nicht so leicht kombinieren und man muss jede einzeln aufführen; dann ggf so:

Code: Alles auswählen
=Wahl(Wennfehler(Vergleich(I2;{"w";"m"};0);3)+Max(BS2;BM2)*3;"Sehr geehrte";"Sehr geehrter";"Sehr geehrte*r";"Liebe";"Lieber";"Liebe*r")


Gruß Daniel
slowboarder
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 28574
Registriert: 18. Apr 2009, 13:33

Re: WENN UND ODER mit mehreren wahren Bedingungen

Beitragvon hillo » 28. Okt 2021, 14:49

Vielen, vielen Dank für die Antworten!! Ich habe es direkt mit der ersten Antwort geschafft.

Die Formel sieht dann so aus bei mir:

=WENN(BM3+BS3>0;"Liebe"&WENN(I3="m";"r";WENN(ODER(I3="unbekannt";I3="d");"*r";""));WENN(BM3+BS3=0;"Sehr geehrte"&WENN(I3="m";"r";WENN(ODER(I3="unbekannt";I3="d");"*r";""))))
hillo
 


Zurück zu Excel Forum (provisorisch)

Wer ist online?

Mitglieder in diesem Forum: Bing [Bot], Der Ratlose, Kuwe und 28 Gäste