Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Zellen kopieren abhängig von Wert in anderer Zelle
zurück: Bedingte Formatierung bei Feld mit Bezug-Fehler weiter: Automatische Formatierung bei Zeiteingabe Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Feedback Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
clanfuehrer
Im Profil kannst Du frei den Rang ändern


Verfasst am:
23. Apr 2014, 18:26
Rufname:

Zellen kopieren abhängig von Wert in anderer Zelle - Zellen kopieren abhängig von Wert in anderer Zelle

Nach oben
       Version: Office 2013

Hallo.

Ich habe eine Excel Tabelle in der In den Zellen

B5:E31 jeweils ein Vorgang abgebildet.

Dieser Vorgang wiederholt sich je nach Nutzer mehrmals.

Nun möchte ich es so gestalten, daß ich in einer Zelle einen Wert eingebe, also z. B. in A1 den Wert 5 und abhängig von diesem Wert wird der Zellenbereich B5:E31 kopiert.

In diesem Beispiel also 4 mal, so daß ich diesen Bereich insgesamt 5 mal habe..

Gleichzeitig müssten sich die Zellen rechts davon um den jeweiligen Bereich nach rechts verschieben.

Hoffe ich habe das verständlich erklärt.

Im angehängten Bild habe ich mal die beiden Ergebnisse bei einem Wert 1 und bei einem Wert 5 in Zelle A1 Abgebildet.

Wäre auch genial, wenn die Spaltenbriete beim Kopieren beibehalten wird.
clanfuehrer
Im Profil kannst Du frei den Rang ändern


Verfasst am:
23. Apr 2014, 18:27
Rufname:

AW: Zellen kopieren abhängig von Wert in anderer Zelle - AW: Zellen kopieren abhängig von Wert in anderer Zelle

Nach oben
       Version: Office 2013

Hier mal das Bild dazu


Bild1.png
 Beschreibung:
 Dateigröße:  223.57 KB
 Angeschaut:  122 mal

Bild1.png


Thomas Ramel
Microsoft Excel-MVP


Verfasst am:
24. Apr 2014, 10:23
Rufname: Thom
Wohnort: Glashütten - CH

AW: Zellen kopieren abhängig von Wert in anderer Zelle - AW: Zellen kopieren abhängig von Wert in anderer Zelle

Nach oben
       Version: Office 2013

Grüezi Clanführer

Nimm mal die folgenden Zeilen und kopiere sie ins Codemodul des betreffenden Tabellenblattes (Rechtsklick auf den Tabellenblattreiter und 'Code anzeigen' auswählen):

Code:
Private Sub Worksheet_Change(ByVal Target As Range)
Dim lngI As Long
    If Target.Address(0, 0) = "A1" Then
        On Error GoTo ErrorHandler
        Application.EnableEvents = False

        For lngI = 1 To Target.Value - 1

            With Range("B5:E31")
                .Copy
                .Offset(0, lngI * 4).Insert (xlShiftToRight)
                .Offset(0, lngI * 4).PasteSpecial xlPasteColumnWidths
            End With

        Next lngI

        Target.Activate
        Application.CutCopyMode = False
    End If
   
ErrorHandler:
    Application.EnableEvents = True
End Sub



Verändere dann den Wert in A1 und schau ob es das Gewünschte ist.

_________________
Mit freundlichen Grüssen

Thomas Ramel
[Vista Ultimate SP-1 / xl2007 SP-2]
clanfuehrer
Im Profil kannst Du frei den Rang ändern


Verfasst am:
24. Apr 2014, 17:10
Rufname:

AW: Zellen kopieren abhängig von Wert in anderer Zelle - AW: Zellen kopieren abhängig von Wert in anderer Zelle

Nach oben
       Version: Office 2013

Hallo Thomas.

Vielen Dank.

Das geht in die Richtung.

Nur müsste es wenn ich anschließend den Weert in A1 ändere, wieder die neue Anzahl erzeugen.

