Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Spalteneinträge in mehreren Tabellenblättern zusammen zählen
zurück: Markieren von allen Zeilen die der Suche entsprechen weiter: Bedingte Formatierung Ecxel 2007 - leere Zellen Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Feedback Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
steve100
Im Profil kannst Du frei den Rang ändern


Verfasst am:
23. Apr 2013, 13:41
Rufname: Steve

Spalteneinträge in mehreren Tabellenblättern zusammen zählen - Spalteneinträge in mehreren Tabellenblättern zusammen zählen

Nach oben
       Version: Office 2010

Hallo Zusammen,

ich möchte in mehreren Tabellenblättern Einträge zählen.

Bedingungen:
Tabelle x
Spalte C = Wert1
Spalte N = Wert2

Tabellex1
Spalte C = Wert1
Spalte N = Wert2

Die Spalten sind immer die selben. Aber die Namen der Tabellenblätter können variabel sein. Hierzu habe ich auf meinem "Rechenblatt" eine Spalte (Q) in der von Q4 bis Q10 die Namen der Tabellenblätter eingetragen werden können. Meine Formel addiert dann, wenn ein Name eingetragen ist, die entsprechenden Werte zusammen (siehe Auszug mit Addition der Blätter, die in Q4, Q5 und Q6 stehen):


=ZÄHLENWENNS(INDIREKT("'"&Q4&"'!C:C");D18;INDIREKT("'"&Q4&"'!N:N");E15)
+WENN(Q5>0;ZÄHLENWENNS(INDIREKT("'"&Q5&"'!C:C");D18;INDIREKT("'"&Q5&"'!N:N");E15))
+WENN(Q6>0;ZÄHLENWENNS(INDIREKT("'"&Q6&"'!C:C");D18;INDIREKT("'"&Q6&"'!N:N");E15))

Ich habe nicht die ganze Formel eingefügt, da es so eventl. besser zu lesen ist.

Leider drückt meine Formel ordentlich auf die Performance Sad . Hat vielleicht jemand eine Idee, wie ich das eleganter bzw. performanter lösen kann?

Ich brauche keine fertige Lösung. Ich würde mich aber über Hinweise freuen.

Vielen Dank für Eure Mühe und viele Grüße
Steve
shift-del
{Irrtum / Versuch * Glaskugel}


Verfasst am:
23. Apr 2013, 20:10
Rufname: Detlef
Wohnort: Ehemaliges Fabrikgelände


AW: Spalteneinträge in mehreren Tabellenblättern zusammen zä - AW: Spalteneinträge in mehreren Tabellenblättern zusammen zä

Nach oben
       Version: Office 2010

Hallo Steve

Zunächst mal kannst du die Formel noch kürzen. Und dann würde ich nicht die kompletten Spalten durchsuchen, sondern nur den Bereich, der wirklich Daten enthält plus eine Reserve.
Code:
=SUMMENPRODUKT(ZÄHLENWENNS(INDIREKT("'"&INDIREKT("Q4:Q"&3+ANZAHL2(Q4:Q10))&"'!C2:C100");D18;INDIREKT("'"&INDIREKT("Q4:Q"&3+ANZAHL2(Q4:Q10))&"'!N2:N100");E15))


Ein anderes Problem ist INDIREKT(). Diese Funktion ist volatil.
Das läßt sich hier umgehen, in dem in jedem Tabellenblatt die Zählung vorgenommen wird.
Code:
=ZÄHLENWENNS(C2:C100;Tabelle1!D18;N2:N100;Tabelle1!E15)

Auf dem Zusammenfassungs-Blatt wird dann nur noch summiert. Vor dem dem ersten Blatt fügt man ein Blatt mit Namen Start ein und nach dem letzten Blatt fügt man ein Blatt mit Namen Stop ein.

Code:
=SUMME(Start:Stop!A1)

_________________
Wir sehen uns!
... shift-del
Eine Mustertabelle hilft beim Helfen.
Excel Super-Funktionen: VERWEIS(), INDEX(), WAHL()
steve100
Im Profil kannst Du frei den Rang ändern


Verfasst am:
23. Apr 2013, 22:39
Rufname: Steve

AW: Spalteneinträge in mehreren Tabellenblättern zusammen zä - AW: Spalteneinträge in mehreren Tabellenblättern zusammen zä

Nach oben
       Version: Office 2010

Hallo Detlef - shift-del,

sehr sehr GEIL!! Danke schön. Ich bevorzuge die Variante 1. Denn so bleibe ich bei der Tabellenblattanzahl und den Namen absolut flexibel.

Ich habe den zu durchsuchenden Bereich eingeschränkt und das sieht ganz vernünftig aus. Die Performance wurde sichtlich verbessert.

Eine Frage habe ich aber noch:

Wenn ich in der Spalte B die Anzahl nicht leerer Zellen durchsuche, habe ich deine 1. Formel umgeschrieben:

=Anzahl2(INDIREKT("'"&INDIREKT("Q4:Q"&3+ANZAHL2(Q4:Q14))&"'!B4:B5000"))

Wenn ich nur einen Tabellennamen in Q4:Q14 stehen habe, wird korrekt gerechnet. Stehen aber mehr als eine Tabelle in der Spalte, bekomme ich immer nur 1 als Ergbebnis.

Warum funktioniert das nicht mit Anzahl2?

Ich würde mich über eine erneute Rückmeldung freuen.

Viele Grüße
Steve
shift-del
{Irrtum / Versuch * Glaskugel}


Verfasst am:
23. Apr 2013, 22:58
Rufname: Detlef
Wohnort: Ehemaliges Fabrikgelände

