Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
mehrere Felder in Listenfeld mit Mehrfachausw. aktualisieren
zurück: Kombobox mit Mehrfachauswahl weiter: Datensatz-Zähler Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Feedback Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
csnb
ich stolpere mich so durch...


Verfasst am:
22. Apr 2014, 12:42
Rufname:

mehrere Felder in Listenfeld mit Mehrfachausw. aktualisieren - mehrere Felder in Listenfeld mit Mehrfachausw. aktualisieren

Nach oben
       Version: Office 2010

Hi!

Nachdem ich mein Problem bei einem zu aktualisierenden Feld verstanden habe, hakt es nun beim Aktualisieren mehrerer Felder.

Mein Ziel: es sollen mehrere Felder in einer Liste von Sendungen aktualisiert werden.

Mein bisheriger Weg:
Ich habe
- ein Listenfeld namens lstVerladung mit Mehrfachauswahl, das auf einer Abfrage namens DatenVerladung beruht. Die Abfrage zieht Daten aus der Tabelle ITRMaster. In dieser Tabelle gibt es das Feld Referenz, welches eine Sendung eindeutig identifiziert.
- folgende Textfelder - die im Formular eingebettet sind - enthalten die gewünschten Daten: txtLadeDat (dd-mm-yyyy Format) ; txtContNo ; txtVessel ; txtSeal ; txtMBL und cboContSize (Daten direkt im Kombifeld hinterlegt)

Aus dem Code bei dem mir Marmeladenglas vorhin so gut geholfen hat, habe ich nun diesen Code gebastelt und im Klickevent des Button DatenEintragen hinterlegt:
Code:
Private Sub DatenEintragen_Click()
    Dim varItm As Variant
   
    For Each varItm In Me!lstVerladung.ItemsSelected
        CurrentDb.Execute _
           "UPDATE ITRMaster" _
           & " SET container_loading_date = " & Format(Me.txtLadeDat _
                                                     , "\#mm-dd-yyyy\#") _
           & " ", "Container_no = " & Me.txtContNo _
           & " ", "Container_size = " & Me.cboContSize _
           & " ", "Vessel = " & Me.txtVessel & " ", "seal = " & Me.txtSeal _
           & " ", "MBL# = " & Me.txtMBL _
         & " WHERE Referenz ='" & Me!lstVerladung.ItemData(varItm) & "'"
    Next varItm
    Me!lstVerladung.Requery
    Me.txtLadeDat = Null
    Me.txtContNo = Null
    Me.txtContSize = Null
    Me.txtVessel = Null
    Me.txtSeal = Null
End Sub
Ich bin der Meinung beim Aktualiseren mehrerer Spalten werden diese durch Komma im SET-Teil voneinander getrennt. Der Code liefert das Ergebnis: Fehler beim Komplilieren, Falsche Anzahl an Argumenten oder ungültige Zuweisung einer Eigenschaft. Es wird der .Execute Befehl in
Zitat:
CurrentDb.Execute _
als Problemstelle ausgewiesen.
Wo liegt mein Fehler und warum?

Vielen Dank im Vorraus
Gruß
Carsten
Marmeladenglas
komme zurecht


Verfasst am:
22. Apr 2014, 13:04
Rufname:

AW: mehrere Felder in Listenfeld mit Mehrfachausw. aktualisi - AW: mehrere Felder in Listenfeld mit Mehrfachausw. aktualisi

Nach oben
       Version: Office 2010

Hi,
du solltest dir anschauen wie man Strings miteinander verkettet....
D.h. jeder Teil der duch " eingeschlossen ist, muss durch ein & verkettet sein
1.) ...." & Me.irgendwas & ", Feldxy = " & ....
2.) gibt es 3 Fälle zu unterscheiden:
Zahl
Text
Datum
Die letzten beiden erwarten eine gesonderte Formatierung. DAtum hatten wir schon. Bei Text muss die Variable (Steuerelement) in HOchkommata stehen.

Insofern sind diese Stellen falsch:
& " ", "Container_no = " & Me.txtContNo ....
" ", "Container_size .....
& " ", "seal


Das " " & im Thread mit dem Datum diente lediglich dazu, dass ein Leerzeichen das Schlüsselwort WHERE vom Rest des Strings trennt, ist aber keine Syntax die so einzuhalten ist...

