Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Button erst aktivieren wenn bestimmte felder gefüllt sind
Gehe zu Seite Zurück  1, 2
zurück: Befehlschaltfläche mit Hakenfeld kombinieren weiter: neues UF mit Abfrage -> richtiges Foto anzeigen Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Feedback Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
Willi Wipp
Moderator


Verfasst am:
13. Feb 2006, 14:22
Rufname:
Wohnort: Raum Wiesbaden

Re: Button erst aktivieren wenn bestimmte felder ... (IV) - Re: Button erst aktivieren wenn bestimmte felder ... (IV)

Nach oben
       

Hi ecmichi,

jetzt sorgst Du bei mir fuer Verwirrung Embarassed
Versuchen wir es mal mit der Komfort-Loesung Wink
Code:
Private Sub Verkehrsart_AfterUpdate()
    FnbButtonVisible
End Sub

Private Sub Tabelle_Anlegen_einer_Frachtanfrage_Kunden_AfterUpdate()
    FnbButtonVisible
End Sub

Private Sub Status_der_Frachtanfrage_AfterUpdate()
    FnbButtonVisible
End Sub

Private Sub Allgemeinangebot_AfterUpdate()
    FnbButtonVisible
End Sub

Private Sub Form_AfterUpdate()
    FnbButtonVisible
End Sub

Private Function FnbButtonVisible() As Boolean
    If Trim(Nz(Me!Verkehrsart, "")) = "" Or _
       Trim(Nz(Me![Tabelle Anlegen einer Frachtanfrage_Kunden], "")) = "" Or _
       Trim(Nz(Me![Status der Frachtanfrage], "")) = "" Or _
       Trim(Nz(Me!Allgemeinangebot, "")) = "" Then
        If Screen.ActiveControl.Name = "Diese Anfrage jetzt drucken" Then
            Me!EineAnderesSteuerelement.SetFocus
        End If
        Me![Diese Anfrage jetzt drucken].Visible = False
        FnbButtonVisible = False
      Else
        Me![Diese Anfrage jetzt drucken].Visible = True
        FnbButtonVisible = True
    End If
End Function

Private Sub Diese_Anfrage_jetzt_drucken_Click()
On Error GoTo Err_Diese_Anfrage_jetzt_drucken_Click
    Dim stDocName As String
    Dim sKrit As String
   
    If Not FnbButtonVisible Then Exit Sub
    stDocName = "Frachtanfrage direkt Druck aus Formular"
    sKrit = "[Laufende Nummer] = " & Me![Laufende Nummer]
    DoCmd.DoMenuItem acFormBar, acRecordsMenu, acSaveRecord, , acMenuVer70
    DoCmd.OpenReport stDocName, acNormal, , sKrit
    DoCmd.Close

Exit_Diese_Anfrage_jetzt_drucken_Click:
    Exit Sub
Err_Diese_Anfrage_jetzt_drucken_Click:
    MsgBox "Sie haben nicht alle Muss-Felder gefüllt"
    Resume Exit_Diese_Anfrage_jetzt_drucken_Click