also ich gebe in A!1 den Wert 5 ein, dann kopiert es mir die Zellen 4 mal (Soweit funktioniert es ja auch)

Wenn ich dann den Wert in A1 auf 3 ändere, müsste es wieder 2 Kopien löschen. Usw.

Kann man das einbauen?

Vielen Dank
Thomas Ramel
Microsoft Excel-MVP


Verfasst am:
24. Apr 2014, 20:26
Rufname: Thom
Wohnort: Glashütten - CH

Re: AW: Zellen kopieren abhängig von Wert in anderer Zelle - Re: AW: Zellen kopieren abhängig von Wert in anderer Zelle

Nach oben
       Version: Office 2013

Grüezi Clanführer

clanfuehrer hat folgendes geschrieben:
Das geht in die Richtung.


...nah wenigstens stimmt die Himmelsrichtung.... Sad

clanfuehrer hat folgendes geschrieben:
Nur müsste es wenn ich anschließend den Weert in A1 ändere, wieder die neue Anzahl erzeugen.

also ich gebe in A!1 den Wert 5 ein, dann kopiert es mir die Zellen 4 mal (Soweit funktioniert es ja auch)

Wenn ich dann den Wert in A1 auf 3 ändere, müsste es wieder 2 Kopien löschen. Usw.

Kann man das einbauen?


Ja, kann man - aber nicht ohne zu wissen welche der zuvor eingefügten denn wieder gelöscht werden sollen - geht es immer um die letzten oder sollen die dazwischen liegenden entfernt werden?

Es müsste auch noch zwischengespeichert werden wie viele Blöcke denn vorhanden sind im Moment - dafür müsste ich am besten eine Zelle belegen können/dürfen.


Da ich Salami am liebsten auf dem Brot mag, nicht aber wenn bei Fragen immer mal wieder was nachkommt, bitte ich dich um eine ausführliche(re) Schilderung des ganzen Vorhabens, nicht das wir uns auf eine Richtung einschiessen, eine andere aber besser gewesen wäre... Wink

_________________
Mit freundlichen Grüssen

Thomas Ramel
[Vista Ultimate SP-1 / xl2007 SP-2]
Gast



Verfasst am:
25. Apr 2014, 08:41
Rufname:

AW: Zellen kopieren abhängig von Wert in anderer Zelle - AW: Zellen kopieren abhängig von Wert in anderer Zelle

Nach oben
       Version: Office 2013

Hallo thomas.

Das ganze sind jeweils Phasen innerhalb eines Projektes.

Beim einen Projekt sind es 1 Phase, bei anderen 4 oder 5 oder auch mal mehr.

Das File ist die Grundmaske und beim Start des Projektes soll mann wählen können wie viele Phasen.

Ich möchte dann aber, daß man eben auch Phasen wieder zurück nehmen kann.

Da sollte dann jeweils von rechts nach links gelöscht werden.

Mann kann jede Zeile belegen, die benötigt wird.

Wenn ich im Verlauf des Projektes eine zusätzliche Phase benötige, dann soltte man das auch noch erweitern können, bzw reduzieren, wenn es zu viele sind.

Hoffe ich habe das jetzt ausführlich erklärt.

Besten Dank für Deine Unterstützung.
Thomas Ramel
Microsoft Excel-MVP


Verfasst am:
25. Apr 2014, 09:34
Rufname: Thom
Wohnort: Glashütten - CH

AW: Zellen kopieren abhängig von Wert in anderer Zelle - AW: Zellen kopieren abhängig von Wert in anderer Zelle

Nach oben
       Version: Office 2013

Grüezi Clanführer

Danke für die detaillierte und umfassende Schilderung des Vorhabens, so fällt es mit sehr viel leichter auf Eventualitäten einzugehen.