..& " " & "," & " Container_no....
wäre die "sturre" Auflösung der Syntax in richtige Schreibweise...
& " , Container_no = " & ... dann die übersichtliche... Smile
csnb
ich stolpere mich so durch...


Verfasst am:
22. Apr 2014, 14:18
Rufname:

AW: mehrere Felder in Listenfeld mit Mehrfachausw. aktualisi - AW: mehrere Felder in Listenfeld mit Mehrfachausw. aktualisi

Nach oben
       Version: Office 2010

Hallo Marmeladenglas,

ich stelle mich offenbar noch ein wenig dusselig an. So langsam habe ich aber grob verstanden was passieren soll. Mein Code sieht nun so aus:
Code:
        CurrentDb.Execute _
           "UPDATE ITRMaster" _
           & " SET container_loading_date = " & Format(Me.txtLadeDat _
                                                     , "\#mm-dd-yyyy\#"), _
                   Container_no = '" & Me.txtContNo & "', _
                   Container_size = '" & Me.cboContSize & "', _
                   Vessel = '" & Me.txtVessel & "', _
                   Seal = '" & Me.txtSeal & "' _
         & " WHERE Referenz ='" & Me!lstVerladung.ItemData(varItm) & "'"
Nun erscheint: Erwartet Ausdruck . Es wird der gesamte Execute Teil markiert, wobei der Cursor bei den Hochkommata stehen bleibt.
Blackpit
Im Profil kannst Du frei den Rang ändern


Verfasst am:
22. Apr 2014, 14:24
Rufname:

AW: mehrere Felder in Listenfeld mit Mehrfachausw. aktualisi - AW: mehrere Felder in Listenfeld mit Mehrfachausw. aktualisi

Nach oben
       Version: Office 2010

Empfehlung:

Erstell eine Variable (String) und weise Ihr das SQL-Statement zu.
Du hast dann die Möglichkeit
a) die erstellte Zeichenkette per Debug.Print zu prüfen
b) das Statement im AbfrageEditor zu testen
c) den Code ein wenig übersichtlicher zu halten Wink

Ausserdem empfehle ich Execute den Parameter "dbFailOnError" mitzugeben um aufschlussreiche Fehlermeldungen zu bekommen.

Gruß

BP
Marmeladenglas
komme zurecht


Verfasst am:
22. Apr 2014, 14:34
Rufname:

AW: mehrere Felder in Listenfeld mit Mehrfachausw. aktualisi - AW: mehrere Felder in Listenfeld mit Mehrfachausw. aktualisi

Nach oben
       Version: Office 2010

Hi,
warum steht das Komma nach der Formatanweisung außerhalb des Strings ??
Warum ist die Formatanweisung nicht korrekt mit dem String verkettet ?
csnb
ich stolpere mich so durch...


Verfasst am:
22. Apr 2014, 14:55
Rufname:

AW: mehrere Felder in Listenfeld mit Mehrfachausw. aktualisi - AW: mehrere Felder in Listenfeld mit Mehrfachausw. aktualisi

Nach oben
       Version: Office 2010

Hi!

Meine VBA Kenntnisse beschränken sich auf Inselwissen, das ich mir durch Probieren selbst angeeignet habe und es fehlen daher leider allerhand Grundlagen.

Ich habe das Komma, zum Beispiel jenes das direkt nach dem Hochkomma kommt:
Code:
Container_no = '" & Me.txtContNo & "', _
dorthin gesetzt, da ich mit dem Komma das nächste zu aktualisierende Feld beginnen möchte. Offenbar scheint der Gedanke aber nicht ganz ausgereift zu sein.
Wo ist mein Fehler?

@Blackpit, soweit ich Deiner Idee gedanklich folgen kann, klingt sie gut. Vielen Dank dafür! Aber ich habe mich momentan auf den Lösungsweg von Marmeldenglas eingeschossen und würde den gern erst einmal bis zum Ende verfolgen. Sollte ich daran kläglich scheitern, werde ich die Alternative probieren.
Marmeladenglas
komme zurecht


Verfasst am:
22. Apr 2014, 15:00
Rufname:

