Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
fortlaufende Nummerierung im Unterformular
Gehe zu Seite 1, 2  Weiter
zurück: Kontextmenu (Standard mit Kopieren und Einfügen) weiter: Suche eine Idee für eine Lizenzschlüsselgenerierung Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Antwort Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
dimei
Probierer


Verfasst am:
29. Okt 2008, 21:59
Rufname: meise
Wohnort: Gera

fortlaufende Nummerierung im Unterformular - fortlaufende Nummerierung im Unterformular

Nach oben
       Version: Office 2003

Hallo zusammen,

ich habe ein Formular mit einem Unterformular.
das Unterformular ist ein Endlosformular.
Beim Anlegen eines neuen Datensatzes soll nun ein Feld dieses Datensatzes mit einer fortlaufenden Nummer gefüllt und auch in der zugrunde liegenden tabelle gespeichert werden.
Bei jedem neuen Datensatz im Hauptformular soll diese fortlaufende Nummer immer wieder bei 1 anfangen.
Springt man dann wieder zurück in den vorhergehenden Datensatz im Hauptformular, muß dort natürlich die Nummerierung weitergeführt werden, falls man da noch einen Datensatz anfügt.

Schön wäre auch eine Zusatzfunktion diese Nummerierung zu ändern. zb. die letzte Position auf die 1. umzusetzen und den Rest dann nach hinten zu schieben. Also wenn Pos. 5 zu Pos. 1 wird muß die alte Nr. 1 auf die Pos.2 geschoben werden usw.

Geht das zu lösen ?
Marmeladenglas
komme zurecht


Verfasst am:
30. Okt 2008, 09:09
Rufname:


AW: fortlaufende Nummerierung im Unterformular - AW: fortlaufende Nummerierung im Unterformular

Nach oben
       Version: Office 2003

hi,
ein erster Ansatz könnte vielleicht so etwas sein.



Fortlaufend.zip
 Beschreibung:

Download
 Dateiname:  Fortlaufend.zip
 Dateigröße:  30.59 KB
 Heruntergeladen:  157 mal

dimei
Probierer


Verfasst am:
31. Okt 2008, 18:45
Rufname: meise
Wohnort: Gera

AW: fortlaufende Nummerierung im Unterformular - AW: fortlaufende Nummerierung im Unterformular

Nach oben
       Version: Office 2003

dimei am 30. Okt 2008 um 15:07 hat folgendes geschrieben:
Hallo Marmeladenglas,

genau so ist das ein sehr guter Ansatz. Aber wie bekomme ich jetzt noch die Pos-Nr. in der Tabelle gespeichert?

Und ist es machbar die Pos.Nr. zu ändern, d.h. den Datensatz beliebig nach oben oder unten zu verschieben?

Danke schon mal im voraus.

Hallo zusammen,

hab jetzt den halben Tag probiert.
komme leider keinen Schritt weiter. Hat jemand eine Idee?
hab schon eine oracledatenbank gesehen wo das so funktioniert.
da gibt es einen button der heißt "versetzen" der öffnet ein kleines formular mit 2 Feldern. eins heißt momentane Position, das 2. heißt "verschieben auf Position". damit ändert man dann im endlosformular die Position des Datensatzes.
sollte das mit acces nicht auch gehen ?

Gruß

Dimei
Martin1000
Gast


Verfasst am:
01. Nov 2008, 21:19
Rufname:

AW: fortlaufende Nummerierung im Unterformular - AW: fortlaufende Nummerierung im Unterformular

Nach oben
       Version: Office 2003

Hi,

nachstehende Lösung ist für das Unterformular

im Ereigniss "Vor Aktualiserung"
Code:
    'Wenn noch kein DS vorhanden ist, muss auch keine Prüfung erfolgen
    If lngDCount > 0 Then
        Select Case Nz(Me!range_int.OldValue, 0)
          Case 0                            'Es handelt sich um einen neuen DS
            If Me!range_int = lngDCount + 1 Then
                                       'Die Rangfolge muss nur geprüft werden,
                                    'wenn der neue DS nicht im Rang anschließt
                                              '(letzer DS = 10 --> neuer = 12)
                lngDCount = lngDCount + 1          'Der neue DS ist noch nicht
                          'vorhanden, daher Erhöhung des Zählers um einen Wert
              Else
                SetNewRange
            End If
          Case Me!range_int                   'Wenn der alte Wert = neuer Wert
                                           'soll die Prüfung verhindert werden
          Case Else
            SetNewRange                        'Eine Rangprüfung muss erfolgen
                                     'Es handelt sich um einen alten DS der im
                                                    'Rang verändert worden ist
        End Select
      Else
        lngDCount = lngDCount + 1       'Der neue DS ist noch nicht vorhanden,
                                                 'daher Erhöhung um einen Wert
    End If
    'Datensatzanzahl als neue Vorgabewert setzen
    Me!range_int.DefaultValue = lngDCount + 1
