Win-Seriennummer aus externer HD auslesen

Alle anderen Themen ...

Moderator: ModerationP

Win-Seriennummer aus externer HD auslesen

Beitragvon RaiSta » 06. Nov 2016, 19:52

Hallo Ihr Wissenden

Der Rechner einer Bekannten ist unrettbar abgestürzt, alle Versuche der Wiederbelebung sind soweit gescheitert inklusive Reparaturinstallation. Nun boote ich den Rechner von einem USB-Stick und möchte die (Win-10-) Seriennummer auslesen, um sie für eine Neuinstallation zu nutzen. Wie kann ich das machen, quasi von einer 'externen' HD die Seriennummer zu ermitteln?

Danke für Eure Tipps,
RaiSta
Wenn Sokrates als intelligent gilt, weil er "ich weiß, daß ich nichts weiß" erkannte, muß ich ein Genie sein.
RaiSta
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 215
Registriert: 02. Jul 2013, 01:07
Wohnort: Im Mittelpunkt - der EU

Re: Win-Seriennummer aus externer HD auslesen

Beitragvon < Peter > » 06. Nov 2016, 20:03

Hallo,

probier es mal mit Magical Jelly Bean: https://www.heise.de/download/product/m ... nder-36531
Gruß
Peter
Benutzeravatar
< Peter >
Moderator
 
Beiträge: 66040
Registriert: 04. Sep 2004, 10:19
Wohnort: Das schönste Land in Deutschlands Gaun

Re: Win-Seriennummer aus externer HD auslesen

Beitragvon Der Steuerfuzzi » 07. Nov 2016, 10:31

Hallo,

war es nicht so, dass man für die Aktivierung von Win10 keine Seriennummer mehr benötigt, da diese entweder bereits im BIOS hinterlegt ist oder die Aktivierung anhand der Hardware schon bei der Erstinstalltion bereits bei MS hinterlegt ist?

Eine Online-Verbindung vorausgesetzt, sollte Win 10 IMHO automatisch aktiviert/aktivierbar sein.
Gruß
Michael
Der Steuerfuzzi
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 3123
Registriert: 25. Mär 2013, 13:28

Re: Win-Seriennummer aus externer HD auslesen

Beitragvon RaiSta » 08. Jan 2017, 22:42

Vielen Dank,
Ihr Lieben für Eure Antworten. Ich habe auf die beschriebenen Arten Seriennummern auslesen, aber aufgrund diverser anderer Schwierigkeiten noch nicht wieder einsetzen können. Um aber nicht als undankbarer Fragensteller zu gelten, hiermit schon mal meinen Dank!

Gruß
RaiSta
Wenn Sokrates als intelligent gilt, weil er "ich weiß, daß ich nichts weiß" erkannte, muß ich ein Genie sein.
RaiSta
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 215
Registriert: 02. Jul 2013, 01:07
Wohnort: Im Mittelpunkt - der EU

Re: Win-Seriennummer aus externer HD auslesen

Beitragvon ComputerVersteher » 12. Jan 2017, 07:18

Hi RaiSta,

hast Du den PC gewechselt? Normalerweise hängt die Aktivierung an der Hardware (zumindest beim Ugrade von Win 7/8).

Hattest Du ein verknüpftes Mircosoft-Konto, dort wird die Lizenz gespeichert.

Sonst probier mal diesen Code

Code: Alles auswählen
Option Explicit 
 
 Const HKEY_LOCAL_MACHINE = &H80000002
 
Dim objshell,path,DigitalID, Result, oReg , WshShell, binary, i, file
Dim strValue, strComputer,RegRoot , iResult1
Set objshell = CreateObject("WScript.Shell")
Set WshShell = CreateObject("WScript.shell")
strComputer = "."
file = "d:\SOFTWARE"
'Set registry key path
Path = "TEMPHIVE\Microsoft\Windows NT\CurrentVersion\"
'Registry key value
RegRoot = "HKLM\TEMPHIVE"
iResult1 = WshShell.Run("reg.exe load " & RegRoot & " " & chr(34) & file & chr(34), 0, True)
    If iResult1 <> 0 Then
     WScript.Echo("***   An error occurred while loading HKCU: " )
    Else
     WScript.Echo("HKCU loaded: " )
    End If
Set oReg = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & _
    strComputer & "\root\default:StdRegProv")

   
Dim ProductName,ProductID,ProductKey,ProductData