AW: mehrere Felder in Listenfeld mit Mehrfachausw. aktualisi - AW: mehrere Felder in Listenfeld mit Mehrfachausw. aktualisi

Nach oben
       Version: Office 2010

Code:
        CurrentDb.Execute _
           "UPDATE ITRMaster" _
           & " SET container_loading_date = " & Format(Me.txtLadeDat _
                                                     , "\#mm-dd-yyyy\#") _
              & ", Container_no = '" & Me.txtContNo & "'" _
              & ", Container_size = '" & Me.cboContSize & "'" _
              & ", Vessel = '" & Me.txtVessel & "'" _
              & ", Seal = '" & Me.txtSeal & "'" _
         & " WHERE Referenz ='" & Me!lstVerladung.ItemData(varItm) & "'" _
                        , 128 'dbFailOnError
ungefähr so

Entscheidend ist übrigens die Dimensionierung des Feldes in der Tabelle !
Also ist Container_no eine Zahl in der Tabelle, dann wären die Hochkommata falsch !

Blackpits Vorschläge sind keine Alternativen, sondern Vorgehensweisen den Code übersichtlich zu halten. Mit dbFailOnError meint er die Erweiterung des
Code:
        Currendb.Execute "DeinString", 128 'dbFailOnError
csnb
ich stolpere mich so durch...


Verfasst am:
22. Apr 2014, 16:43
Rufname:

AW: mehrere Felder in Listenfeld mit Mehrfachausw. aktualisi - AW: mehrere Felder in Listenfeld mit Mehrfachausw. aktualisi

Nach oben
       Version: Office 2010

So... es ist geschafft und funktioniert tadellos.

Noch ein paar Anmerkungen falls künftig mal ein ähnlich ahnungsloser Mensch wie ich sich daran versucht.
- das Feld Container_loading_date ist wenig überraschend ein Datumsfeld
- die Felder Cont_size, Cont_No, Seal, MBL sind Textfelder
- die Kombibox Cont_size habe ich ohne Hochkommata eingefügt. Das Feld in der Tabelle ist zwar ein Textfeld, so wie ich es verstanden habe, liefert eine Kombibox aber eine Zahl als Ergebnis.

In meiner Tabelle ITRMaster hieß das Feld MBL anfangs MBL#. Das Käsekästchen verursachte aber Fehler, deshalb habe ich das # entfernt.

Endgültiger Code:
Code:
Private Sub DatenEintragen_Click()
    Dim varItm As Variant
   
    For Each varItm In Me!lstVerladung.ItemsSelected
        CurrentDb.Execute _
           "UPDATE ITRMaster" _
           & " SET container_loading_date = " & Format(Me.txtLadeDat _
                                                     , "\#mm-dd-yyyy\#") _
              & ", Container_no = '" & Me.txtContNo & "'" _
              & ", Seal = '" & Me.txtSeal & "'" _
              & ", Vessel = '" & Me.txtVessel & "'" _
              & ", MBL = '" & Me.txtMBL & "'" _
              & ", container_size = '" & Me.cboContSize & "'" _
         & " WHERE Referenz ='" & Me!lstVerladung.ItemData(varItm) & "'"
    Next varItm
    'Das Listenfeld wird aktualisiert und die gefüllten Textfelder werden wieder auf Null gesetzt
    Me!lstVerladung.Requery
    Me.txtLadeDat = Null
    Me.txtContNo = Null
    Me.cboContSize = Null
    Me.txtVessel = Null
    Me.txtSeal = Null
    Me.txtMBL = Null
End Sub
Es wird eindeutig Zeit um ein paar Grundlagen zu lernen. Ansonsten ist das immer mehr raten warum etwas funktioniert anstatt es zu wissen.

Vielen lieben Dank Marmeladenglas und Blackpit für eure Zeit und bitte entschuldigt meine Ahnungslosigkeit. Ihr habt mir wirklich sehr geholfen!

Viele Grüße
Carsten
Blackpit
Im Profil kannst Du frei den Rang ändern


Verfasst am:
22. Apr 2014, 16:52
Rufname:

AW: mehrere Felder in Listenfeld mit Mehrfachausw. aktualisi - AW: mehrere Felder in Listenfeld mit Mehrfachausw. aktualisi

Nach oben
       Version: Office 2010