und dann habe ich noch diese Funktion im Formular
Code:
Private Sub SetNewRange()
    Dim db As DAO.Database
    Dim rs As DAO.Recordset
    Dim strSQL As String
    Dim lngMajorID As Integer
    Dim lngNoID As Long
    Dim intNoRange As Integer
    Dim intMaxRange As Integer
    Dim i As Integer
   
    i = 0
    lngMajorID = Me!major_ID_lng   'Die Parent ID bei dir die ID des Haupt-Frm
    lngNoID = Me!scope_ID                   'Die ID des gerade bearbeiteten DS
    intMaxRange = DCount("[scope_ID]", "tbl_scope", _
                         "[major_ID_lng]=" & lngMajorID)
    intNoRange = Me!range_int
    strSQL = "SELECT * FROM tbl_scope " & _
              "WHERE scope_ID<>" & lngNoID & " " & _
                "AND major_ID_lng=" & lngMajorID & " " & _
           "ORDER BY range_int"
    Set db = CurrentDb
    Set rs = db.OpenRecordset(strSQL, dbOpenDynaset)
    rs.FindFirst "scope_ID Is Not Null"
    If rs.NoMatch = False Then
        rs.MoveLast
        rs.MoveFirst
        Do While Not rs.EOF
            i = i + 1
            If i <> intNoRange Then
                With rs
                    .Edit
                    .Fields("range_int") = i
                    .Update
                End With
              Else
                i = i + 1
                With rs
                    .Edit
                    .Fields("range_int") = i
                    .Update
                End With
            End If
            rs.MoveNext
        Loop
    End If
    rs.Close
    Set rs = Nothing
    Set db = Nothing
End Sub
Sieht etwas kaotisch aus, ich wollt mich da auch schon mal drum kümmern es zu kürzen, -->leider Zeit!!!<--

Es funktioniert aber nun schon seit 3 Wochen im Einsatz.
Mit der Lösung kann der Nutzer die Nummern beliebig im Unterformular ändern. Es erfolgt dann ein Prüfung im Hintergrund und baut die Folge wieder auf.

Beispiel

1. DS Nr. 1
2. DS Nr. 2
3. DS Nr. 3

neuer DS Nr. 2

dann

1. DS Nr. 1
neuer DS
2. DS Nr. 3
3. DS Nr. 4
dimei
Probierer


Verfasst am:
02. Nov 2008, 09:40
Rufname: meise
Wohnort: Gera


AW: fortlaufende Nummerierung im Unterformular - AW: fortlaufende Nummerierung im Unterformular

Nach oben
       Version: Office 2003

Hallo Martin1000,

ich hab es gerade mal eingebaut. Funktioniert bei mir aber irgendwie nicht. Crying or Very sad
Die Namen der Felder hab ich auf meinen Feldnamen angepassst.
Das einzigste was ich noch nicht zuordnen kann ist " lngDCount".
Welche Bedeutung hat das und muß ich das erst noch als variable deklarieren.

Sorry für die blöde Frage, bin aber leider alles andere als fit in VBA.

Gruß

Dimei
Martin1000
Gast


Verfasst am:
03. Nov 2008, 05:00
Rufname:

AW: fortlaufende Nummerierung im Unterformular - AW: fortlaufende Nummerierung im Unterformular

Nach oben
       Version: Office 2003

Hallo,

ich habe das gleich mal umgebaut, muss es ja sowieso früher oder später machen.

Erstell bitte ein neues Modul und übernehme folgende Zeilen:
Code:
Public Function SetNewRange(CURRENTDATAID As Long, _
                            PARENTID As Long, _
                            RANGEVALUE As Long, _
                            RANGEOLDVALUE As Long, _
                            FIELDNAMEOFDATAID As String, _
                            FIELDNAMEOFPARENTID As String, _
                            FIELDNAMEOFRANGE As String, _
                            NAMEOFTABLE As String, _
                            RANGESTEPS As Integer)
