Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Mehrere Abfrageergebnisse in Listenfeld, nur Anzahl Datens.
zurück: PivotChart sperren weiter: Prüfen ob Felder gefüllt Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Feedback Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
Alabastar
VBA-Einsteiger


Verfasst am:
05. Jul 2011, 15:33
Rufname: Kai
Wohnort: Bremen

Mehrere Abfrageergebnisse in Listenfeld, nur Anzahl Datens. - Mehrere Abfrageergebnisse in Listenfeld, nur Anzahl Datens.

Nach oben
       Version: Office 2007

Hallo,

ich habe in einer Tabelle die Namen mehrerer Abfragen abgelegt. Ich möchte diese Abfragen nun eine nach der anderen abarbeiten und die Ergebnisse in einem Formular in einer Listbox darstellen. Als Ergebnis soll aber nur die Anzahl der Datensätze angezeigt werden, die in der jeweiligen Abfrage enthalten sind. Am liebsten wäre mir eine Listbox mit 2 Spalten.
1. Spalte: Abfragename aus Tabelle entnommen
2. Spalte: Anzahl der Datensätze aus Abfrage

Ich hab schon versucht, eine weitere Abfrage zu erstellen, die alle anderen Abfragen enthält. Es werden keine Daten angezeigt.

Mit Domanzahl und einzelnen Textfeldern gehts halt, aber da es mit der Ziet immer mehr Abfragen werden, wollte ich das automatisieren.

Ich bräuchte dann nur noch einen neuen Eintrag in der Tabelle der Abfragen, eine entsprechende Abfrage generieren.

Hat jemand eine Idee?

_________________
Gruß
Alabastar
Nouba
nicht ganz unwissend :)


Verfasst am:
05. Jul 2011, 17:16
Rufname:
Wohnort: Berlin

AW: Mehrere Abfrageergebnisse in Listenfeld, nur Anzahl Date - AW: Mehrere Abfrageergebnisse in Listenfeld, nur Anzahl Date

Nach oben
       Version: Office 2007

Hallo,

ein möglicher Ansatz könnte so aussehen.
Code:
Private Sub FillListbox()
  Dim lb       As ListBox
  Dim db       As DAO.Database
  Dim qdf      As DAO.QueryDef
  Dim lCnt     As Long

  On Error GoTo FillListbox_Error

  Set lb = Me("Listenfeldname")   'oder Me.Listenfeldname
  lb.RowSource = vbNullString     'Listfeld leeren
  lb.RowSourceType = "Value List" 'oder in den Eigenschaften Werteliste festlegen
  lb.ColumnCount = 2              'dito für Spaltenanzahl

  Set db = DBEngine(0)(0)
  Set qdf = db.CreateQueryDef("")  'temporäre Abfrage verwenden

  With db.OpenRecordset("SELECT AbfrageFeldnameInTabelle FROM TabellenName", _
                        , dbForwardOnly)
    Do Until .EOF
      'eckige Klammern sind nur notwendig bei verwendeten Leer- bzw. Sonderzeichen
      'im Abfragenamen
      qdf.SQL = "SELECT Count(*) FROM [" & .Fields(0) & "]"
      With qdf.OpenRecordset(dbOpenSnapshot)
        If Not .EOF Then
          lCnt = .Fields(0)
        End If
        .Close
      End With
      lb.AddItem .Fields(0) & ";" & lCnt
      .MoveNext
    Loop
    .Close
  End With
  Set qdf = Nothing
  Set db = Nothing
  Set lb = Nothing

Exit_FillListbox:
  On Error GoTo 0
  Exit Sub

FillListbox_Error:
  MsgBox "Deine Fehlermeldung"
  Resume Exit_FillListbox
End Sub

Private Sub Form_Load()
  Call FillListbox
End Sub

_________________
mit freundlichen Grüssen Nouba

Wenn beim Lesen eines Beitrags der Eindruck entsteht, dass sich der Fragesteller wenig Mühe gegeben hat, so erhöht das nicht unbedingt die Motivation, eine Antwort zu verfassen.
Alabastar
VBA-Einsteiger


Verfasst am:
06. Jul 2011, 10:57
Rufname: Kai
Wohnort: Bremen


AW: Mehrere Abfrageergebnisse in Listenfeld, nur Anzahl Date - AW: Mehrere Abfrageergebnisse in Listenfeld, nur Anzahl Date

Nach oben
       Version: Office 2007

Hallo Nouba,

vielen Dank für die schnelle Reaktion!

Du bist mein(e) Held(in)! Razz

Das war genau das was ich brauchte. Tolles Forum hier!

_________________
Gruß
Alabastar
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Diese Seite Freunden empfehlen

Seite 1 von 1
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Access Tabellen & Abfragen: Anzahl pro Monat ermittlen! 10 Mini84 796 16. Aug 2006, 10:42
Mini84 Anzahl pro Monat ermittlen!
Keine neuen Beiträge Access Tabellen & Abfragen: Bestimmte Anzahl von Dubletten löschen 2 Pogoist 2191 10. Aug 2006, 13:25
Pogoist Bestimmte Anzahl von Dubletten löschen
Keine neuen Beiträge Access Tabellen & Abfragen: DS Anzahl 9 lily 615 13. März 2006, 19:32
jens05 DS Anzahl
Keine neuen Beiträge Access Tabellen & Abfragen: Auswertung nach Zeit und Anzahl der Datensätze 4 langejg 1184 08. März 2006, 04:00
langejg Auswertung nach Zeit und Anzahl der Datensätze
Keine neuen Beiträge Access Tabellen & Abfragen: Anzahl: mind. 2 1 Access-Unerfahrene 484 21. Feb 2006, 15:45
steffen0815 Anzahl: mind. 2
Keine neuen Beiträge Access Tabellen & Abfragen: nur die ersten drei Abfrageergebnisse anzeigen 3 Gloem 1503 17. Feb 2006, 19:12
steffen0815 nur die ersten drei Abfrageergebnisse anzeigen
Keine neuen Beiträge Access Tabellen & Abfragen: Anzahl von Werten in einer Access-Abfrage 3 TobiasM 994 10. Dez 2005, 21:30
jens05 Anzahl von Werten in einer Access-Abfrage
Keine neuen Beiträge Access Tabellen & Abfragen: Anzahl gleiche Einträge einer Tabelle 5 lea 3211 30. Okt 2005, 03:01
reke Anzahl gleiche Einträge einer Tabelle
Keine neuen Beiträge Access Tabellen & Abfragen: Berechnung im Listenfeld anzeigen? 3 Schnoop 804 20. Okt 2005, 08:24
Timbo Berechnung im Listenfeld anzeigen?
Keine neuen Beiträge Access Tabellen & Abfragen: Probleme mit Listenfeld 1 Schnoop 512 17. Okt 2005, 10:04
rita2008 Probleme mit Listenfeld
Keine neuen Beiträge Access Tabellen & Abfragen: Anzahl Datensätze in einer Tabelle bzw. Abfrage 7 Andre5 12034 14. Sep 2005, 11:51
Andre5 Anzahl Datensätze in einer Tabelle bzw. Abfrage
Keine neuen Beiträge Access Tabellen & Abfragen: Anzahl der aktuellen Tage von Lebensjahren berechnen 2 grosseblaueaugen 5447 07. Sep 2005, 11:56
grosseblaueaugen Anzahl der aktuellen Tage von Lebensjahren berechnen
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: Excel Tipps