Zitat:
Blackpits Vorschläge sind keine Alternativen, sondern Vorgehensweisen den Code übersichtlich zu halten.
In Deinem Fall würde das dann so aussehen:
Code:
Private Sub DatenEintragen_Click()
    Dim varItm As Variant
    Dim strSQL As String
   
    For Each varItm In Me!lstVerladung.ItemsSelected
        strSQL = "UPDATE ITRMaster" _
                 & " SET container_loading_date = " & Format(Me.txtLadeDat _
                                                           , "\#mm-dd-yyyy\#") _
                    & ", Container_no = '" & Me.txtContNo & "'" _
                    & ", Seal = '" & Me.txtSeal & "'" _
                    & ", Vessel = '" & Me.txtVessel & "'" _
                    & ", MBL = '" & Me.txtMBL & "'" _
                    & ", container_size = '" & Me.cboContSize & "'" _
               & " WHERE Referenz ='" & Me!lstVerladung.ItemData(varItm) & "'"
'Debug.Print strSQL   'hier könntest Du den String im Direktfenster zum testen im Abfrageeditor verwenden
         CurrentDb.Execute strSQL, dbFailOnError
    Next varItm
    'Das Listenfeld wird aktualisiert und die gefüllten Textfelder werden wieder auf Null gesetzt
    Me!lstVerladung.Requery
    Me.txtLadeDat = Null
    Me.txtContNo = Null
    Me.cboContSize = Null
    Me.txtVessel = Null
    Me.txtSeal = Null
    Me.txtMBL = Null
End Sub

Gruß

BP
Marmeladenglas
komme zurecht


Verfasst am:
22. Apr 2014, 17:03
Rufname:

AW: mehrere Felder in Listenfeld mit Mehrfachausw. aktualisi - AW: mehrere Felder in Listenfeld mit Mehrfachausw. aktualisi

Nach oben
       Version: Office 2010

Zitat:
die Kombibox Cont_size habe ich ohne Hochkommata eingefügt. Das Feld in der Tabelle ist zwar ein Textfeld, so wie ich es verstanden habe, liefert eine Kombibox aber eine Zahl als Ergebnis.
Das ist Unsinn!!
Einzig entscheidend ist die Festlegung in der Tabelle.
Ein Steuerelementtyp hat keinen Einfluss darauf, welcher Datentyp zurückgegeben wird. Einzig vielleicht beim Kontrollkästchen kann es nur Boolean geben ...
csnb
ich stolpere mich so durch...


Verfasst am:
24. Apr 2014, 12:12
Rufname:

AW: mehrere Felder in Listenfeld mit Mehrfachausw. aktualisi - AW: mehrere Felder in Listenfeld mit Mehrfachausw. aktualisi

Nach oben
       Version: Office 2010

csnb am 22. Apr 2014 um 17:18 hat folgendes geschrieben:
Oh ha...
Mit Hochkommata funktionierte der Code leider nicht.
Das ist das was ich mit raten statt wissen meinte.... ich werde den Beitrag editieren.

Edit: Edit beim fraglichen Beitrag nicht mehr möglich... damit ist der Fehler erst einmal fest eingebaut. Rolling Eyes schade eigentlich.

Hallo nochmal!

Es gibt da noch einen weiteren kleinen Wunsch, bei dem ich an meine Grenzen stoße.
Die Liste ist noch immer die oben behandelte, allerdings soll neben der Aktualisierung von Daten nun auch ein Bericht über diese neuen Informationen per .pdf und Mail gesendet werden.
Dazu habe ich:
- einen Bericht namens rptMeldungVorlauf mit der Abfrage MeldungVorlauf als Datenquelle