On Error GoTo SubError
    Dim db As DAO.Database
    Dim rs As DAO.Recordset
    Dim strSQL As String
    Dim i As Integer
    Dim lngDCount As Long
   
    strSQL = "SELECT * FROM " & NAMEOFTABLE & " " & _
              "WHERE " & FIELDNAMEOFDATAID & "<>" & CURRENTDATAID & " " & _
                "AND " & FIELDNAMEOFPARENTID & "=" & PARENTID & " " & _
           "ORDER BY " & FIELDNAMEOFRANGE
    Set db = Application.CurrentDb
    Set rs = db.OpenRecordset(strSQL, dbOpenDynaset)
    'Datensätze einmal durchlaufen um die Anzahl zu ermitteln
    rs.MoveLast: rs.MoveFirst
    If CURRENTDATAID = 0 Then                 'alle Datensätze neu nummerieren
        GoTo JUMP
    End If
    lngDCount = rs.RecordCount + 1
    'Wenn noch kein DS vorhanden ist, muss auch keine Prüfung erfolgen
    If lngDCount Then
        If RANGEOLDVALUE = 0 Then           'Es handelt sich um einen neuen DS
            Select Case RANGEVALUE
              Case lngDCount             'Die Rangfolge muss nur geprüft werden,
                Exit Function         'wenn der neue DS nicht im Rang anschließt
              Case Is > lngDCount
                MsgBox "Bitte prüfen Sie ihre Eingaben der Rangfolge," & _
                       vbCrLf & "da Sie einen gößere Zahl als " & _
                       lngDCount & " angegeben haben!", _
                       vbInformation + vbOKOnly, "Rangfolge"
              Case Is < lngDCount  'Ein neuer DS wurde auf einen besetzen Rang
                GoTo JUMP                                            'gestellt
            End Select
         Else
JUMP:
            'Wenn der alte Wert = neuer Wert
            If RANGEVALUE = RANGEOLDVALUE Then
                 Exit Function             'soll die Prüfung verhindert werden
            End If
            'Es handelt sich um einen alten DS der im Rang verändert
            'worden ist
            i = 0
            Do While Not rs.EOF
                'Schrittweises erhöhen z.B. 1 oder 10er Schritte
                i = i + RANGESTEPS
                Debug.Print "4." & i & " wird bearbeitet"
                'Solang Rang ungleich bearbeiteter Datensatz
                If i <> RANGEVALUE Then
                    With rs                     'den Rang schrittweise erhöhen
                        .Edit
                        .Fields(FIELDNAMEOFRANGE) = i
                        .Update
                    End With
                  Else
                    'Wenn der Rang dem bearbeiten DS entspricht um einen
                    'Schritt erhöhen bzw. überspringen des Rang
                    i = i + RANGESTEPS
                    With rs
                        .Edit
                        .Fields(FIELDNAMEOFRANGE) = i
                        .Update
                    End With
                End If
                rs.MoveNext
            Loop
        End If
    End If
    rs.Close
    Set rs = Nothing
    Set db = Nothing
    Exit Function
SubError:
   MsgBox Err.Number & " " & Err.Description & vbCrLf & _
          "im Sub --SetNewRange--", vbCritical + vbOKOnly
   Debug.Print Err.Number & " " & Err.Description & vbCrLf & _
               "im Sub --SetNewRange--", vbCritical + vbOKOnly
End Function
In deinem Unterformular im Ereigniss "Vor Aktualisierung" muss dann folgendes rein:
Code:
    SetNewRange Feldmit_ID_desbearbeitetenDS, _
                Feldmit_ID_desbeiDirHauptformular, _
                FeldmitRangdesbearbeitetenDS, _
                Nz(Me!wievorher.OldValue, 0), _
                "FeldNamedes_ID-FeldesinderTabelle", _
                "FeldNamedes_linked-FeldesinderTabelle", _
                "FeldNamederRängeinderTabelle", _
                "NamederTabelle", Schrittfolge '1, 10, 100
So siehts doch gleich etwas übersichtlicher aus.

Schönen guten Morgen
dimei
Probierer


Verfasst am:
03. Nov 2008, 22:54
Rufname: meise
Wohnort: Gera

AW: fortlaufende Nummerierung im Unterformular - AW: fortlaufende Nummerierung im Unterformular

Nach oben
       Version: Office 2003

Hallo Martin1000,

jetzt hast du mich total verwirrt. Welche Namen muß denn jetzt anpassen, damit es zu meiner Datenbank passt?

