Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Hilfe mit vorh. DB: DropDownFeld nimmt Abfragewerte nicht !
zurück: ich brauche hilfe zum vb Button klick weiter: Datum speichern Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Feedback Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
PommBaer
Fortgeschrittener Access-Neuling


Verfasst am:
18. Nov 2008, 10:31
Rufname:

Hilfe mit vorh. DB: DropDownFeld nimmt Abfragewerte nicht ! - Hilfe mit vorh. DB: DropDownFeld nimmt Abfragewerte nicht !

Nach oben
       Version: Office 2k (2000)

Hallo zusammen,

habe eine bestehende DB zur Besetzung von Mitarbeitern auf verschiedene Positionen.

Problem:

In einem DropDownFeld sollen alle Namen auftauchen, die im Formular gewählte Kriterien erfüllen.
Die Abfrage liefert beim ausführen die richtigen Namen, nur das DropDownFeld (DDF) gibt folgende Fehlermeldung:
"Syntaxfehler in Abfrageausdruck ... >hier kommt der Quellcode der Abfrage<"

Benötige Access-Profi der sich die DB mal anschaut und evtl. den Fehler findet !!!

Bitte helft mir !!! Komme schon seit Tagen deshalb nicht weiter ...


Versand der DB gepackt per mail.

_________________
EINE RÜCKMELDUNG OB ES FUNKTIONIERT HAT WÄRE SEHR NETT !!!
_______________________________________
Wer will, sucht Möglichkeiten.
Wer nicht will, Gründe.
KlausMz
Moderator Access


Verfasst am:
18. Nov 2008, 10:41
Rufname:
Wohnort: Irgendwo in der Pfalz

AW: Hilfe mit vorh. DB: DropDownFeld nimmt Abfragewerte nich - AW: Hilfe mit vorh. DB: DropDownFeld nimmt Abfragewerte nich

Nach oben
       Version: Office 2k (2000)

Hallo,
Zitat:
Versand der DB gepackt per mail.
Nein, bitte nicht.
Lösungen gehören wie die Probleme ins Forum. Das ist auch der Sinn des Forums.

Zeige hier bitte den SQL Code der Abfrage. Das genügt möglicherweise schon um den Fehler zu finden.

_________________
Gruß
Klaus . . . . . Feedback wäre wünschenswert.
Ich möchte bitte keine unaufgeforderten PN. Fragen bitte im Forum.
PommBaer
Fortgeschrittener Access-Neuling


Verfasst am:
18. Nov 2008, 10:58
Rufname:


AW: Hilfe mit vorh. DB: DropDownFeld nimmt Abfragewerte nich - AW: Hilfe mit vorh. DB: DropDownFeld nimmt Abfragewerte nich

Nach oben
       Version: Office 2k (2000)

Das verstehe ich natürlich.

Die entsprechende Abfrage funktioniert. Den Fehler vermute ich daher im Quellcode des Formulars. Im folgenden Werde ich daher Quellcode der Abfrage und Quellcode des Forms einstellen.

ACHTUNG, sehr ausführlich, warscheinlich nur für erfahrene Knobler geeignet Wink
Abfrage-Code
Code:
SELECT M.PERSNR, M.MANAME
FROM   TBLMASTAMM AS M
       LEFT JOIN tblABWESENHEIT AS A
       ON M.PERSNR=A.PERSNR
WHERE  M.MEISTERSCHAFT=Forms!frmVERFUEGBARKEIT!MEISTERSCHAFT
AND    M.SCHICHT=Forms!frmVERFUEGBARKEIT!SCHICHT
AND    M.EINSATZORT=Forms!frmVERFUEGBARKEIT!EINSATZORT
AND    (A.PERSNR Is Null
OR      Forms!frmVERFUEGBARKEIT!ADATUM Not Between A.VONDATUM
                                               And A.BISDATUM);
Quellcode - Form (abgespeckt)
Code:
Option Compare Database
Option Explicit
Dim MySQL As String
Dim db As DAO.Database
Dim TB As DAO.Recordset
Dim TG As DAO.Recordset

Private Sub EINSATZORT_AfterUpdate()
On Error GoTo FehlerEinsatzort
' Aufruf der Funktion zur Suche der passenden Mitarbeiter -
' in der Funktion selbst wird geprüft, ob alle 4 Kriterien eingegeben sind
    SUCHEMA
EndeEINSATZORT:
    Exit Sub