AW: Spalteneinträge in mehreren Tabellenblättern zusammen zä - AW: Spalteneinträge in mehreren Tabellenblättern zusammen zä

Nach oben
       Version: Office 2010

Hallo Steve

Zitat:
Warum funktioniert das nicht mit Anzahl2?

INDIREKT() ist ziemlich eigen. Manchmal benötigt man eine Klammer-Funktion wie N() oder T().
Hier hilft das leider nicht. Deshalb ein Workaround:
Code:
=SUMMENPRODUKT(ZÄHLENWENN(INDIREKT("'"&INDIREKT("Q4:Q"&3+ANZAHL2(Q4:Q14))&"'!B4:B5000");"<>"&""))

_________________
Wir sehen uns!
... shift-del
Eine Mustertabelle hilft beim Helfen.
Excel Super-Funktionen: VERWEIS(), INDEX(), WAHL()
steve100
Im Profil kannst Du frei den Rang ändern


Verfasst am:
23. Apr 2013, 23:25
Rufname: Steve


AW: Spalteneinträge in mehreren Tabellenblättern zusammen zä - AW: Spalteneinträge in mehreren Tabellenblättern zusammen zä

Nach oben
       Version: Office 2010

Hallo Detlef - shift-del,

sehr cool.
hier noch einmal das Ergebnis zum Vergleich:

meine Variante:

=WENN(Q4>"";ANZAHL2(INDIREKT("'"&Q4&"'!B4:B5000")))+WENN(Q5>"";ANZAHL2(INDIREKT("'"&Q5&"'!B4:B5000")))+WENN(Q6>"";ANZAHL2(INDIREKT("'"&Q6&"'!B4:B5000")))+WENN(Q7>"";ANZAHL2(INDIREKT("'"&Q7&"'!B4:B5000")))+WENN(Q8>"";ANZAHL2(INDIREKT("'"&Q8&"'!B4:B5000")))+WENN(Q9>"";ANZAHL2(INDIREKT("'"&Q9&"'!B4:B5000")))+WENN(Q10>"";ANZAHL2(INDIREKT("'"&Q10&"'!B4:B5000")))+WENN(Q11>"";ANZAHL2(INDIREKT("'"&Q11&"'!B4:B5000")))+WENN(Q12>"";ANZAHL2(INDIREKT("'"&Q12&"'!B4:B5000")))+WENN(Q13>"";ANZAHL2(INDIREKT("'"&Q13&"'!B4:B5000"))+WENN(Q14>"";ANZAHL2(INDIREKT("'"&Q14&"'!B4:B5000"))))

und nun deine Variante:

=SUMMENPRODUKT(ZÄHLENWENN(INDIREKT("'"&INDIREKT("Q4:Q"&3+ANZAHL2(Q4:Q14))&"'!B4:B5000");"<>"&""))

Hmmm. Maginaler Unterschied Laughing

Vielen Dank für die schnelle Hilfe!
Gruß
Steve
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Diese Seite Freunden empfehlen

Seite 1 von 1
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Excel Formeln: Nummern zählen 9 BernhardK 820 06. Feb 2005, 08:01
BernhardK Nummern zählen
Keine neuen Beiträge Excel Formeln: Argumente in einer Zelle zählen 2 fridgenep 1538 31. Jan 2005, 14:52
fridgenep Argumente in einer Zelle zählen
Keine neuen Beiträge Excel Formeln: text zählen 4 roli 1885 28. Jan 2005, 12:34
Kuwe text zählen
Keine neuen Beiträge Excel Formeln: summenprodukt mit monatsabfrage und mehreren bedingungen 2 Gast 3497 21. Dez 2004, 14:00
Kottan summenprodukt mit monatsabfrage und mehreren bedingungen
Keine neuen Beiträge Excel Formeln: Buchstaben zählen 1 Wilfried 1374 29. Nov 2004, 10:55
steve1da Buchstaben zählen
Keine neuen Beiträge Excel Formeln: Zählen bei Filtersetzung 2 Enjoy82 1254 24. Nov 2004, 16:32
Enjoy82 Zählen bei Filtersetzung
Keine neuen Beiträge Excel Formeln: SUMMEWENN mit mehreren Argumenten - geht dass 3 ExcelFan 1652 22. Nov 2004, 10:54
ExcelFan SUMMEWENN mit mehreren Argumenten - geht dass
Keine neuen Beiträge Excel Formeln: Wenn-Bedingung mit mehreren Spalten und Zeile 6 Lusie 2819 02. Nov 2004, 15:57
Lusie Wenn-Bedingung mit mehreren Spalten und Zeile
Keine neuen Beiträge Excel Formeln: Gelbe Zellen zählen! 6 Axis_Sonnenflieger 4453 27. Okt 2004, 14:50
Axis_Sonnenflieger Gelbe Zellen zählen!
Keine neuen Beiträge Excel Formeln: Buchstaben zählen! 2 Alexslider 1059 21. Okt 2004, 22:28
Gast Buchstaben zählen!
Keine neuen Beiträge Excel Formeln: Suche Formel (zählenwenn mit mehreren Krit - Summenprodukt) 17 akm1978 4080 02. Okt 2004, 23:27
Gast Suche Formel (zählenwenn mit mehreren Krit - Summenprodukt)
Keine neuen Beiträge Excel Formeln: Zahlenblöcke in Spalte zählen?? 2 fendti 1350 30. Sep 2004, 00:35
fendti Zahlenblöcke in Spalte zählen??
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: Expression Web