ich hab jetzt bei "vor aktuallisierung" die namen der Felder geändert.
Feldmit_ID_desbearbeitetenDS, _(Id des Unterformulars?)
Feldmit_ID_desbeiDirHauptformular, _(iD des Hauptformulars?)
FeldmitRangdesbearbeitetenDS, _(mein Feld Position?)
Nz(Me!wievorher.OldValue, 0), _(wievorher = Position ?)
"FeldNamedes_ID-FeldesinderTabelle", _(id Unterformular?)
"FeldNamedes_linked-FeldesinderTabelle", _(weiß ich nicht was du meinst?)
"FeldNamederRängeinderTabelle", _(Position?)
"NamederTabelle", Schrittfolge '1, 10, 100(tblunter? so heißt die Tabelle des UF)

was muß ich im : Public Function SetNewRange noch ändern ?

Sorry, aber bin ggf. doch zu blöd für VBA.

Danke schon mal für deine bisherige Geduld.

Gruß

Dimei
Gast



Verfasst am:
05. Nov 2008, 20:58
Rufname:

AW: fortlaufende Nummerierung im Unterformular - AW: fortlaufende Nummerierung im Unterformular

Nach oben
       Version: Office 2003

Sorry,

konnte die letzen Tage nichts posten, da verhindert!

-ID Feld im Uformular (Feld1) von dem Feld der Name in der tblunter(Name1)
-Verknüpftes Feld zum Hformular (Feld2) von dem Feld der Name in der tblunter(Name2)
-Feld mit Positionen (Feld3) von dem Feld der Name in der tblunter(Name3)
Code:
    SetNewRange Me!Feld1, Me!Feld2, Me!Feld3, Nz(Me!Feld3.OldValue, 0), _
                "Name1", "Name2", "Name3", "tblunter", 1
So dann schau mal Wink

Viel Spaß
dimei
Probierer


Verfasst am:
09. Nov 2008, 21:07
Rufname: meise
Wohnort: Gera

AW: fortlaufende Nummerierung im Unterformular - AW: fortlaufende Nummerierung im Unterformular

Nach oben
       Version: Office 2003

Hallo Martin1000,

konnte jetzt leider auch einige Tage nichts machen.
ich bekomme das irgendwie trotzdem nicht hin Confused .
kannst du bitte mal einen Beispieldatenbank reinstellen, damit ich mir das mal ansehen kann.

Ich hab jetzt aller Felder angepasst, aber es kommt noch nicht mal eine Fehlermeldung. Es passiert einfach gar nichts Shock .

Sorry, wenn ich nerve.

Gruß

Dimei
Willi Wipp
Moderator


Verfasst am:
09. Nov 2008, 21:33
Rufname:
Wohnort: Raum Wiesbaden

Re: fortlaufende Nummerierung im Unterformular - Re: fortlaufende Nummerierung im Unterformular

Nach oben
       Version: Office 2003

Hi dimei,

wie waere es wenn Du eine auf das Wesentliche reduzierte Beispiel-DB mit vollstaendig anonymisierten
und repraesentative Demo-Daten online stellst, die Deine aktuellen Stand zeigt?

_________________
Eine kurze Rueckmeldung waere nett
SL Willi Wipp

(Anleitung fuer das Anhaengen von Dateien: Klicke links auf [www], Gaeste muessen sich dafuer anmelden)
Gast



Verfasst am:
10. Nov 2008, 11:53
Rufname:

AW: fortlaufende Nummerierung im Unterformular - AW: fortlaufende Nummerierung im Unterformular

Nach oben
       Version: Office 2003

Sorry,

war in der Nacht etwas übereilig mit dem reinstellen, das größer als 1 fehlte hier Embarassed , daher bekommst du auch keine Fehlermeldung

If lngDCount > 1Then

Müsste jetzt aber gehen!
dimei
Probierer


Verfasst am:
10. Nov 2008, 20:00
Rufname: meise
Wohnort: Gera

AW: fortlaufende Nummerierung im Unterformular - AW: fortlaufende Nummerierung im Unterformular

Nach oben
       Version: Office 2003

Hallo Willi Wipp, Hallo Martin1000,

habe mich soeben angemeldet für den Dateiupload.
Stelle dann eine DB ein.

Ihr findet bestimmt meine "Anfänger"-Fehler Sad

Danke für Eure Geduld mit einem Nichtwissenden.

Gruß

Dimei
boyfrawag
Anfänger


Verfasst am:
11. Nov 2008, 22:09
Rufname: Frank
Wohnort: Neustadt/Weinstraße

