Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Befehl sperren
zurück: byronic weiter: texteingabefenster Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Bitte Status wählen ! Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
Blackolive
Gast


Verfasst am:
11. Nov 2005, 10:38
Rufname:

Befehl sperren - Befehl sperren

Nach oben
       

Hallo,

ok, mein aktueller Stand:

Ich habe in meinem Excel-Blatt 4 CommandButtons erstellt. Und alles funktioniert wunderbar.
Ein CommandButton bietet die Möglichkeit Zeilen einzufügen und damit meine Tabelle konsistent bleib ist es auch sehr wichtig, dass dieser Button benutzt wird, um eine Zeile einzufügen.
Da man aber auch über Menü-> Einfügen-> Zellen auch eine Zeile einfügen kann sowie über die rechte Maustaste und das meine komplette Arbeit ruinieren würde möchte ich diese Möglichkeit ausschließen, indem das Benutzten dieses Befehls deaktiviert wird, falls das überhaupt möglich ist???

In diesem Forum wurde mir schon sehr geholfen, dafür vielen Dank, jetzt fehlt mir nur noch eine Kleinigkeit, sozusagen der Feinschliff. Wenn das auch noch klappt, dann flipp ich völlig aus vor freude Smile

Grüße
Blackolive
Case
Coder


Verfasst am:
13. Nov 2005, 02:08
Rufname: Case
Wohnort: Schwäbisch Hall


Das kannst du..... - Das kannst du.....

Nach oben
       

Hallo,

erreichen, in dem du über die IDs der Controls gehst. Jeder dieser Einträge hat eine eindeutige ID, inklusive der Einträge im Kontextmenü.

Folgender Code muss in "DieseArbeitsmappe":

Code:
Option Explicit

Private Sub Workbook_Open()
Application.Run "Modul1.Zellen_einfuegen_aus"
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
Application.Run "Modul1.Zellen_einfuegen_ein"
End Sub


Und das in ein allgemeines Modul:

Code:
Option Explicit

Private Sub Zellen_einfuegen_aus()
Call Control_ID_Ein_Aus(295, False)
Call Control_ID_Ein_Aus(296, False)
Call Control_ID_Ein_Aus(3181, False)
End Sub

Private Sub Zellen_einfuegen_ein()
Call Control_ID_Ein_Aus(295, True)
Call Control_ID_Ein_Aus(296, True)
Call Control_ID_Ein_Aus(3181, True)
End Sub

Private Sub Control_ID_Ein_Aus(IDNummer As Long, Wahr_Falsch As Boolean)
Dim cmbAbfrage As CommandBar
Dim cmbElement As CommandBarControl

On Error Resume Next
 
  For Each cmbAbfrage In Application.CommandBars
    Set cmbElement = cmbAbfrage.FindControl(ID:=IDNummer, recursive:=True)
      If Not cmbElement Is Nothing Then cmbElement.Enabled = Wahr_Falsch
  Next

End Sub


Application.Run wegen Private Sub.
Private Sub damit die Makros nicht bei Extras - Makro - Makros... angezeigt werden.

Wenn du folgendes Makro sausen lässt, bekommst du alle IDs vom Kontextmenü der "Zellen":

Code:
Option Explicit

Public Sub Zeige_ID_von_Cell()
Dim myControl As CommandBarControl
Dim intZahl As Integer

intZahl = 1

  For Each myControl In CommandBars("Cell").Controls
    Cells(intZahl, 1) = myControl.ID
    Cells(intZahl, 2) = myControl.Caption
    intZahl = intZahl + 1
  Next

Columns("A:B").AutoFit

End Sub


Und im folgenden die IDs vom Menü "Einfügen":

Code:
Option Explicit

Public Sub Zeige_ID_von_Einfuegen()
Dim myControl As CommandBarControl
Dim intZahl As Integer

intZahl = 1

  For Each myControl In CommandBars("Worksheet Menu Bar").Controls("Einfügen").Controls
    Cells(intZahl, 1) = myControl.ID
    Cells(intZahl, 2) = myControl.Caption
    intZahl = intZahl + 1
  Next

Columns("A:B").AutoFit

End Sub


Servus
Case