FehlerEinsatzort:
    MsgBox Err.Number & " " & Err.Description
    Resume EndeEINSATZORT
End Sub

Private Sub EINSATZORT_Dirty(Cancel As Integer)
    AUFBAUGERAET
End Sub

Private Sub Form_Open(Cancel As Integer)
On Error GoTo FehlerOPEN
    Set db = CurrentDb
    Me!BZ5 = ""
    Me!frmMASTAMM.Visible = False
    Me!EINSATZPLANUNG.Visible = False
    Me!GERAETELISTE.Visible = False
    Me!Bezeichnungsfeld65.Visible = False
    Me!Rechteck82.Visible = False
    Me!Linie66.Visible = False
    Me!frmub_VERFUEGBARKEIT.Visible = False
    Me!frmABWESENHEIT.Visible = False
EndeOPEN:
    Exit Sub
FehlerOPEN:
    MsgBox Err.Number & " " & Err.Description
    DoCmd.CancelEvent
    Resume EndeOPEN
End Sub

Private Sub ADATUM_AfterUpdate()
    SUCHEMA
End Sub

Private Sub GERAETELISTE_DblClick(Cancel As Integer)
On Error GoTo FehlerGERAETELISTE
    Dim CTL As Control
    Dim VARELEMENT As Variant
   
    ' Prüfen ob schon ein Mitarbeiter ausgewählt wurde wenn nein,
    ' dann kann kein Gerät zu geordnet werden
    If IsNull(Me!MITARBEITER) Or Me!MITARBEITER = "" Then
        MsgBox "Achtung - Sie haben keinen Mitarbeiter ausgewählt!!", _
               vbCritical, "Prüfen Mitarbeiter"
        Me!MITARBEITER.SetFocus
        Exit Sub
    End If
    ' Prüfen, ob für diesen Mitarbeiter mit diesem Datum bereits ein Gerät
    ' zugeordnet ist - prüfen gegen die Tabelle tblBEREITSTELLUNG
    Set CTL = Me!GERAETELISTE
    For Each VARELEMENT In CTL.ItemsSelected
        Me!GERAETEID = CTL.ItemData(VARELEMENT)
        Me!GERAET = DLookup("GERAET", "tblGERAET", _
                            "GERAETEID = " & Me!GERAETEID)
    Next VARELEMENT
EndeGERAETELISTE:
    Exit Sub
FehlerGERAETELISTE:
    MsgBox Err.Number & " " & Err.Description
    Resume EndeGERAETELISTE
End Sub

Private Sub MEISTERSCHAFT_AfterUpdate()
' Aufruf der Funktion zur Suche der passenden Mitarbeiter
' - in der Funktion selbst wird geprüft, ob alle 4 Kriterien eingegeben sind
    SUCHEMA
End Sub

Private Sub MITARBEITER_AfterUpdate()
On Error GoTo FehlerMITARBEITER
    Set TB = db.OpenRecordset("tbl_BESETZUNG")
    TB.Index = "Primarykey"
    TB.Seek "=", Me!ADATUM, Me!MITARBEITER
    If Not TB.NoMatch Then
        Me!GERAETEID = TB!GERAETEID
        Me!GERAET = DLookup("GERAET", "tblGERAET", _
                            "GERAETEID = " & Me!GERAETEID)
    End If
EndeMITARBEITER:
    TB.Close
    Set TB = Nothing
    Exit Sub
FehlerMITARBEITER:
    MsgBox Err.Number & " " & Err.Description
    Resume EndeMITARBEITER
End Sub

Private Sub SCHICHT_AfterUpdate()
' Aufruf der Funktion zur Suche der passenden Mitarbeiter
' - in der Funktion selbst wird geprüft, ob alle 4 Kriterien eingegeben sind
    SUCHEMA
End Sub


Private Sub SUCHEMA()
On Error GoTo FehlerSUCHEMA
    Dim CHECKGRU As String
' Wenn die Felder Einsatzort, Schicht und ADATUM leer sind, dann nicht nach
' Mitarbeitern suchen, sondern die Function verlassen
    If IsNull(Me!EINSATZORT) Or Me!EINSATZORT = "" Then
        Exit Sub
    End If
    If IsNull(Me!SCHICHT) Or Me!SCHICHT = "" Then
        Exit Sub
    End If
    If IsNull(Me!ADATUM) Or Me!ADATUM = "" Then
        Exit Sub
    End If
    If IsNull(Me!MEISTERSCHAFT) Or Me!MEISTERSCHAFT = "" Then
        Exit Sub
    End If
    Me!GERAETELISTE.Visible = False
    ' Anzeige welche Schicht und welches Lager
    Me!BZ5 = Me!EINSATZORT & ", " & Me!SCHICHT
    Me!MITARBEITER = Null
    Me!GERAETEID = Null
    Me!GERAET = Null
    ' Aufbau des SQL-Befehles zur Suche nach entsprechenden Mitarbeitern
    ' HIER VERMUTE ICH DEN FEHLER !!!!! ######################################