AW: fortlaufende Nummerierung im Unterformular - AW: fortlaufende Nummerierung im Unterformular

Nach oben
       Version: Office 2003

Hi zusammen,
ich habe eine ähnliche Frage und zwar, wenn die Pos 1 im UFO sich um eins erhöht ist es auch möglich dies eventuell so zu gestalten:

Pos. 1 (eventuell irgend ein Artikel)
Pos. 1.1 (dazu passende Leistung)
Pos. 1.2 (eventueller Zuschlag für diesen Artikel)

Pos. 2 (neuer Artikel)

Pos. 3 (neuer Artikel)

Ist es möglich den Code von Martin1000 näher zu erklären?

_________________
Viele Grüße
Frank

Wer nicht sucht, findet nichts.
Gast



Verfasst am:
12. Nov 2008, 01:02
Rufname:

AW: fortlaufende Nummerierung im Unterformular - AW: fortlaufende Nummerierung im Unterformular

Nach oben
       Version: Office 2003

Hallo,

mir scheint deine Frage in Richtung Stücklisten oder ähnliches zu gehen. Es sind natürlich Wege möglich die auch das direkt bei der Dateneingabe löst. Doch der VBA-Progammier-Aufwand ist hoch und komplex. Zu dem ich ehrlich gesagt keine Muse habe, den hier zu verfolgen und zu posten.

Die einfachste Lösung denke ich wäre für Dich eine Tabelle zu schaffen die in einem zweiten Unterformular das Erfassen von Zuschlägen u. Leistungen ermöglicht.

Ich habe mal o.g. Function gekürzt, da diese auf Ereignisse reagiert, was aber bei relativ wenigen Datensätzen nicht notwendig ist.
Code:
Private Sub Form_AfterUpdate()
    fct_SetNewRange Me!Feld1, "Name1", "Name2", "Tabellenname", _
                    "Name3=" & Me!Feld2, 1
End Sub
Feld 1) das Feld im Formular was die Datensatz-ID des soebenbearbeiteten DS darstellt
Feld 2) das Feld im Formular was die ID des Parent-DS darstellt (i.d.R das Feld mit der verlinkten ID zum Hauptformular)
Name1) die Feldbezeichnung in der Tabelle des ID-Feldes
Name2) die Feldbezeichnung in der Tabelle in der die Ränge gespeichert werden
Tabellenname) der Name der Tabelle wo die Datensätze gespeichert werden
Name3) der Feldname des Feldes auf das ein Kriterium(Filter) angewendet werden soll

Beachte: >"< Semikolon müssen stehen bleiben

so nun noch die Funktion mit etwas mehr Erklärung:
Code:
Option Compare Database
Option Explicit

Public Function fct_SetNewRange(CURRENTDATA As String, _
                                FIELDNAMEOFDATA As String, _
                                FIELDNAMEOFRANGE As String, _
                                NAMEOFTABLE As String, _
                                CRITERIA As String, _
                                RANGESTEPS As Integer)
    Dim db As DAO.Database
    Dim rs As DAO.Recordset
    Dim strSQL As String
    Dim strCriteria As String
    Dim intNoRange As Integer
    Dim i As Integer
 
'On Error GoTo SubError
   strSQL = "SELECT * FROM " & NAMEOFTABLE & " " & _
             "WHERE " & FIELDNAMEOFDATA & "<>" & CURRENTDATA & " " & _
               "AND " & CRITERIA & " " & _
          "ORDER BY " & FIELDNAMEOFRANGE
   Set db = Application.CurrentDb
   Set rs = db.OpenRecordset(strSQL, dbOpenDynaset)
   If rs.NoMatch Then
      Exit Function
   End If
   'Rang des bearbeiteten Datensatz ermitteln
   intNoRange = DLookup(FIELDNAMEOFRANGE, NAMEOFTABLE, _
                        FIELDNAMEOFDATA & "=" & CURRENTDATA)
    i = 0 'Schrittzähler
    'Prüfen ob Datensätze vorhanden sind
    Debug.Print rs.RecordCount
    If rs.RecordCount Then
        'Schleife durchlaufen solange eine Datensatz vorhanden ist
        Do While Not rs.EOF
            'Zähler um den festgelegten Intervall erhöhen
            i = i + RANGESTEPS
          'Prüfen ob der Datensatz ungleich dem über CURRENTDATA angegeben ist
            If i = intNoRange Then
                'Zähler nochmals um den festgelegten Intervall erhöhen,
                'damit der Rang "übersprungen" wird
                i = i + RANGESTEPS
            End If
            With rs
                'Datensatzbearbeitung anweisen
                .Edit
                'zu bearbeitendes Feld ändern
                .Fields(FIELDNAMEOFRANGE) = i:
                'speichern des bearbeiteten Datensates
                .Update
            End With
            'zum nächsten Datensatz gehen
            rs.MoveNext
            'Bei "i" wieder anfangen
        Loop
    End If
    'Recordset usw. schließen
    rs.Close
    Set rs = Nothing
    Set db = Nothing
    Exit Function