oReg.GetStringValue HKEY_LOCAL_MACHINE,Path ,"ProductName",strValue
ProductName = "Product Name: " & strValue
oReg.GetStringValue HKEY_LOCAL_MACHINE,Path ,"ProductID",strValue
ProductID = "Product ID: " & strValue
oReg.GetBinaryValue HKEY_LOCAL_MACHINE,Path,"DigitalProductId",strValue
For i = lBound(strValue) to uBound(strValue)
   binary = binary & strValue(i)
Next

If binary <> "000" then
   ProductKey = "Installed Key: " & ConvertToKey(strValue)
Else
   WScript.Echo("Kein Key gefunden!")
End If
ProductData = ProductName  & vbNewLine & ProductID  & vbNewLine & ProductKey
'Show messbox if save to a file 
If vbYes = MsgBox(ProductData  & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then
   Save ProductData 
End If
iResult1 = WshShell.Run("reg.exe unload " & RegRoot,0, True) 'Unload HKCU from HKLM
    If iResult1 <> 0 Then
     WScript.Echo("*** An error occurred while unloading HKCU: ")
    Else
     WScript.Echo("   unloaded: " )
    End If
 
 
'Convert binary to chars
Function ConvertToKey(Key)
    Const KeyOffset = 52
    Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
    'Check if OS is Windows 8
    isWin8 = (Key(66) \ 6) And 1
    Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
    i = 24
    Maps = "BCDFGHJKMPQRTVWXY2346789"
    Do
           Current= 0
        j = 14
        Do
           Current = Current* 256
           Current = Key(j + KeyOffset) + Current
           Key(j + KeyOffset) = (Current \ 24)
           Current=Current Mod 24
            j = j -1
        Loop While j >= 0
        i = i -1
        KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
        Last = Current
    Loop While i >= 0 
     
    If (isWin8 = 1) Then
        keypart1 = Mid(KeyOutput, 2, Last)
        insert = "N"
        KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
        If Last = 0 Then KeyOutput = insert & KeyOutput
    End If     
     
 
    ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)
   
     
End Function
'Save data to a file
Function Save(Data)
    Dim fso, fName, txt,objshell,UserName
    Set objshell = CreateObject("wscript.shell")
    'Get current user name 
    UserName = objshell.ExpandEnvironmentStrings("%UserName%") 
    'Create a text file on desktop 
    fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt"
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set txt = fso.CreateTextFile(fName)
    txt.Writeline Data
    txt.Close
End Function


Das ganze als "GetKey.vbs" in einer Textdatei speichern (Endung .vbs) und in der Variablen file den Pfad zum Regfile(X:\Windows\system32\config\SOFTWARE(ohne Endung)) anpassen , wobei X das Laufwerk mit der alten Windows Installation ist. Dann über Shell "GetKey.vbs" starten.

Gruß CV
"Am Anfang wurde das Universum erschaffen. Das machte viele Leute sehr wütend und wurde allenthalben als Schritt in die falsche Richtung angesehen."
Benutzeravatar
ComputerVersteher
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 158
Registriert: 23. Jul 2016, 18:17

Re: Win-Seriennummer aus externer HD auslesen

Beitragvon RaiSta » 17. Jan 2017, 17:49

ComputerVersteher hat geschrieben:Hi RaiSta,

hast Du den PC gewechselt?

[...]

Code: Alles auswählen
Option Explicit 
 
 Const HKEY_LOCAL_MACHINE = &H80000002
 
Dim objshell,path,DigitalID, Result, oReg , WshShell, binary, i, file
Dim strValue, strComputer,RegRoot , iResult1
Set objshell = CreateObject("WScript.Shell")
[...]
 


Das ganze als "GetKey.vbs" in einer Textdatei speichern (Endung .vbs) und in der Variablen file den Pfad zum Regfile(X:\Windows\system32\config\SOFTWARE(ohne Endung)) anpassen , wobei X das Laufwerk mit der alten Windows Installation ist. Dann über Shell "GetKey.vbs" starten.

Gruß CV

Vielen Dank für den Tipp,
jedoch waren die genannten 'Probleme' völlig anderer Natur, so daß ich schlicht zeitlich nicht dazu kam, das Thema mit der nötigen Energie zu verfolgen.
Sobald ich dazu komme, sehe ich mal, wie es tut.

Gruß
RaiSta
Wenn Sokrates als intelligent gilt, weil er "ich weiß, daß ich nichts weiß" erkannte, muß ich ein Genie sein.
RaiSta
Im Profil kannst Du frei den Rang ändern
 
Beiträge: 215
Registriert: 02. Jul 2013, 01:07
Wohnort: Im Mittelpunkt - der EU


Zurück zu Offtopic (provisorisch)

Wer ist online?

Mitglieder in diesem Forum: 0 Mitglieder und 2 Gäste