'    MySQL = "SELECT M.PERSNR, M.MANAME" & _
'              "FROM TBLMASTAMM AS M " & _
'                   "LEFT JOIN tblABWESENHEIT AS A " & _
'                   "ON M.PERSNR=A.PERSNR" & _
'             "WHERE M.MEISTERSCHAFT = " & _
'                                  "Forms!frmVERFUEGBARKEIT!MEISTERSCHAFT " & _
'               "AND M.SCHICHT = Forms!frmVERFUEGBARKEIT!SCHICHT " & _
'               "AND M.EINSATZORT = Forms!frmVERFUEGBARKEIT!EINSATZORT " & _
'               "AND (A.PERSNR Is Null " & _
'                "OR Forms!frmVERFUEGBARKEIT!ADATUM Not Between A.VONDATUM " & _
'                                                          "And A!BISDATUM)" & _
'          "ORDER BY M.MANAME;"
    ' Edit by Willi Wipp: Das eine oder andere Leerzeichen hilft sicher!
    MySQL = "SELECT M.PERSNR, M.MANAME " & _
              "FROM TBLMASTAMM AS M " & _
                   "LEFT JOIN tblABWESENHEIT AS A " & _
                   "ON M.PERSNR=A.PERSNR " & _
             "WHERE M.MEISTERSCHAFT = " & _
                                  "Forms!frmVERFUEGBARKEIT!MEISTERSCHAFT " & _
               "AND M.SCHICHT = Forms!frmVERFUEGBARKEIT!SCHICHT " & _
               "AND M.EINSATZORT = Forms!frmVERFUEGBARKEIT!EINSATZORT " & _
               "AND (A.PERSNR Is Null " & _
               "OR Forms!frmVERFUEGBARKEIT!ADATUM Not Between A.VONDATUM " & _
                                                        "And A!BISDATUM) " & _
          "ORDER BY M.MANAME;"
    ' Versorgung der Datenherkunft des Feldes MITARBEITER mit dem SQL-Befehl
    Me!MITARBEITER.RowSource = MySQL
    ' Aktualisierung des Feldes MITARBEITER
    Me!MITARBEITER.Requery
    ' Aktualisierung des UFO'S zur Anzeige der verfügbaren Mitarbeiter
    Me!frmub_VERFUEGBARKEIT.Requery
    ' Abprüfung ob die dem UFO zugrunde liegende Abfrage Treffer gebracht hat
    ' - nur dann wird das UFO sichtbar
    ' Ansosnten wird das Feld BZ4 mit dem Hinweis keine Treffer angezeigt
    If Me!frmub_VERFUEGBARKEIT.Form.Recordset.RecordCount > 0 Then
        Me!frmub_VERFUEGBARKEIT.Visible = True
        Me!BZ4.Visible = False
      Else
        Me!frmub_VERFUEGBARKEIT.Visible = False
        Me!BZ4.Visible = True
    End If
    ' Abfrage ob es Treffer bei den Mitarbeitern gegeben hat
    ' - wenn ja werden nun die entsprechenden Geräte in einer temporären
    ' Tabelle bereit gestellt.
    If Me!frmub_VERFUEGBARKEIT.Form.Recordset.RecordCount > 0 Then
        ' Aufruf der Funktion zur Bereitstellung der Geräte
        ' - könnte man auch gleich hier weiter programmieren aber wegen
        ' der Übersichtlichkeit eine eigene Funktion!!
        AUFBAUGERAET
    End If
    Me!frmub_VERFUEGBARKEIT1.Visible = True
EndeSUCHEMA:
    Exit Sub
FehlerSUCHEMA:
    MsgBox Err.Number & " " & Err.Description
    Resume EndeSUCHEMA
End Sub


