Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Anzeige in Verteilerlisten ändern
zurück: Fax-Nummern beim Verfassen einer Mail ausblenden weiter: Defektes Outlook-Profil reparieren Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Dieses Thema ist gesperrt, du kannst keine Beiträge editieren oder beantworten.     Status: Tutorial Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
Peter Marchert
Im Profil kannst Du frei den Rang ändern


Verfasst am:
07. Jun 2006, 18:02
Rufname:

Anzeige in Verteilerlisten ändern - Anzeige in Verteilerlisten ändern

Nach oben
       

Hallo,

wenn ein neuer Kontakt angelegt wird, so wird nach der Eingabe der E-Mailadresse der "Anzeigename" (Feld "Anzeigen als", bitte nicht verwechseln mit dem Feld "Speichern unter") in der Reihenfolge "Vor-/Nachname (mail@server.de)" angezeigt.

In dieser Reihenfolge werden auch die Mitglieder von Verteilerlisten angezeigt, was häufig nicht gewünscht ist. Mit dem nachfolgenden Programm kann die Reihenfolge des Anzeigenamens in "Nach-/Vorname" geändert werden. Zur Verwendung des Codes bitte die Hinweise im Code beachten.

Wichtig: Wenn 2 oder 3 E-Mailadressen in einem Kontakt vorhanden sind, so wird für alle als Anzeigename die Kombination aus Vor- und Nachname verwendet!

Code:
Option Explicit
Sub ChangeToFirstName()
    ChangeDisplayName True
End Sub
Sub ChangeToLastName()
    ChangeDisplayName False