Den Code von oben habe ich um eine Abfrage erweitert die eigentlich dem Bericht als Filter dienen soll. Allerdings funktionieren meine Filterversuche nicht.
Code:
Private Sub Vorlaufmeldung_Click()
    Dim varItm As Variant
   
    For Each varItm In Me.lstVorlauf.ItemsSelected
        CurrentDb.Execute _
           "UPDATE ITRMaster" _
           & " SET transport_comment2 = '" & Me.txtVorlaufMeldung & "'" _
           & " WHERE Referenz ='" & Me.lstVorlauf.ItemData(varItm) & "'"
        CurrentDb.QueryDefs!MeldungVorlauf.SQL = "SELECT *" _
                                                & " FROM ITRMaster" _
                                               & " WHERE Referenz = " _
                                            & "Me.lstVorlauf.ItemData(varItm)"
        DoCmd.SendObject acSendReport, "rptMeldungVorlauf" _
                       , "PDF-Format (*.pdf)", "Mail@test.com" _
                       , "Mail@testCC.com", "", "precarriage notice: " _
                       , "Hallo," & vbNewLine & "irgendwas ist ja immer." _
                       , True, ""
    Next varItm
    'Das Listenfeld wird aktualisiert und die gefüllten Textfelder werden wieder auf Null gesetzt
    Me.lstVorlauf.Requery
    Me.txtVorlaufMeldung = Null
End Sub
Wenn ich das richtig sehe, geht es im Prinzip nur um die Zeile
Code:
        CurrentDb.QueryDefs!MeldungVorlauf.SQL = "SELECT *" _
                                                & " FROM ITRMaster" _
                                               & " WHERE Referenz = " _
                                            & "Me.lstVorlauf.ItemData(varItm)"
Wo ist mein Fehler?

Vielen Dank im Voraus!
Marmeladenglas
komme zurecht


Verfasst am:
24. Apr 2014, 12:29
Rufname:

AW: mehrere Felder in Listenfeld mit Mehrfachausw. aktualisi - AW: mehrere Felder in Listenfeld mit Mehrfachausw. aktualisi

Nach oben
       Version: Office 2010

Hi,
es ist immer wieder das gleiche. Du willst eine Variable übergeben, bzw. eine Formularreferenz. Insofern muss diese außerhalb des Strings übergeben werden.
Oben hast es doch richtig gemacht, warum jetzt wieder falsch ?? Smile
csnb
ich stolpere mich so durch...


Verfasst am:
24. Apr 2014, 12:54
Rufname:

AW: mehrere Felder in Listenfeld mit Mehrfachausw. aktualisi - AW: mehrere Felder in Listenfeld mit Mehrfachausw. aktualisi

Nach oben
       Version: Office 2010

Mein erster Versuch sah so aus. Da war ich der Meinung, dass ich nicht so ganz weit von der Wahrheit weg sein kann. Wollte aber nicht.
Code:
        CurrentDb.QueryDefs!MeldungVorlauf.SQL = "SELECT *" _
                                                & " FROM ITRMaster" _
                                               & " WHERE Referenz = '" _
                                        & Me.lstVorlauf.ItemData(varItm) & "'"

Nachtrag: csnb am 24. Apr 2014 um 15:25 hat folgendes geschrieben:
Ich bekomme es leider auch mit try and error nicht hin. Hat jemand noch einen Tipp für mich?
Marmeladenglas
komme zurecht


Verfasst am:
24. Apr 2014, 19:44
Rufname:

AW: mehrere Felder in Listenfeld mit Mehrfachausw. aktualisi - AW: mehrere Felder in Listenfeld mit Mehrfachausw. aktualisi

Nach oben
       Version: Office 2010

Code:
        CurrentDb.QueryDefs("MeldungVorlauf").SQL = "SELECT *" _
                                                   & " FROM ITRMaster" _
                                                  & " WHERE Referenz = '" _
                                        & Me.lstVorlauf.ItemData(varItm) & "'"
csnb
ich stolpere mich so durch...


Verfasst am:
25. Apr 2014, 07:40
Rufname:

AW: mehrere Felder in Listenfeld mit Mehrfachausw. aktualisi - AW: mehrere Felder in Listenfeld mit Mehrfachausw. aktualisi

Nach oben
       Version: Office 2010

oh man... das kommt davon wenn man nicht aufpasst. Die Datenquelle des Berichtes war leider nicht die Abfrage, sondern die Tabelle selbst. Dann kann das ja auch nicht klappen.