Hier der angepasste Code, der Zelle B1 als Referenz verwendet um festzuhalten wie viele Blöcke denn gerade vorhanden sind.
Diese Zelle kannst Du z.B. auch mit ;;; formatieren, dann ist der Werte nicht sichtbar.
Zelle A1 würde ich noch mit einer Datenüberprüfung versehen, sodass dort nur ganzzahlige Werte zwischen 1 und der maximalen Anzahl Blöcke eingegeben werden kann.
Damit ist der Code dann entsprechend abgesichert.

Im Moment bleiben beim Löschen von Blöcken dort die Spaltenbreiten so erhalten wie sie kopiert worden sind - das könnte man ggf am Code noch nachbessern.


Nimm also neu die folgenden Zeilen und schau mal ob das deinen Vorstellungen entspricht:

Code:
Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
Dim lngI As Long
    If Target.Address(0, 0) = "A1" Then
        On Error GoTo ErrorHandler
        Application.EnableEvents = False

        If Range("A1").Value > Range("B1").Value Then
            'Bereiche hinzufügen
            For lngI = Range("B1").Value To Target.Value - 1
                With Range("B5:E31")
                    .Copy
                    .Offset(0, lngI * 4).Insert (xlShiftToRight)
                    .Offset(0, lngI * 4).PasteSpecial xlPasteColumnWidths
                End With
            Next lngI
        Else
            'Bereiche entfernen
            For lngI = Range("B1").Value - 1 To Target.Value Step -1
                Range("B5:E31").Offset(0, lngI * 4).Delete (xlShiftToLeft)
            Next lngI
        End If

        Target.Activate
        Range("B1").Value = Target.Value
        Application.CutCopyMode = False
    End If

ErrorHandler:
    Application.EnableEvents = True
End Sub

_________________
Mit freundlichen Grüssen

Thomas Ramel
[Vista Ultimate SP-1 / xl2007 SP-2]
clanfuehrer
Im Profil kannst Du frei den Rang ändern


Verfasst am:
25. Apr 2014, 13:45
Rufname:

AW: Zellen kopieren abhängig von Wert in anderer Zelle - AW: Zellen kopieren abhängig von Wert in anderer Zelle

Nach oben
       Version: Office 2013

Hallo Thomas.

Perfekt.

Genau das was ich wollte.

Vielen herzlichen Dank.
clanfuehrer
Im Profil kannst Du frei den Rang ändern


Verfasst am:
25. Apr 2014, 16:13
Rufname:

AW: Zellen kopieren abhängig von Wert in anderer Zelle - AW: Zellen kopieren abhängig von Wert in anderer Zelle

Nach oben
       Version: Office 2013

Hallo Thomas.

In meiner kleinen Musterdatei hat das perfekt hingehauen.

Wenn ich das jetzt auf meine richtige Datei übertrage dann funktioniert es nicht mehr so perfekt.

Er kopiert zwar die Anzahl der genannten Kopien und nimmt sie wieder weg.

Aber er übernimmt nicht die formatierung und ich muss nach der Eingabe auch jedesmal erst bestägen.

Heißt die Zielbereicht enhalten den gewünschten Inhalt, haben aber noch den blinkenden Rahmen in dem ich bestätigen muss.

Der zu kopierende Bereiche ist jetzt L5:N54.

Das Eingabefeld ist G:52 und die Zusatzzelle für die Speicherung ist H52.

Wie folgt habe ich den code abgeändert:

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
Dim lngI As Long
If Target.Address(0, 0) = "G52" Then
On Error GoTo ErrorHandler
Application.EnableEvents = False

If Range("G52").Value > Range("H52").Value Then
'Bereiche hinzufügen
For lngI = Range("h52").Value To Target.Value - 1
With Range("L5:N54")
.Copy
.Offset(0, lngI * 4).Insert (xlShiftToRight)
.Offset(0, lngI * 4).PasteSpecial xlPasteColumnWidths
End With
Next lngI
Else
'Bereiche entfernen
For lngI = Range("h52").Value - 1 To Target.Value Step -1
Range("L5:N54").Offset(0, lngI * 4).Delete (xlShiftToLeft)
Next lngI
End If