_________________
Servus
Case
bernd200
Gast


Verfasst am:
13. Nov 2005, 21:32
Rufname:

AW: Befehl sperren - AW: Befehl sperren

Nach oben
       

Genau diese Lösung habe ich auch gesucht Razz

Eine Frage habe ich noch: Wofür steht die ID 3181? Sie wird bei mir (Excel 2003) nicht aufgelistet.

Bernd
Case
Coder


Verfasst am:
13. Nov 2005, 22:30
Rufname: Case
Wohnort: Schwäbisch Hall

Die ID..... - Die ID.....

Nach oben
       

Hallo,

.. steht für "Zellen einfügen..." aus dem Kontextmenü (rechte Maustaste) im Zellbereich.

Servus
Case

_________________
Servus
Case
bernd200
Gast


Verfasst am:
14. Nov 2005, 12:37
Rufname:


AW: Befehl sperren - AW: Befehl sperren

Nach oben
       

Danke, hat eine Weile gedauert bis Excel mir diese ID rausgerueckt hat. Man sollte die ID 3183 ebenfalls auf False setzen, sonst kann man durch Klick auf den Zeilenkopf eine ganze Zeile markieren und in diesem Context Menue waere schon wieder ein Einfuegen moeglich.

Gruss, Bernd
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Diese Seite Freunden empfehlen

Seite 1 von 1
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Dieses Thema ist gesperrt, du kannst keine Beiträge editieren oder beantworten. Excel Formeln: Sperren von Zellen bei auswahlkreterien 1 Patrick22 177 08. März 2010, 12:48
silex1 Sperren von Zellen bei auswahlkreterien
Keine neuen Beiträge Excel Formeln: Excel Anfänger braucht dringend Hilfe! Welcher Befehl?DB? 10 assy 514 22. Feb 2010, 15:56
assy Excel Anfänger braucht dringend Hilfe! Welcher Befehl?DB?
Keine neuen Beiträge Excel Formeln: Gegenseitige Eingabe sperren 6 EinRatSuchender 606 18. Jul 2009, 13:41
EinRatSuchender Gegenseitige Eingabe sperren
Keine neuen Beiträge Excel Formeln: Formeln sperren - trotz. Eingaben machen und Zellen einfügen 1 sgille 510 16. Jul 2009, 17:30
Gast Formeln sperren - trotz. Eingaben machen und Zellen einfügen
Keine neuen Beiträge Excel Formeln: Tabellenblätter sperren 2 MrHancky 697 25. Jun 2009, 15:34
Gast Tabellenblätter sperren
Keine neuen Beiträge Excel Formeln: Dropdown-Menu soll Felder sperren/markieren/ausfüllen 5 Thandor 2127 23. Apr 2009, 11:08
Gast Dropdown-Menu soll Felder sperren/markieren/ausfüllen
Keine neuen Beiträge Excel Formeln: Befehl à là: MAX((E5-E4):(AS5-AS4)) 6 MatthiasDS 402 22. Apr 2009, 16:39
MatthiasDS Befehl à là: MAX((E5-E4):(AS5-AS4))
Keine neuen Beiträge Excel Formeln: Zellen sperren und automatisch in ein neues Feld verweisen 1 Dancer82 306 19. März 2009, 14:53
Raimund Zellen sperren und automatisch in ein neues Feld verweisen
Keine neuen Beiträge Excel Formeln: Beschriebene Zellen nach Speichern in einem Logbuch sperren. 1 Fish79 1122 27. Jan 2009, 22:32
Fish79 Beschriebene Zellen nach Speichern in einem Logbuch sperren.
Keine neuen Beiträge Excel Formeln: Wenn - Dann Befehl 3 diehappy01 395 11. Dez 2008, 18:21
< Peter > Wenn - Dann Befehl
Keine neuen Beiträge Excel Formeln: Zellen Permanent Sperren Hife ?? 4 yuc 898 07. Dez 2008, 17:42
yuc Zellen Permanent Sperren Hife ??
Keine neuen Beiträge Excel Formeln: Zellen sperren und Textfeld 4 Gast 416 24. Sep 2008, 18:57
Gast Zellen sperren und Textfeld
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: Dreamweaver Forum