Nun aber geht es. Marmeladenglas, vielen Dank für Deine Mühe!
Endgültiger Code:
Code:
Private Sub Vorlaufmeldung_Click()
    Dim varItm  As Variant
    Dim strSQL  As String
   
    For Each varItm In Me.lstVorlauf.ItemsSelected
        strSQL = "UPDATE ITRMaster" _
                 & " SET transport_comment2= '" & Me.txtVorlaufMeldung & "'" _
               & " WHERE Referenz ='" & Me.lstVorlauf.ItemData(varItm) & "'"
        CurrentDb.Execute strSQL, 128 'dbFailOnError
        strSQL = "SELECT *" _
                & " FROM ITRMaster" _
               & " WHERE Referenz = '" & Me.lstVorlauf.ItemData(varItm) & "'"
        CurrentDb.QueryDefs!MeldungVorlauf.SQL = strSQL
        DoCmd.SendObject acSendReport, "rptMeldungVorlauf" _
                       , "PDF-Format (*.pdf)", "Mail@test.com" _
                       , "Mail@testCC.com", "", "precarriage notice: " _
                       , "Hallo," & vbNewLine & "irgendwas ist ja immer." _
                       , True, ""
    Next varItm
    'Das Listenfeld wird aktualisiert und die gefüllten Textfelder werden wieder auf Null gesetzt
    Me.lstVorlauf.Requery
    Me.txtVorlaufMeldung = Null
End Sub
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Diese Seite Freunden empfehlen

Seite 1 von 1
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Access Tabellen & Abfragen: Tabellen-Abfrage mit 'Datum ab' Felder 11 ali.soy 1383 29. Aug 2005, 09:12
ali.soy Tabellen-Abfrage mit 'Datum ab' Felder
Keine neuen Beiträge Access Tabellen & Abfragen: Mehrfachauswahl in Listenfeld als Abfrageparameter möglich? 3 esprene 1395 26. Aug 2005, 14:25
cablit Mehrfachauswahl in Listenfeld als Abfrageparameter möglich?
Dieses Thema ist gesperrt, du kannst keine Beiträge editieren oder beantworten. Access Tabellen & Abfragen: Formular-Abfrage Aktualisieren!? 2 quick30 2096 21. Aug 2005, 14:51
Willi Wipp Formular-Abfrage Aktualisieren!?
Keine neuen Beiträge Access Tabellen & Abfragen: Tabellen erweitern und aktualisieren, bzw. zusammenführen 1 Sharon060370 801 16. Aug 2005, 10:34
lothi Tabellen erweitern und aktualisieren, bzw. zusammenführen
Keine neuen Beiträge Access Tabellen & Abfragen: Verkettung von Inhalten versch.Felder in einer Tabelle 15 haike 1487 27. Jul 2005, 11:56
haike Verkettung von Inhalten versch.Felder in einer Tabelle
Keine neuen Beiträge Access Tabellen & Abfragen: Berechnende Felder aus Formular in Tbl speichern 1 heatseeker 1280 26. Jul 2005, 20:27
jens05 Berechnende Felder aus Formular in Tbl speichern
Keine neuen Beiträge Access Tabellen & Abfragen: Felder addieren dann dividieren gleich Problem 4 Karl-Heinz 3814 13. Jul 2005, 10:04
Karl-Heinz Felder addieren dann dividieren gleich Problem
Keine neuen Beiträge Access Tabellen & Abfragen: AXP: 2Tabellen, Aktualisieren, Berechnung 3 defan 693 03. Mai 2005, 10:19
Willi Wipp AXP: 2Tabellen, Aktualisieren, Berechnung
Keine neuen Beiträge Access Tabellen & Abfragen: Unterformular aktualisieren ?? Häh?? 1 blicki 980 07. März 2005, 23:11
der_Volkmann Unterformular aktualisieren ?? Häh??
Keine neuen Beiträge Access Tabellen & Abfragen: Berechnende Felder in einer Abfrage 1 schnecke 881 23. Nov 2004, 02:20
mapet Berechnende Felder in einer Abfrage
Keine neuen Beiträge Access Tabellen & Abfragen: Suche in Listenfeld 4 Access-Anfänger 673 04. Nov 2004, 11:35
Hilde Suche in Listenfeld
Keine neuen Beiträge Access Tabellen & Abfragen: Summer einzelner Felder mittels Abfrage ???? 1 slow 688 05. Okt 2004, 09:29
TommyK Summer einzelner Felder mittels Abfrage ????
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: Microsoft-Excel Diagramme