Private Sub AUFBAUGERAET()
On Error GoTo FehlerAUFBAUGERAET
    ' Löschen des Inhaltes der Tabelle tblTEMPGERAET
    ' Ausschalten der ACCESS-Warnmeldungen
    ' - "sie wollen soundsoviele Datensätze löschen
    DoCmd.SetWarnings False
    ' Running SQl-Befehl - löschen des Inhaltes der Tabelle tblTEMPGERAET
    DoCmd.RunSQL "DELETE * FROM tblTEMPGERAET;"
    ' Running SQL-Befehl einfügen aller Geräte die verfügbar sind aus der
    ' Tabelle tblGERAET in die Tabelle tblTEMPGERAET
    DoCmd.RunSQL "INSERT INTO tblTEMPGERAET " & _
                      "( GERAETEID, GERAET ) " & _
                 "SELECT GERAETEID, GERAET " & _
                   "FROM tblGERAET " & _
                  "WHERE VERFUEGBAR=True " & _
                    "AND GERAETEORT = EINSATZORT;"
    ' Einschalten der ACCESS-Warnmeldungen
    DoCmd.SetWarnings True
    ' Nun muss geprüft werden, welche Geräte für diesen Tag schon zugeordnet
    ' sind - die dürfen dann nicht mehr in der Liste der Verfügbaren Geräte
    ' auftauchen!!
    ' Man möchte ja auch mal Pause machen bei der Zuordnung oder muss die
    ' Maske verlassen um was anderes zu tun!!
    Set TB = db.OpenRecordset("tbl_BESETZUNG")
    TB.Index = "Primarykey"
    TB.Seek ">=", Me!ADATUM
    If TB.NoMatch Then GoTo OHNETB
    Do Until TB.EOF
        ' Alle Datensaätze aus der Tabelle tbl_BESETZUNG lesen bis das
        ' End-of-File (EOF) erreicht ist!!
        If TB!BDATUM <> Me!ADATUM Then Exit Do
        DoCmd.SetWarnings False
        ' das ensprechende Gerät wird aus der Tabelle tblTEMPGERAET = zur
        ' Verfügung stehende Geräte gelöscht
        DoCmd.RunSQL "DELETE * FROM tblTEMPGERAET " & _
                      "WHERE GERAETEID = " & TB!GERAETEID & ";"
        DoCmd.SetWarnings True
        TB.MoveNext
    Loop
OHNETB:
    ' Aktualisieren des Listenfeldes
    Me!GERAETELISTE.Requery
    ' Anzeige eines Listenfeldes auf der Maske mit den zur Verfügung
    ' stehenden Geräten
    Me!GERAETELISTE.Visible = True
EndeAUFBAUGERAET:
    TB.Close
    Set TB = Nothing
    Exit Sub
FehlerAUFBAUGERAET:
    If Err = 3021 Then
        Resume OHNETB
    End If
    MsgBox Err.Number & " " & Err.Description
    Resume EndeAUFBAUGERAET
End Sub

Private Sub SPEICHERN_Click()
On Error GoTo Err_SPEICHERN_Click
    ' Speichern der Gerätezuordnung in der Tabelle tblBEREITSTELLUNG
    ' Prüfen ob die notwendigen Felder gefüllt sind
    If IsNull(Me!MITARBEITER) Or Me!MITARBEITER = "" Then
        MsgBox "Achtung - Sie haben keinen Mitarbeiter eingegeben", _
               vbCritical, "Prüfen Mitarbeiter"
        Me!MITARBEITER.SetFocus
        Exit Sub
    End If
    If IsNull(Me!GERAETEID) Or Me!GERAETEID = "" Then
        MsgBox "Achtung - Sie haben kein Gerät zugeordnet", vbCritical, _
               "Prüfen Mitarbeiter"
        Me!MITARBEITER.SetFocus
        Exit Sub
    End If
    If IsNull(Me!ADATUM) Or Me!ADATUM = "" Then
        MsgBox "Achtung - Sie haben kein Datum eingegeben", vbCritical, _
               "Prüfen Datum"
        Me!ADATUM.SetFocus
        Exit Sub
    End If
    ' Bereitstellung der Tabelle tblBEREITSTELLUNG - das folgende könnte
    ' man auch mit einem Insert-Befehl in SQL ausführen
    Set TB = db.OpenRecordset("tbl_BESETZUNG")
    TB.Index = "Primarykey"
    Set TG = db.OpenRecordset("tblTEMPGERAET")
    TG.Index = "Primarykey"
    ' Lesen ob für den Mitarbeiter für das Datum bereit ein Datensatz in der
    ' Tabelle tbl_BESETZUNG gespeichert ist
    TB.Seek "=", Me!ADATUM, Me!MITARBEITER
    If TB.NoMatch Then
        ' Wenn der Datensatz nicht gespeichert ist, wird ein neuer Datensatz
        ' angelegt
        TB.AddNew
        ' Das ausgewählte Gerät wird aus der Tabelle der zur Verfügung
        ' stehenden Geräte gelöscht - deshalb eine temporäre tabelle die
        ' immer aus der Geräte-Tabelle aufgebaut wird
        TG.Seek "=", Me!GERAETEID
        If Not TG.NoMatch Then
            TG.Delete
            ' Das Listenfeld wird upgedatet damit der aktuelle Stand
            ' angezeigt wird!!
            Me!GERAETELISTE.Requery
        End If
      Else
        ' Wenn der Datensatz exisitert kann er geändert werden
        TB.Edit
    End If
    TB!BDATUM = Me!ADATUM
    TB!PERSNR = Me!MITARBEITER
    TB!GERAETEID = Me!GERAETEID
    ' Schreiben des neuen Satzes oder der Änderung in die Tabelle tbl_BESETZUNG
    TB.Update
    ' Maskenfelder löschen
    Me!MITARBEITER = Null
    Me!GERAETEID = Null
    Me!GERAET = Null
    Me!MITARBEITER.SetFocus