Target.Activate
Range("h52").Value = Target.Value
Application.CutCopyMode = False
End If

ErrorHandler:
Application.EnableEvents = True
End Sub



Wo habe ich da den Fehler begannen.

Bild mit dran.
clanfuehrer
Im Profil kannst Du frei den Rang ändern


Verfasst am:
25. Apr 2014, 16:13
Rufname:

AW: Zellen kopieren abhängig von Wert in anderer Zelle - AW: Zellen kopieren abhängig von Wert in anderer Zelle

Nach oben
       Version: Office 2013

hier Bild


Unbenannt.JPG
 Beschreibung:
 Dateigröße:  277.58 KB
 Angeschaut:  39 mal

Unbenannt.JPG


clanfuehrer
Im Profil kannst Du frei den Rang ändern


Verfasst am:
25. Apr 2014, 16:32
Rufname:

AW: Zellen kopieren abhängig von Wert in anderer Zelle - AW: Zellen kopieren abhängig von Wert in anderer Zelle

Nach oben
       Version: Office 2013

Hallo.

Noch mal ich.

Habs noch mal versucht und jetzt klappts (fast)

Macht mir nur ne Leerspalte zwischen den Kopien.
clanfuehrer
Im Profil kannst Du frei den Rang ändern


Verfasst am:
25. Apr 2014, 16:32
Rufname:

AW: Zellen kopieren abhängig von Wert in anderer Zelle - AW: Zellen kopieren abhängig von Wert in anderer Zelle

Nach oben
       Version: Office 2013

siehe Bild


Unbenannt.JPG
 Beschreibung:
 Dateigröße:  330.74 KB
 Angeschaut:  28 mal

Unbenannt.JPG


Thomas Ramel
Microsoft Excel-MVP


Verfasst am:
25. Apr 2014, 16:39
Rufname: Thom
Wohnort: Glashütten - CH

AW: Zellen kopieren abhängig von Wert in anderer Zelle - AW: Zellen kopieren abhängig von Wert in anderer Zelle

Nach oben
       Version: Office 2013

Grüezi Clanführer

Siehst Du, genau das meine ich mit Salami - es kommt immer mal wieder was nach, wenn Du nicht von Anfang an die 'Karten' auf den Tisch legst und genau das schilderst was Du gerne haben möchtest.... Twisted Evil

Entweder bist Du fit genug einen prinzipiell funktionierenden Ansatz auf dein Problem zu übertragen, ansonsten hilfst Du dir selbst, wenn Du dein Problem nicht veränderst/verfälscht wenn Du es postest... Rolling Eyes

BTW: Bilder helfen beim Erstellen eines Codes übrigens auch nicht, sie machen nur Arbeit, weil alles in ein Tabellenblatt übertragen werden muss, damit eine funktionierende Datei entstehen kann...


Der Unterschied deines Beispiels zu deiner eigentlichen Mappe sind nicht nur andere Bezüge (das hast Du offenbar hingekriegt), sondern, dass Du auch einen weniger breiten Bereich hast, der hinzugefügt oder weg genommen werden soll.
Das hast Du im Code nicht geändert...

Hier der angepasste und funktionierende neue Code:

Code:
Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
Dim lngI As Long
    If Target.Address(0, 0) = "G52" Then
        On Error GoTo ErrorHandler
        Application.EnableEvents = False

        If Range("G52").Value > Range("H52").Value Then
            'Bereiche hinzufügen
            For lngI = Range("H52").Value To Target.Value - 1
                With Range("L5:N54")
                    .Copy
                    .Offset(0, lngI * 3).Insert (xlShiftToRight)
                    .Offset(0, lngI * 3).PasteSpecial xlPasteColumnWidths
                End With
            Next lngI
        Else
            'Bereiche entfernen
            For lngI = Range("H52").Value - 1 To Target.Value Step -1
                Range("L5:N54").Offset(0, lngI * 3).Delete (xlShiftToLeft)
            Next lngI
        End If

        Target.Activate
        Range("H52").Value = Target.Value
        Application.CutCopyMode = False
    End If