SubError:
   MsgBox Err.Number & " " & Err.Description & vbCrLf & _
          "in --fct_SetNewRange--", vbCritical + vbOKOnly
   Debug.Print Err.Number & " " & Err.Description & vbCrLf & _
               " --fct_SetNewRange--", vbCritical + vbOKOnly
End Function
dimei
Probierer


Verfasst am:
14. Nov 2008, 19:55
Rufname: meise
Wohnort: Gera


AW: fortlaufende Nummerierung im Unterformular - AW: fortlaufende Nummerierung im Unterformular

Nach oben
       Version: Office 2003

hallo zusammen,

ich hänge jetzt hier mal meine kläglichen Versuche Sad an.

Vielleicht könnt Ihr mir helfen.

Danke schon mal im voraus.

Gruß Dimei



Fortlaufend_Di.zip
 Beschreibung:

Download
 Dateiname:  Fortlaufend_Di.zip
 Dateigröße:  40.91 KB
 Heruntergeladen:  58 mal

Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Gehe zu Seite 1, 2  Weiter
Diese Seite Freunden empfehlen

Seite 1 von 2
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Access Tabellen & Abfragen: Abfrage in Unterformular 3 Hundshamer 302 25. Mai 2010, 11:22
blackoutNO Abfrage in Unterformular
Keine neuen Beiträge Access Tabellen & Abfragen: Fortlaufende Nummer... 1 siggi111 371 24. März 2010, 21:44
MiLie Fortlaufende Nummer...
Keine neuen Beiträge Access Tabellen & Abfragen: Nummerierung von Zeilen mit zweifacher Sortierung 2 Michael87 1395 24. Feb 2010, 22:18
Michael87 Nummerierung von Zeilen mit zweifacher Sortierung
Keine neuen Beiträge Access Tabellen & Abfragen: Dynamische Nummerierung 1 magnum 400 30. Jan 2010, 21:45
steffen0815 Dynamische Nummerierung
Keine neuen Beiträge Access Tabellen & Abfragen: fortlaufende Nummerierung 8 romae 1914 10. Jun 2009, 11:28
romae fortlaufende Nummerierung
Keine neuen Beiträge Access Tabellen & Abfragen: M:N Beziehung, DS inkl. Autowert im Unterformular einfügen 5 wolfsmilch 2624 10. Feb 2008, 20:08
KlausMz M:N Beziehung, DS inkl. Autowert im Unterformular einfügen
Keine neuen Beiträge Access Tabellen & Abfragen: Fortlaufende Nummer in Abschnitten 1 Blocki 387 08. Okt 2007, 20:44
jens05 Fortlaufende Nummer in Abschnitten
Keine neuen Beiträge Access Tabellen & Abfragen: [Unterformular] Automatisch neuen Datensatz anfügen 1 Dege 3200 02. Okt 2007, 14:47
Willi Wipp [Unterformular] Automatisch neuen Datensatz anfügen
Keine neuen Beiträge Access Tabellen & Abfragen: Abfrage-Kriterium aus Register Unterformular 2 Bullett 2113 05. Sep 2007, 21:44
Bullett Abfrage-Kriterium aus Register Unterformular
Keine neuen Beiträge Access Tabellen & Abfragen: Textfeld an Unterformular binden 1 RobiMaverick 2392 13. März 2007, 17:20
Thomas2007 Textfeld an Unterformular binden
Keine neuen Beiträge Access Tabellen & Abfragen: Fortlaufende Nummern bei Unterbrechungen herausfiltern 1 Martin-C 600 29. Jan 2007, 21:01
jens05 Fortlaufende Nummern bei Unterbrechungen herausfiltern
Keine neuen Beiträge Access Tabellen & Abfragen: Problem: Parameter-Abfrage aus einem Unterformular ausführen 3 bettina_vt 3427 12. Mai 2006, 15:44
bettina_vt Problem: Parameter-Abfrage aus einem Unterformular ausführen
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: Microsoft Excel Tricks