End Sub
Sub ChangeDisplayName(Optional blnFirstName As Boolean)

    '==========================================================================================
    ' Diese Funktion ist nützlich für das Erstellen von Verteilerlisten. Beim Anlegen eines
    ' Kontakts wird der Anzeigename der E-Mailadresse immer mit "Vor-/Nachname" angelegt. In
    ' Verteilerlisten möchte man meistens jedoch die Reihenfolge "Nach-/Vorname" haben.
    ' Mit Hilfe dieses Programms kann die Reihenfolge umgedreht werden.
    '==========================================================================================
    ' So kommt der Code ins Outlook:
    ' - zunächst bitte die Sicherheitseinstellungen ändern: "Extras", "Makro", "Sicherheit". Hier
    '   die Sicherheitsstufe "Mittel" wählen.
    ' - "ALT+F11" (VBA-Umgebung aufrufen)
    ' - "STRG+R" (Projektexplorer aktivieren)
    ' - Im Projektexplorer das "Projekt1" erweitern (Doppelklick oder Klick auf das "+")
    ' - "Microsoft Office Outlook Objekte" erweitern
    ' - "DieseOutlookSitzung" doppelklicken
    ' - Im rechten Fenster dann den gesamten Code hineinkopieren
    ' - Speichern und VBA-Umgebung schliessen
    '-----------------------------------------------------------------------------------------
    ' Um den Code mit Schaltflächen aufzurufen, bitte wie folgt vorgehen:
    ' - rechter Mausklick auf eine freie Stelle einer Symbolleiste
    ' - "Anpassen..."
    ' - "Befehle"
    ' - "Makros"
    ' - in der rechten Fensterhälfte das Makro "Projekt1.ChangeToFirstName" bzw.
    '   "Projekt1.ChangeToLastName" anlklicken und auf eine gewünschte Stelle einer Symbolleiste
    '   ziehen und dort loslassen
    ' - mit einem Rechtsklick auf die neue Schaltfläche können noch Eigenschaften festgelegt
    '   werden
    ' - danach den Anpassen-Dialog wieder schliessen
    '==========================================================================================
    ' Das Programm stammt aus einem KB-Artikel von Microsoft und wurde von Peter Marchert ange-
    ' passt. Die Verwendung erfolgt auf eigene Gefahr.
    '==========================================================================================
   
    Dim objCurrentFolder        As MAPIFolder       ' Aktuller Ordner
    Dim objItems                As Items            ' Alle Kontakte im akutellen Ordner
    Dim objItem                 As Object           ' Einzelnes Element im Ordner
    Dim strOption               As String           ' Sortierreihenfolge
    Dim intIndex                As Integer          ' Schleifenzähler
   
    '-----------------------------------------------------------------------------------------
    ' Referenz auf den aktuellen Ordner setzen
    '-----------------------------------------------------------------------------------------
    Set objCurrentFolder = Application.ActiveExplorer.CurrentFolder
   
    '-----------------------------------------------------------------------------------------
    ' Meldung für Benutzer abhängig von der Reihenfolge
    '-----------------------------------------------------------------------------------------
    strOption = IIf(blnFirstName, "Vor-/Nachname", "Nach-/Vorname")
   
    '-----------------------------------------------------------------------------------------
    ' Aktueller Ordner vom Typ Kontakte?
    '-----------------------------------------------------------------------------------------
    If objCurrentFolder.DefaultItemType = olContactItem Then
       
        '-------------------------------------------------------------------------------------
        ' Hinweis an Benutzer anzeigen
        '-------------------------------------------------------------------------------------
        MsgBox "Der Anzeigename wird jetzt zu " & strOption & " geändert.", _
            vbInformation + vbOKCancel + vbDefaultButton2, "Anzeigenamen ändern"
       
        '-------------------------------------------------------------------------------------
        ' Referenz auf alle Kontakte im aktuellen Ordner setzen
        '-------------------------------------------------------------------------------------
        Set objItems = objCurrentFolder.Items
       
        '-------------------------------------------------------------------------------------
        ' Alle Kontakte bearbeiten
        '-------------------------------------------------------------------------------------
        For intIndex = 1 To objItems.Count
           
            '---------------------------------------------------------------------------------
            ' Referenz auf einzelnen Kontakt setzen
            '---------------------------------------------------------------------------------
            Set objItem = objItems.Item(intIndex)
           
            With objItem
           
                '-----------------------------------------------------------------------------
                ' Ist das Element ein Kontakt (keine Verteilerliste)?
                '-----------------------------------------------------------------------------
                If UCase(Left(.MessageClass, 11)) = "IPM.CONTACT" Then
                   
                    '-------------------------------------------------------------------------
                    ' Reihenfolge je nach Option ändern
                    '-------------------------------------------------------------------------
                    If blnFirstName Then
                       
                        '---------------------------------------------------------------------
                        ' Vor-/Nachname
                        '---------------------------------------------------------------------
                        If Trim(.FullName) <> "" Then
                            .Email1DisplayName = .FullName & " (" & .Email1Address & ")"
                            .Email2DisplayName = .FullName & " (" & .Email2Address & ")"
                            .Email3DisplayName = .FullName & " (" & .Email3Address & ")"
                        End If
                       
                    Else
                   
                        '---------------------------------------------------------------------
                        ' Nach-/Vorname
                        '---------------------------------------------------------------------
                        If Trim(.LastNameAndFirstName) <> "" Then
                            .Email1DisplayName = .LastNameAndFirstName & " (" & .Email1Address & ")"
                            .Email2DisplayName = .LastNameAndFirstName & " (" & .Email2Address & ")"
                            .Email3DisplayName = .LastNameAndFirstName & " (" & .Email3Address & ")"
                        End If
                   
                    End If
                   
                    '-------------------------------------------------------------------------
                    ' Änderung am Kontakt speichern
                    '-------------------------------------------------------------------------
                    .Save
                   
                End If
               
            End With
           
        Next
       
        '-------------------------------------------------------------------------------------
        ' Meldung an den Benutzer
        '-------------------------------------------------------------------------------------
        MsgBox "Vorgang ist beendet. Alle Kontakte im Ordner  """ & objCurrentFolder.Name & _
            """ sind jetzt nach " & strOption & "n sortiert", vbInformation + vbOKOnly, "Anzeigenamen ändern"
   
    Else
       
        '-------------------------------------------------------------------------------------
        ' Meldung, wenn kein Kontakteordner ausgewählt ist
        '-------------------------------------------------------------------------------------
        MsgBox "Das Ändern des Anzeigenamens funktioniert nur in Kontakteordnern.", _
            vbCritical + vbOKOnly, "Anzeigenamen ändern"
   
    End If

End Sub


Fragen und Anregungen dazu bitte im Outlook-Mail-Forum.

Gruß
Peter

_________________
Tipps, Tricks & Tools für
Microsoft® Office Outlook®


Zuletzt bearbeitet von Peter Marchert am 08. Jun 2006, 08:44, insgesamt 6-mal bearbeitet
Christi@n
Outlook-Moderator


Verfasst am:
07. Jun 2006, 22:28
Rufname:
Wohnort: Bamberg


AW: Anzeige in Verteilerlisten ändern - AW: Anzeige in Verteilerlisten ändern

Nach oben
       

{Dieser Beitrag nimmt das Thema aus den unbeantworteten Themen heraus}
_________________
Viele Grüße
Christian
Neues Thema eröffnen   Dieses Thema ist gesperrt, du kannst keine Beiträge editieren oder beantworten. Alle Zeiten sind
GMT + 1 Stunde

Diese Seite Freunden empfehlen

Seite 1 von 1
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Outlook Mail: Outlook Vista - Absender ändern 0 miladin 392 05. Jun 2009, 12:41
miladin Outlook Vista - Absender ändern
Keine neuen Beiträge Outlook Mail: Einheitliche Anzeige der Absender im E-Mail-Postfach 3 Gast009 1087 09. Apr 2009, 19:17
Christi@n Einheitliche Anzeige der Absender im E-Mail-Postfach
Keine neuen Beiträge Outlook Mail: Kann man die Kategorien für Vertraulichkeit ändern?? 2 Andi_Muc 2609 23. Okt 2008, 00:49
Christi@n Kann man die Kategorien für Vertraulichkeit ändern??
Keine neuen Beiträge Outlook Mail: Outlook 2007 - Änderunsdatum der mails ändern(wegen archiv.) 20 bybi 7680 15. Sep 2008, 08:29
abnonta Outlook 2007 - Änderunsdatum der mails ändern(wegen archiv.)
Keine neuen Beiträge Outlook Mail: HTML (Newsletter) anzeige Outlook 2003 2 wgei 2915 19. Aug 2008, 09:36
wgei2 HTML (Newsletter) anzeige Outlook 2003
Keine neuen Beiträge Outlook Mail: Mailformular ändern 3 thiman 486 20. Mai 2008, 07:08
Andreas.Fischer Mailformular ändern
Keine neuen Beiträge Outlook Mail: Schriftgröße im gesamten Outlook ändern? 0 Gast 2006 07. März 2008, 11:21
Gast Schriftgröße im gesamten Outlook ändern?
Keine neuen Beiträge Outlook Mail: Schriftfarbe von beantworteten E-Mail ändern 3 nimo 5851 05. Dez 2007, 14:12
Andreas.Fischer Schriftfarbe von beantworteten E-Mail ändern
Keine neuen Beiträge Outlook Mail: Exchange Server - wie Abesendername ändern? 1 Rettungswagen 1799 05. Jul 2007, 07:32
Andreas.Fischer Exchange Server - wie Abesendername ändern?
Keine neuen Beiträge Outlook Mail: Anzeige gelöschter IMAP-Nachricten stört 0 dopem 603 13. Dez 2006, 12:19
dopem Anzeige gelöschter IMAP-Nachricten stört
Keine neuen Beiträge Outlook Mail: Outlook, Kontaktfester Notizfeld Standardeinstellung ändern? 3 harold 2093 06. Nov 2006, 15:33
Andreas.Fischer Outlook, Kontaktfester Notizfeld Standardeinstellung ändern?
Keine neuen Beiträge Outlook Mail: Bei allen Konten (10) gleichzeitig Postausgangsserver ändern 1 Thomas-L 1189 01. Sep 2006, 15:20
kraemer Bei allen Konten (10) gleichzeitig Postausgangsserver ändern
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: Microsoft-Excel Diagramme