ErrorHandler:
    Application.EnableEvents = True
End Sub

_________________
Mit freundlichen Grüssen

Thomas Ramel
[Vista Ultimate SP-1 / xl2007 SP-2]
clanfuehrer
Im Profil kannst Du frei den Rang ändern


Verfasst am:
25. Apr 2014, 16:53
Rufname:

AW: Zellen kopieren abhängig von Wert in anderer Zelle - AW: Zellen kopieren abhängig von Wert in anderer Zelle

Nach oben
       Version: Office 2013

Ja ok, Du hast ja vollkommen recht.

Habe mich da wohl ein wenig überschätzt in meiner Fähigkeit das zu übertragen.

Aber trotzdem vielen Dank.

wünsche ein schönes Wochenende.
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Diese Seite Freunden empfehlen

Seite 1 von 1
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Excel Formeln: Text und fortlaufende Nr. in eine Zelle 2 Strebe nach Können 1013 16. Jul 2004, 19:19
Strebe nach Können Text und fortlaufende Nr. in eine Zelle
Keine neuen Beiträge Excel Formeln: Wenn in Spalte A der Wert .... dann die Felder in Spalte B 3 mucky 2520 16. Jul 2004, 08:06
mucky Wenn in Spalte A der Wert .... dann die Felder in Spalte B
Keine neuen Beiträge Excel Formeln: Zusammenhängende Zellen mit gleichem Text zählen 10 Red Hair 1522 09. Jul 2004, 15:22
Red Hair Zusammenhängende Zellen mit gleichem Text zählen
Keine neuen Beiträge Excel Formeln: punkt am ende der zelle? 3 marKUSS 1815 08. Jul 2004, 14:26
Gast punkt am ende der zelle?
Keine neuen Beiträge Excel Formeln: Wort in Zelle immer mit Großbuchstaben beginnen 6 QWERT 2522 24. Jun 2004, 15:56
steve1da Wort in Zelle immer mit Großbuchstaben beginnen
Keine neuen Beiträge Excel Formeln: ANZAHL in einer bestimmten Schriftfarbe formatierter Zellen 12 curious 1933 21. Jun 2004, 13:56
Gast ANZAHL in einer bestimmten Schriftfarbe formatierter Zellen
Keine neuen Beiträge Excel Formeln: Zahlen die links in einer Zelle stehen addieren 9 Red Hair 1611 09. Jun 2004, 07:41
steve1da Zahlen die links in einer Zelle stehen addieren
Keine neuen Beiträge Excel Formeln: ##WERT wird angezeigt, 2 Tieftaucher03 588 25. Mai 2004, 20:34
xyzdef ##WERT wird angezeigt,
Keine neuen Beiträge Excel Formeln: Mittelwert über Zellen in denen auch 0 stehen kann 3 pkegelking 484 18. Mai 2004, 10:57
pkegelking Mittelwert über Zellen in denen auch 0 stehen kann
Keine neuen Beiträge Excel Formeln: Aktuelles Datum soll in einer Zelle farbig markiert werden 7 Moustee 2511 01. Mai 2004, 19:55
Gast Aktuelles Datum soll in einer Zelle farbig markiert werden
Keine neuen Beiträge Excel Formeln: Zusätzliche Ausgabe in einer anderen Zelle 3 Hansjörg 604 19. Apr 2004, 16:14
icke Zusätzliche Ausgabe in einer anderen Zelle
Keine neuen Beiträge Excel Formeln: Quotient aus zwei Zellen bilden 2 pwerky 2593 04. Apr 2004, 00:27
Gast Quotient aus zwei Zellen bilden
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: MS Frontpage