Exit_SPEICHERN_Click:
    ' Datenbanktabelle schliessen
    TB.Close
    TG.Close
    ' Aufräumen
    Set TB = Nothing
    Set TG = Nothing
    Exit Sub
Err_SPEICHERN_Click:
    MsgBox Err.Description
    Resume Exit_SPEICHERN_Click
End Sub

Private Sub LOESCHEN_Click()
On Error GoTo Err_LOESCHEN_Click
    ' Speichern der Gerätezuordnung in der Tabelle tblBEREITSTELLUNG
    ' Prüfen ob die notwendigen Felder gefüllt sind
    If IsNull(Me!MITARBEITER) Or Me!MITARBEITER = "" Then
        MsgBox "Achtung - Sie haben keinen Mitarbeiter eingegeben", _
               vbCritical, "Prüfen Mitarbeiter"
        Me!MITARBEITER.SetFocus
        Exit Sub
    End If
    If IsNull(Me!GERAETEID) Or Me!GERAETEID = "" Then
        MsgBox "Achtung - Sie haben kein Gerät zugeordnet", vbCritical, _
               "Prüfen Mitarbeiter"
        Me!MITARBEITER.SetFocus
        Exit Sub
    End If
    If IsNull(Me!ADATUM) Or Me!ADATUM = "" Then
        MsgBox "Achtung - Sie haben kein Datum eingegeben", vbCritical, _
               "Prüfen Datum"
        Me!ADATUM.SetFocus
        Exit Sub
    End If
    ' Bereitstellung der Tabelle tblBEREITSTELLUNG - das folgende könnte man
    ' auch mit einem Delete-Befehl in SQL ausführen
    Set TB = db.OpenRecordset("tbl_BESETZUNG")
    TB.Index = "Primarykey"
    Set TG = db.OpenRecordset("tblTEMPGERAET")
    TG.Index = "Primarykey"
    ' Lesen ob für den Mitarbeiter für das Datum dieser Datensatz in der
    ' Tabelle tbl_BESETZUNG gespeichert ist
    TB.Seek "=", Me!ADATUM, Me!MITARBEITER
    If TB.NoMatch Then
        MsgBox "Achtung - der Datensatz kann nicht gelesen werden - eine " & _
               "Löschung ist nicht möglich!!", vbCritical, _
               "Löschen Gerätezuordnung"
        Me!MITARBEITER.SetFocus
        Exit Sub
    End If
    ' Löschen des Datensatzes
    TB.Delete
    ' Nun muss das Gerät wieder verfügbar gemacht werden und die Anzeige der
    ' Geräteliste aktualisiert werden
    ' Wegen der Übersichtlichkeit und weil man es beim Ändern der Zuordnung
    ' Mitarbeiter/Gerät auch braucht wird dies in einer eigenen Funktion
    ' erledigt
    RUECKFUEHRUNGGERAET Me!GERAETEID
    Me!MITARBEITER = Null
    Me!GERAETEID = Null
    Me!GERAET = Null
Exit_LOESCHEN_Click:
    TB.Close
    TG.Close
    Set TB = Nothing
    Set TG = Nothing
    Exit Sub