End Sub
In der Funktion FnbButtonVisible habe ich die Funktion IsNull
durch Trim(Nz(... ersetzt. Da geht nur bei Feldern vom Datentyp Text.
Falls also eines der Felder einen anderen Datentyp hat, musst Du es dort wieder durch IsNull(... ersetzen.
Achte darauf das auch bei allen Steuerelementen und beim Formular fuer das Ereigniss
Nach Aktualisierung (AfterUpdate) der Eintrag [Ereignisprozedur] ([Event Procedure]) vorhanden ist.
Im Zweifelsfall setze auf alle Aufrufe der Funktion FnbButtonVisible eine Haltepunkt und teste ob er erreicht wird.

_________________
Eine kurze Rueckmeldung waere nett
SL Willi Wipp

(Anleitung fuer das Anhaengen von Dateien: Klicke links auf [www], Gaeste muessen sich dafuer anmelden)


Zuletzt bearbeitet von Willi Wipp am 15. Okt 2007, 15:47, insgesamt einmal bearbeitet
ecmichi
Schwaches Access;Fortgeschriten Word+Excel


Verfasst am:
13. Feb 2006, 14:37
Rufname:


AW: Button erst aktivieren wenn bestimmte felder gefüllt sin - AW: Button erst aktivieren wenn bestimmte felder gefüllt sin

Nach oben
       

Oh weh.... etz wird es langsam zu hoch ;)

hab das jetzt versucht wobei mir der Befehl TRim(NZ... vollkommen fremd war.

Kommt Fehler beim Kompilieren in der Zeile:

Private Function FnbButtonVisible() As Boolean

"Falsche Anzahl an Argumenten oder ungültige Zuweisung einer Eigenschaft"


Sollte ich besser aufgeben?
Willi Wipp
Moderator


Verfasst am:
13. Feb 2006, 14:40
Rufname:
Wohnort: Raum Wiesbaden

Re: Button erst aktivieren wenn bestimmte felder ... (V) - Re: Button erst aktivieren wenn bestimmte felder ... (V)

Nach oben
       

Hi ecmichi,

ist doch eigentlich gar nicht sooo schwer:
Man baut eine Funktion die prueft ob die Befehlsschaltflaeche sichtbar sein soll.
Diese wird dann bei den entsprechenden Ereignissen, bei dennen geprueft werden soll, aufgerufen.
Also nicht die Flinte ins Korn werfen Wink

Die Loesung mit Trim(Nz(... soll nur eventuell vorhandene Felder die nur Leerzeichen enthalten abfangen.

Welche Fehlermeldung kommt denn?

_________________
Eine kurze Rueckmeldung waere nett
SL Willi Wipp

(Anleitung fuer das Anhaengen von Dateien: Klicke links auf [www], Gaeste muessen sich dafuer anmelden)


Zuletzt bearbeitet von Willi Wipp am 26. Jun 2006, 15:47, insgesamt 2-mal bearbeitet
ecmichi
Schwaches Access;Fortgeschriten Word+Excel


Verfasst am:
13. Feb 2006, 15:14
Rufname:

AW: Button erst aktivieren wenn bestimmte felder gefüllt sin - AW: Button erst aktivieren wenn bestimmte felder gefüllt sin

Nach oben
       

ok, alsooooo

Wenn ich das so abändere und mein Formular öffne, dann ist der Button sichtbar.
Fülle ich dann die Daten ist der Button noch da und ich kann auch klicken, aber egal ob ich nun die Felder fülle oder nicht kommt meine MSGBOX "nicht alle Muss-felder gefüllt"

Eben mit dem kompilieren war ein Tipp-Fehler von mir.....
Willi Wipp
Moderator


Verfasst am:
13. Feb 2006, 16:43
Rufname:
Wohnort: Raum Wiesbaden


Re: Button erst aktivieren wenn bestimmte felder ... (VI) - Re: Button erst aktivieren wenn bestimmte felder ... (VI)

Nach oben
       

Hi ecmichi,

schon wieder was vergessen Embarassed
Fuege beim Formular-Ereignis Beim Anzeigen (Current) mal auch noch dazu
Code:
Private Sub Form_Current()
    FnbButtonVisible
End Sub
Welchend Datentyp haben den die gebundenen Felder der Steuerelemente:
Verkehrsart, [Tabelle Anlegen einer Frachtanfrage_Kunden], [Status der Frachtanfrage] und Allgemeinangebot?
Und was fuer Steurelemente verwendest Du?

_________________
Eine kurze Rueckmeldung waere nett
SL Willi Wipp

(Anleitung fuer das Anhaengen von Dateien: Klicke links auf [www], Gaeste muessen sich dafuer anmelden)
ecmichi
Schwaches Access;Fortgeschriten Word+Excel


Verfasst am:
13. Feb 2006, 16:55
Rufname:

AW: Button erst aktivieren wenn bestimmte felder gefüllt sin - AW: Button erst aktivieren wenn bestimmte felder gefüllt sin

Nach oben
       

Hi Will,

hab den Code ergänzt. Folgende Fehlermeldung kommt nun:

Zitat:
Laufzeitfehler '2474'
Für den von Ihnen eingegebenen Ausdruck ist es erforderlich, dass sich das Steuerelement im aktiven Fenster befindet
Zeile der Fehlermeldung
Code:
   If Screen.ActiveControl.Name = "Neuen Kunden erfassen" Then
- Verkehrsart ist ein Bezeichnungsfeld + Kombinationsfeld
- Tabelle Anlegen einer Frachtanfrage_Kunden ist auch ein
Bezeichnungsfeld + Kombinationsdfeld
- Status der Anfrage ist ein Bezeichnungsfeld + Kombinationsfeld
- Allgemeinangebot Ist ein Bezeichnugsfeld + Kontrollkästchen

(P.S. Eben mit meinem Chef abgesprochen, dass das Feld "Allgemeinangebot" nicht zum Muss-Feld wird)

Das Form wurde mit dem Assisten mit Basis einer Tabelle erstellt.
Willi Wipp
Moderator


Verfasst am:
13. Feb 2006, 17:24
Rufname:
Wohnort: Raum Wiesbaden

Re: Button erst aktivieren wenn bestimmte felder ... (VII) - Re: Button erst aktivieren wenn bestimmte felder ... (VII)

Nach oben
       

Hi ecmichi,

heute ist nicht mein Tag Wink
Code:
Private Function FnbButtonVisible() As Boolean
    If Trim(Nz(Me!Verkehrsart, "")) = "" Or _
       Trim(Nz(Me![Tabelle Anlegen einer Frachtanfrage_Kunden], "")) = "" Or _
       Trim(Nz(Me![Status der Frachtanfrage], "")) = "" Or _
       Trim(Nz(Me!Allgemeinangebot, "")) = "" Then
        On Error Resume Next
        If Screen.ActiveControl.Name = "Diese Anfrage jetzt drucken" Then
            Me!EineAnderesSteuerelement.SetFocus
        End If
        If Err Then Me!EineAnderesSteuerelement.SetFocus
        On Error GoTo 0
        Me![Diese Anfrage jetzt drucken].Visible = False
        FnbButtonVisible = False
      Else
        Me![Diese Anfrage jetzt drucken].Visible = True
        FnbButtonVisible = True
    End If
End Function
Beim Oeffnen ist ja noch kein Steuerelement aktiviert.
So sollte der Fehler abgefangen werden.

Leider hast Du den Datentyp der an die Steuerelemnte gebundenen Felder nicht angegeben.
Kann es sein das diese vom Datentyp Zahl sind?
Dann mussen wir das Trim(Nz(... wieder gegen IsNull(... austauschen Exclamation

_________________
Eine kurze Rueckmeldung waere nett
SL Willi Wipp

(Anleitung fuer das Anhaengen von Dateien: Klicke links auf [www], Gaeste muessen sich dafuer anmelden)
ecmichi
Schwaches Access;Fortgeschriten Word+Excel


Verfasst am:
13. Feb 2006, 17:48
Rufname:

AW: Button erst aktivieren wenn bestimmte felder gefüllt sin - AW: Button erst aktivieren wenn bestimmte felder gefüllt sin

Nach oben
       

Sind keine Zahlen...Text

Aber

ES FUNKTIONIERT!!!! *FREU*

Razz Razz Razz Razz Razz Razz

Des Rätsels lösung!!

Willi, Danke danke danke danke!!!
jonnyb2006
VBA Dummie


Verfasst am:
14. Okt 2007, 21:17
Rufname:
Wohnort: Kassel

Re: Button erst aktivieren wenn bestimmte felder ... (VII) - Re: Button erst aktivieren wenn bestimmte felder ... (VII)

Nach oben
       

Hallo willi, ich habe ebenfalls versucht diese Funktion bei mir einzubauen, es funktioniert auch soweit! Leider wird aber der Button erst sichtbar wenn ich einmal den Datensatz wechsel. Woran liegt das?

Mein Code:
Code:
Private Function FnbButtonVisible() As Boolean
    If Trim(Nz(Me!Mitarbeiter, "")) = "" Or _
       Trim(Nz(Me![Auftragsart], "")) = "" Or _
       Trim(Nz(Me![Bem_Techniker], "")) = "" Or _
       Trim(Nz(Me!Bem_KDC, "")) = "" Then
        On Error Resume Next
        If Screen.ActiveControl.Name = "Diese Anfrage jetzt drucken" Then
            Me!Mitarbeiter.SetFocus
        End If
        If Err Then Me!Mitarbeiter.SetFocus
        On Error GoTo 0
        Me![eSB_Auftrag_an_Auswahl].Visible = False
        FnbButtonVisible = False
      Else
        Me![eSB_Auftrag_an_Auswahl].Visible = True
        FnbButtonVisible = True
    End If
End Function

gruß
Bernd

_________________
gruß
Bernd


Du mußt Deinen Traum finden dann wird der Weg leicht!
derArb
getting better


Verfasst am:
14. Okt 2007, 21:30
Rufname: derArb
Wohnort: Berlin

AW: Button erst aktivieren wenn bestimmte felder gefüllt sin - AW: Button erst aktivieren wenn bestimmte felder gefüllt sin

Nach oben
       

hallo,

hast Du auch die Textfelder abgefangen mit
Code:
Private Sub Mitarbeiter_AfterUpdate()
    FnbButtonVisible
End Sub
usw....
Code:
Private Sub Form_AfterUpdate()
    FnbButtonVisible
End Sub
evtl. hilft auch ein
Code:
    Me.Requery

mfg
derArb

_________________
MfG
derArb

Scio me nihil scire...Εν οίδα οτι ουδέν οίδα... Ich weiss, dass ich nichts weiss (Sokrates)
Ich bevorzuge Beiträge mit korrekter deutscher Grammatik.
jonnyb2006
VBA Dummie


Verfasst am:
14. Okt 2007, 21:38
Rufname:
Wohnort: Kassel

AW: Button erst aktivieren wenn bestimmte felder gefüllt sin - AW: Button erst aktivieren wenn bestimmte felder gefüllt sin

Nach oben
       

Hey Arb, das war es....besten Dank und gute Nacht Wink
_________________
gruß
Bernd


Du mußt Deinen Traum finden dann wird der Weg leicht!
f4iNtwayne
Access mittlere, VBA geringe Kenntnisse


Verfasst am:
20. Sep 2010, 01:56
Rufname: Jan
Wohnort: Datteln

AW: Button erst aktivieren wenn bestimmte felder gefüllt sin - AW: Button erst aktivieren wenn bestimmte felder gefüllt sin

Nach oben
       Version: Office 2007

Hi zusammen,

ich hoffe mal, dass hier noch irgendwer in so einem alten thread antwortet Wink

Also ich habe das selbe Problem, was schon ecmichi hatte. Ich habe versucht, anhand eurer Erklärungen das selber hinzubiegen, doch das hat dummerweise nicht so ganz geklappt.
Folgende Infos dazu: formularergebnistest.jpg

Die Felder darin heißen:
Zitat:
MitgliedsnummerAbfrage - Kombinationsfeld - AutoWert aus Tabelle
VeranstaltungName - Kombinationsfeld - Zahl aus Tabelle, zugehöriger Text wird angezeigt
DisziplinName - Kombinationsfeld - Zahl aus Tabelle, zugehöriger Text wird angezeigt
Datum - Textfeld - Text mit benutzerdefinierter Formatierung
Serie1 - Textfeld - Zahl
Serie2 - Textfeld - Zahl
Serie3 - Textfeld - Zahl
Serie4 - Textfeld - Zahl
Serie5 - Textfeld - Zahl
Serie6 - Textfeld - Zahl
Ergebnis wird aus Serie1 bis Serie6 errechnet.
Die Buttons heißen:
Zitat:
ErgebnisSpeichern
SchliessenErgebnis
Das Formular funktioniert an sich auch wie es soll.
Nun soll allerdings dieser berühmte "Ergebnis speichern"-Button erst anklickbar sein, wenn alle Felder darüber ausgefüllt sind.
z.B. so: formularergebnistestaus.jpg

Ich habe wie gesagt bereits einen Code, der mir allerdings immer wieder einen Fehler ausgibt:
Code:
Option Compare Database

Private Sub Form_Current()
    SpeicherButtonAktivieren
End Sub

Private Sub MitgliedsnummerAbfrage_AfterUpdate()
    SpeicherButtonAktivieren
End Sub

Private Sub VeranstaltungName_AfterUpdate()
    SpeicherButtonAktivieren
End Sub

Private Sub DisziplinName_AfterUpdate()
    SpeicherButtonAktivieren
End Sub

Private Sub Datum_AfterUpdate()
    SpeicherButtonAktivieren
End Sub

Private Sub Serie1_AfterUpdate()
    SpeicherButtonAktivieren
End Sub

Private Sub Serie2_AfterUpdate()
    SpeicherButtonAktivieren
End Sub

Private Sub Serie3_AfterUpdate()
    SpeicherButtonAktivieren
End Sub

Private Sub Serie4_AfterUpdate()
    SpeicherButtonAktivieren
End Sub

Private Sub Serie5_AfterUpdate()
    SpeicherButtonAktivieren
End Sub

Private Sub Serie6_AfterUpdate()
    SpeicherButtonAktivieren
End Sub

Private Sub Form_AfterUpdate()
    SpeicherButtonAktivieren
End Sub

Private Function SpeicherButtonAktivieren() As Boolean
    If IsNull(Me!MitgliedsnummerAbfrage, "") = "" Or _
       IsNull(Me!VeranstaltungName, "") = "" Or _
       IsNull(Me!DisziplinName, "") = "" Or _
       IsNull(Me!Datum, "") = "" Or _
       IsNull(Me!Serie1, "") = "" Or _
       IsNull(Me!Serie2, "") = "" Or _
       IsNull(Me!Serie3, "") = "" Or _
       IsNull(Me!Serie4, "") = "" Or _
       IsNull(Me!Serie5, "") = "" Or _
       IsNull(Me!Serie6, "") = "" Then
        On Error Resume Next
        If Screen.ActiveControl.Name = "ErgebnisSpeichern" Then
            Me!MitgliedsnummerAbfrage.SetFocus
        End If
        If Err Then Me!MitgliedsnummerAbfrage.SetFocus
        On Error GoTo 0
        Me!ErgebnisSpeichern.Visible = False
        SpeicherButtonAktivieren = False
      Else
        Me!ErgebnisSpeichern.Visible = True
        SpeicherButtonAktivieren = True
    End If
End Function

Private Sub SchliessenErgebnis_Click()
On Error GoTo Err_SchliessenErgebnis_Click
    If Me.Dirty Then
        DoCmd.RunCommand acCmdUndo
    End If
    DoCmd.RunCommand acCmdClose
Exit_SchliessenErgebnis_Click:
    Exit Sub
Err_SchliessenErgebnis_Click:
    MsgBox Err.Description
    Resume Exit_SchliessenErgebnis_Click
End Sub

Private Sub DatensatzSpeichern_Click()
On Error GoTo Err_DatensatzSpeichern_Click
    If Not SpeicherButtonAktivieren Then Exit Sub
    DoCmd.RunCommand acCmdSaveRecord
Exit_DatensatzSpeichern_Click:
    Exit Sub
Err_DatensatzSpeichern_Click:
    MsgBox "Bitte alle Felder ausfüllen"
    Resume Exit_DatensatzSpeichern_Click
End Sub
Folgender Fehler taucht auf, wenn ich das Formular öffnen will: code.png

Außerdem wird das Ergebnis, warum auch immer, nicht mehr berechnet seit ich den Code getippt habe.
Kann mir irgendwer sagen, wieso diese Fehler auftrauchen und was ich dagegen machen kann?

LG und schonmal Danke
f4iNtwayne
Nachtrag: f4iNtwayne am 01. Okt 2010 um 18:50 hat folgendes geschrieben:
Problem gelöst!
Es war ein Typ falsch gesetzt.

_________________
LG f4iNtwayne



formularergebnistest.jpg
 Beschreibung:
 Dateigröße:  55.86 KB
 Angeschaut:  1801 mal

formularergebnistest.jpg



formularergebnistestaus.jpg
 Beschreibung:
 Dateigröße:  38.91 KB
 Angeschaut:  1801 mal

formularergebnistestaus.jpg



code.png
 Beschreibung:
 Dateigröße:  51.98 KB
 Angeschaut:  1802 mal

code.png


KlausMz
Moderator Access


Verfasst am:
01. Okt 2010, 19:13
Rufname:
Wohnort: Irgendwo in der Pfalz

AW: Button erst aktivieren wenn bestimmte felder gefüllt sin - AW: Button erst aktivieren wenn bestimmte felder gefüllt sin

Nach oben
       

Hallo,
3 Anmerkungen noch:

1. Díe Struktur der DB erfordert einen weiteren Normalisierungschritt.
Für die Ergenisse (Serie 1-6) ist eine weitere Tabelle erforderlich.

2. Berechnete Werte werden nicht gespeichert.

3. Ein Speichern Button braucht es dann gar nicht.
Wenn Du sicherstellen willst, dass nur gespeichert werden kann wenn die 6 Ergebnisse (=6 Datensätze) ausgefüllt sind, musst Du nur das Schließen des Formulars verhindern.

_________________
Gruß
Klaus . . . . . Feedback wäre wünschenswert.
Ich möchte bitte keine unaufgeforderten PN. Fragen bitte im Forum.
Willi Wipp
Moderator


Verfasst am:
02. Okt 2010, 07:30
Rufname:
Wohnort: Raum Wiesbaden


Re: Button erst aktivieren wenn bestimmte felder ... (VIII) - Re: Button erst aktivieren wenn bestimmte felder ... (VIII)

Nach oben
       

Hi f4iNtwayne,

noch als Ergaenzung: Der Fehler ruehrt aus der falschen Verwendung der Funktion IsNull.
Diese Funktion erwartet nur einen Parameter! Du hast 2 angegeben.
Die Syntax die Du verwendest gehoert zur Funktion Nz!

_________________
Eine kurze Rueckmeldung waere nett
SL Willi Wipp

(Anleitung fuer das Anhaengen von Dateien: Klicke links auf [www], Gaeste muessen sich dafuer anmelden)
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Gehe zu Seite Zurück  1, 2
Diese Seite Freunden empfehlen

Seite 2 von 2
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Access Tabellen & Abfragen: BESTIMMTE Daten einer Zeile in Spalte umwandeln 7 Gast 2403 30. Dez 2005, 13:56
KirstenS BESTIMMTE Daten einer Zeile in Spalte umwandeln
Keine neuen Beiträge Access Tabellen & Abfragen: Zu viele Felder definiert! 7 michel1964de 689 29. Sep 2005, 09:15
michel1964de Zu viele Felder definiert!
Keine neuen Beiträge Access Tabellen & Abfragen: Felder automatisch ausfüllen 5 NVG 884 13. Sep 2005, 20:05
stpimi Felder automatisch ausfüllen
Keine neuen Beiträge Access Tabellen & Abfragen: Tabellen-Abfrage mit 'Datum ab' Felder 11 ali.soy 1383 29. Aug 2005, 09:12
ali.soy Tabellen-Abfrage mit 'Datum ab' Felder
Keine neuen Beiträge Access Tabellen & Abfragen: Verkettung von Inhalten versch.Felder in einer Tabelle 15 haike 1487 27. Jul 2005, 11:56
haike Verkettung von Inhalten versch.Felder in einer Tabelle
Keine neuen Beiträge Access Tabellen & Abfragen: Berechnende Felder aus Formular in Tbl speichern 1 heatseeker 1280 26. Jul 2005, 20:27
jens05 Berechnende Felder aus Formular in Tbl speichern
Keine neuen Beiträge Access Tabellen & Abfragen: Werte Zählen, aber bestimmte nicht dazu addieren 1 MrMarley 897 14. Jun 2005, 02:21
tobes Werte Zählen, aber bestimmte nicht dazu addieren
Keine neuen Beiträge Access Tabellen & Abfragen: Bestimmte Daten von Excel nach Access 2 andy1986 699 06. Jun 2005, 09:41
andy1986 Bestimmte Daten von Excel nach Access
Keine neuen Beiträge Access Tabellen & Abfragen: Aktualisierungsabfrage bestimmte Datensatzanzahl 4 Gast 789 20. Jan 2005, 19:23
itse4 Aktualisierungsabfrage bestimmte Datensatzanzahl
Keine neuen Beiträge Access Tabellen & Abfragen: Berechnende Felder in einer Abfrage 1 schnecke 881 23. Nov 2004, 02:20
mapet Berechnende Felder in einer Abfrage
Keine neuen Beiträge Access Tabellen & Abfragen: Summer einzelner Felder mittels Abfrage ???? 1 slow 688 05. Okt 2004, 09:29
TommyK Summer einzelner Felder mittels Abfrage ????
Keine neuen Beiträge Access Tabellen & Abfragen: Zu viele Felder in der Tabelle 4 Sephyra 487 16. Sep 2004, 13:12
Sephyra Zu viele Felder in der Tabelle
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: Microsoft-Excel Diagramme