Err_LOESCHEN_Click:
    MsgBox Err.Description
    Resume Exit_LOESCHEN_Click
End Sub

Private Sub RUECKFUEHRUNGGERAET(GID As Long)
On Error GoTo FehlerRFG
    If IsNull(GID) Or GID = 0 Then Exit Sub
    '   Hier als Beispiel mal als SQL-Befehl
    MySQL = "INSERT INTO tblTEMPGERAET " & _
                 "( GERAETEID, GERAET ) " & _
            "SELECT GERAETEID, GERAET " & _
              "FROM tblGERAET " & _
             "WHERE GERAETEID=" & GID & ";"
    ' Hier mal mit einem besonderen befehl - es würde auch DoCmd.RunSQL
    ' (Mysql) gehen
    CurrentDb.Execute MySQL
    ' Aktualisieren der Anzeige der Verfügbaren Geräte
    Me!GERAETELISTE.Requery
EndeRFG:
    Exit Sub
FehlerRFG:
    MsgBox Err.Number & " " & Err.Description
    Resume EndeRFG
End Sub

PommBaer am 18. Nov 2008 um 10:38 hat folgendes geschrieben:
Problem gelöst:

im Sub SUCHEMA fehlten in den SQL-Anweisungen ein paar leerzeichen...

_________________
EINE RÜCKMELDUNG OB ES FUNKTIONIERT HAT WÄRE SEHR NETT !!!
_______________________________________
Wer will, sucht Möglichkeiten.
Wer nicht will, Gründe.
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Diese Seite Freunden empfehlen

Seite 1 von 1
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Access Formulare: Register Element nimmt keine neuen Steuerelemente an 2 FrohnKd 90 15. Nov 2013, 18:21
MissPh! Register Element nimmt keine neuen Steuerelemente an
Keine neuen Beiträge Access Hilfe: Feld nimmt am Anfang kein Null an 2 Gast 86 21. Okt 2013, 22:46
Gast Feld nimmt am Anfang kein Null an
Keine neuen Beiträge Access Programmierung / VBA: Drop-Down-Feld Standardwert einstellen 12 Ansgi 313 02. Nov 2012, 07:33
Ansgi Drop-Down-Feld  Standardwert einstellen
Keine neuen Beiträge Access Formulare: Wenn DropdownFeld, dann kopiere Wert aus Feld2 in Feld 3. 8 Shawn 500 28. Feb 2011, 20:55
Shawn Wenn DropdownFeld, dann kopiere Wert aus Feld2 in Feld 3.
Keine neuen Beiträge Access Formulare: Entfernen einer leeren Zeile im Drop-Downfeld - Möglich? 9 Mario 13 298 11. Jan 2011, 15:00
Mario 13 Entfernen einer leeren Zeile im Drop-Downfeld - Möglich?
Keine neuen Beiträge Access Hilfe: Abfragewerte in mehrere Dateien und Blätter schreiben 4 holgi71 395 27. Jul 2010, 20:32
Gast Abfragewerte in mehrere Dateien und Blätter schreiben
Keine neuen Beiträge Access Hilfe: Dropdownfeld mit anderen Feldern verbinden 1 Gl05e 709 26. Mai 2010, 17:48
kyron9000 Dropdownfeld mit anderen Feldern verbinden
Keine neuen Beiträge Access Formulare: Abhängiges Dropdownfeld 3 zetec81 294 02. Feb 2010, 09:21
zetec81 Abhängiges Dropdownfeld
Keine neuen Beiträge Access Formulare: Wert aus Dropdownfeld in ein Textfeld schreiben 18 Ugeen 1512 23. Sep 2009, 15:38
Ugeen Wert aus Dropdownfeld in ein Textfeld schreiben
Keine neuen Beiträge Access Hilfe: suche Hilfe um eine vorh. Datenbank zu modifizieren !! 2 silversurferrt 284 19. März 2009, 11:17
silversurferrt suche Hilfe um eine vorh. Datenbank zu modifizieren !!
Keine neuen Beiträge Access Formulare: Abfragewerte in Quicktipps anzeigen, möglich?? 2 Andre S. 281 20. Nov 2008, 09:32
Gast Abfragewerte in Quicktipps anzeigen, möglich??
Keine neuen Beiträge Access Formulare: Datensatznavigation per Dropdown-Feld 2 404Error 999 11. Aug 2008, 09:28
404Error Datensatznavigation per Dropdown-Feld
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: Microsoft-Excel Diagramme