Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Sicherheitshinweis ---> für registrierte Mitglieder <-
Abhängige Kombinationsfelder und NotInList Problem!
Gehe zu Seite 1, 2  Weiter
zurück: 2 tabellen in einem formular (kein Unterfomular!) weiter: Keine Kommazahlen Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Bitte Status wählen ! Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
computerpap
Im Profil kannst Du frei den Rang ändern


Verfasst am:
23. Jan 2005, 12:04
Rufname:

Abhängige Kombinationsfelder und NotInList Problem! - Abhängige Kombinationsfelder und NotInList Problem!

Nach oben
       

Hallo zusammen!

Ich habe folgendes Problem: In meiner Datenbank gibt es ein Formular mit zwei Kombi-Feldern. Kombi-Feld 2 ist abhängig von Kombi-Feld 1.
In beiden Feldern habe ich eine Ereignisprozedur für "NotInList" geschrieben, weil beide Kombi's immer wieder erweitert werden müssen.
Für Kombi 1 funktioniert der Code einwandfrei nur bei Kombi 2 erhalte ich die Meldung "Der Datensatz kann nicht hinzu oder geändert werden, da ein Datensatz in der Tabelle 'tbl_Produktgruppen' mit diesen Datensatz in Beziehung stehen muß." Das Problem habe ich verstanden aber wie kann ich dieses Problem lösen? Bitte helft mir!

Danke
mfg computerpap
lothi
c#, .Net


Verfasst am:
23. Jan 2005, 18:49
Rufname:
Wohnort: Birgisch


AW: Abhängige Kombinationsfelder und NotInList Problem! - AW: Abhängige Kombinationsfelder und NotInList Problem!

Nach oben
       

Hallo

Du musst bei deinem Code auch die ID des Hauptdatensatzes mit in der Tabelle speicher.
Irgendwo musst du die ID des Hauptdatensatzes zudem du den Wert speichern
willst herausfinden.
Da ich keine Ahnung habe wie der Code aussieht was du für Daten in deinem Formular
hast kann ich dir leider nicht weiterhelfen.
Sag uns wo sich der petreffende Id befindet, und wie der Code zum peichern aussieht.

_________________
Gruss Lothi, der Bastler
Feedback ist die beste Möglichkeit mir zu sagen ob die Antwort geholfen hat!
AC2002, WinXP, Office XP
computerpap
Im Profil kannst Du frei den Rang ändern


Verfasst am:
24. Jan 2005, 18:58
Rufname:

AW: Abhängige Kombinationsfelder und NotInList Problem! - AW: Abhängige Kombinationsfelder und NotInList Problem!

Nach oben
       

Hallo

Erstmal vielen Dank für die schnelle Antwort.
Ich gebe hier mal paar Detail wie meine DB aussieht vielleicht hilft das weiter.
Folgende Tabellen mit dessen Inhalt sind vorhanden:
tbl_Produktgruppen -> Produktgruppen_ID (AutoWert), Produktgruppen (Text)
tbl_Lieferanten -> Lieferanten_ID (AutoWert), Produktgruppen_ID (Zahl), Lieferanten (Text)
Folgendes Formular mit dessen Inhalt ist vorhanden:
Formular1 -> cmb_Produktgruppen, cmb_Lieferanten

Folgende Code'S gibt es für cmb_Produktgruppen:

Bei Änderung:
Code:
Private Sub cmb_Produktgruppen_Change()
    Me!cmb_Lieferanten.RowSource = "SELECT Lieferanten_ID, Lieferanten " & _
                                   "FROM tbl_Lieferanten " & _
                                   "WHERE Produktgruppen_ID = " & _
                                                          Me!cmb_Produktgruppen
    Me!cmb_Lieferanten = Me!cmb_Lieferanten.Column(0, 0)
End Sub
Bei Nicht in Liste:
Code:
Private Sub cmb_Produktgruppen_NotInList(NewData As String, _
                                         Response As Integer)
On Error GoTo fehler
    Dim db As DAO.Database
    Dim rs As DAO.Recordset
    Dim erg As Integer

    Response = acDataErrAdded
    erg = MsgBox("Der eingegebene Wert '" & NewData & _
                 "' ist nicht in der Liste vorhanden. Möchten Sie " & _
                 "den Wert in die Tabelle übernehmen?", 52, "Neuer Wert")
    If erg = 6 Then
        Set db = CurrentDb
        Set rs = db.OpenRecordset("tbl_Produktgruppen", dbOpenDynaset)
        rs.AddNew
        rs!Produktgruppen = NewData
        rs.Update
        rs.Close
        Set rs = Nothing
        db.Close
      Else
        Response = acDataErrContinue
    End If

ende:
    Exit Sub
fehler:
    MsgBox Err.Description, 16, "Fehler"
    Resume ende
End Sub

Folgende Code'S gibt es für cmb_Lieferanten:
Bei nicht in Liste:
Code:
Private Sub cmb_Lieferanten_NotInList(NewData As String, _
                                      Response As Integer)
On Error GoTo fehler
    Dim db As DAO.Database
    Dim rs As DAO.Recordset
    Dim erg As Integer

    Response = acDataErrAdded
    erg = MsgBox("Der eingegebene Wert '" & NewData & _
                 "' ist nicht in der Liste vorhanden. Möchten Sie " & _
                 "den Wert in die Tabelle übernehmen?", 52, "Neuer Wert")
    If erg = 6 Then
        Set db = CurrentDb
        Set rs = db.OpenRecordset("tbl_Lieferanten", dbOpenDynaset)
        rs.AddNew
        rs!Lieferanten = NewData
        rs.Update
        rs.Close
        Set rs = Nothing
        db.Close
      Else
        Response = acDataErrContinue
    End If

ende:
    Exit Sub
fehler:
    MsgBox Err.Description, 16, "Fehler"
    Resume ende
End Sub
Vielleicht könnt Ihr jetzt einigermaßen meine db verstehen.

MfG
computerpap
lothi
c#, .Net


Verfasst am:
24. Jan 2005, 21:28
Rufname:
Wohnort: Birgisch

AW: Abhängige Kombinationsfelder und NotInList Problem! - AW: Abhängige Kombinationsfelder und NotInList Problem!

Nach oben
       

Hallo

Ja genau das wollte ich wissen Razz .
So lässt es sich arbeiten.

Nimm einfach bei dem NotInList des cmb_Liferanten die ID aus der
cmb_Produktegruppe mit.

Das ist nähmlich die ID die dir in der Tabelle Lieferanten fehlt wenn du
einen neuen DS erstellst.
Code:
Private Sub cmb_Lieferanten_NotInList(NewData As String, Response As Integer)
On Error GoTo fehler
    Dim db As DAO.Database
    Dim rs As DAO.Recordset
    Dim erg As Integer

    Response = acDataErrAdded
    erg = MsgBox("Der eingegebene Wert '" & NewData & _
                 "' ist nicht in der Liste vorhanden. Möchten Sie " & _
                 "den Wert in die Tabelle übernehmen?", 52, "Neuer Wert")
    If erg = 6 Then
        Set db = CurrentDb
        Set rs = db.OpenRecordset("tbl_Lieferanten", dbOpenDynaset)
        rs.AddNew
        rs!Lieferanten = NewData
        rs!Produktgruppen_ID = Me!cmb_Produktgruppen  '<====
        rs.Update
        rs.Close
        Set rs = Nothing
        db.Close
      Else
        Response = acDataErrContinue
    End If

ende:
    Exit Sub
fehler:
    MsgBox Err.Description, 16, "Fehler"
    Resume ende
End Sub

Habe meinen Eintrag mit einem Pfeil markiert. Das setzt voraus das die Gebunde Spalte des cmb_Produktegruppe auch den Autowert aus der Tabelle tbl_Produktegruppe enthält.

_________________
Gruss Lothi, der Bastler
Feedback ist die beste Möglichkeit mir zu sagen ob die Antwort geholfen hat!
AC2002, WinXP, Office XP
computerpap
Im Profil kannst Du frei den Rang ändern


Verfasst am:
26. Jan 2005, 18:51
Rufname:


AW: Abhängige Kombinationsfelder und NotInList Problem! - AW: Abhängige Kombinationsfelder und NotInList Problem!

Nach oben
       

Hallo

hat super geklappt, vielen Dank nochmal.

MfG
computerpap
svmuelle
Im Profil kannst Du frei den Rang ändern


Verfasst am:
01. Feb 2005, 10:38
Rufname:

Ähnliches Problem - Ähnliches Problem

Nach oben
       

Hallo,
ich habe auch denke ich mal ein ähnliches Problem. Ich hoffe das es das gleiche ist. Bin bei solchen Dinge immer noch krasser Newbie. Smile
Ich habe die Tabelle Buchungen, dort sind die Felder:
Buch_ID = Autowert (Primärschlüssel)
BFirma = Kombinationsfeld mit Bezug zur Tabelle Firma
und weitere die denke Ich dabei aber keine Rolle für mein Problem spielen.
Tabelle Firmen
Firm_ID = Autowert (Primärschlüssel)
Fname = Textfeld

Es exsistiert eine 1 zu unendlich beziehung zwischen Fname und BFirma.

Ich würde nun gerne, wenn ich Dtaen in das Kombifeld eingeben die noch nicht als Datensatz in Fname existieren dort direkt in diese Tabelle übernehmen. Ich bekomme dann aber immer wieder die Meldung "Der Datensatz kann nicht hinzu oder geändert werden, da ein Datensatz in der Tabelle 'Firmen' mit diesen Datensatz in Beziehung stehen muß."

Wenn Ich mir diesen Thread druchlesen, denke Ich geht es um genau dieses Problem , nur habe Ich leider nicht verstanden, wie ich es lösen kann.

Ich würde mich freuen, wenn mir geholfen werden kann.

Grüße

Sven
Dalmatinchen
look into my eyes ...


Verfasst am:
01. Feb 2005, 10:55
Rufname:
Wohnort: Steiermark/Österreich

AW: Abhängige Kombinationsfelder und NotInList Problem! - AW: Abhängige Kombinationsfelder und NotInList Problem!

Nach oben
       

Hallo "svmuelle"!
Ich hatte genau das gleiche Problem wie du mit den Feldern Ort und Strasse, da Strasse von Ort abhängig ist.
Ich habe es durch einen kurzen Code gelöst (mit Hilfe von Thunderbird) ...
Code:
Private Sub Strasse_NotInList(NewData As String, Response As Integer)
    Dim db As Database
    Dim rs As New ADODB.Recordset
    Set db = CurrentDb

    rs.Open "tbl_Strassen", CurrentProject.Connection, adOpenKeyset, adLockOptimistic
    rs.AddNew
    rs!Strasse = NewData
    'erstes Ort bezieht sich auf Tabelle,
    'zweites auf Kombinationsfeld im Formular,
    'der ID-Wert wird dabei übernommen
    rs!Ort = Me!Ort.Column(0)   
    rs.Update
    Response = acDataErrAdded
End Sub

Den Code schreibst du ins Ereignis "NotInList", bei "beim Hingehen" usw. musst du keinen extrigen Code schreiben.

Bei Datensatzherkunft des Kombinationsfeldes gehst du auf den Abfrage-Generator und wählst dort die Tabelle (in diesem Fall "Strassen" und gibst bei Ort (das sich auf das Feld Ort in der Tabelle bezieht) ein ...
Code:
[Forms]![frm_Kunden]![Ort]

Damit werden nur die Strassen für den jeweiligen Ort angezeigt.

Beim Kombinationsfeld "Ort" machst du das mit der Datensatzherkunft genau gleich, nur ohne das Kriterium für das Filtern.

Bei dem Ereignis "nach Aktualisierung" schreibst du jedoch folgende VB-Code-Zeile:
Code:
Private Sub Ort_AfterUpdate()
    Me!Strasse.Requery
End Sub

Somit wird das Feld Strasse bei der Auswahl des Ortes aktualisiert und die Einträge neu gefiltert.

Beim Kombinationsfeld Ort solltest du die gebundene Spalte auf jene setzen, die den OrtID beinhaltet.

Bevor du jedoch diese ganze Prozedur machst, musst du in VB auf Extras - Verweise klicken und dort "Microsoft DAO 3.6 Object Library" aktivieren bzw. die jeweilige Version, die dir zur Verfügung steht.

Tausche einfach die Feld- und Tabellennamen aus, dann sollte es eigentlich hinhaun.

Achja ... du musst beim VB-Code für betreffendes Formular eine Zeile hinzufügen (Option Explicit) ...

Code:
Option Compare Database
Option Explicit


Ich hoffe ich konnte dir ein wenig helfen.

_________________
FEEDBACK nützt jedem!
+++ Auf meiner Homepage findet Ihr zahlreiche Access-Beispiele als Download mit Erklärung! +++
lothi
c#, .Net


Verfasst am:
01. Feb 2005, 11:36
Rufname:
Wohnort: Birgisch

AW: Abhängige Kombinationsfelder und NotInList Problem! - AW: Abhängige Kombinationsfelder und NotInList Problem!

Nach oben
       

Hallo

Darf ich da noch eine kleine Anmerkung anbringen. Es geht da um die Deklaration
der Objekt-Variablen.
Das mischen ADO und DAO in einem Code ist nicht unbedingt ratsam. Das kann zu komischen
nicht nachvollziehbaren Fehlern führen.
Code:
    Dim db As Database  'DAO-Objekt
    Dim rs As New ADODB.Recordset  'ADO-Objekt

    Set db = CurrentDb 'Dao-Objekt wird aber hier nicht gebraucht
    ' Hier wird auf die Aktuelle DB mit ADO zugewiesen.
    rs.Open "tbl_Strassen", CurrentProject.Connection, adOpenKeyset, _
            adLockOptimistic

Was noch fehlt ist das schliessen der Objekt Variablen. Es heisst zwar das am Ende
des Codes die Objekt-Variablen geleert werden aber 100%ig kann man sich auch nicht drauf verlassen.
Darum ist es besser die Objekt-Variablen am Ende des Codes selber zu schliessen und zu entleeren.
Code:
    rs.Close
    rs = Nothing

So verhinderst du das auf einmal die Meldung kommt das du nichts speichern kannst weil
die Tabelle irgend jemand benutzt, ohne das auch nur ein Formular offen ist.

_________________
Gruss Lothi, der Bastler
Feedback ist die beste Möglichkeit mir zu sagen ob die Antwort geholfen hat!
AC2002, WinXP, Office XP
svmuelle
Im Profil kannst Du frei den Rang ändern


Verfasst am:
01. Feb 2005, 15:51
Rufname:

äh??? nix verstanden :-) - äh??? nix verstanden :-)

Nach oben
       

Sorry, aber das ist jetzt alles zu hoch. Smile
Mein Prob ist das, dass ich in einem Datensatz korrelierendes Informationen habe, sondern die Daten die Ich in das Kombifeld eingebe und dort noch nicht exsistieren in die andere Tabelle Übernommen werden sollen. Es soll damit ja Quasie ein neuer Datensatz in der Datenursprungstabelle angelegt werden.

Aber danke Das Ihr mir helfen wollt, sorry schon jetzt wenn ich was nicht direkt raffe.

Grüße
Sven
Dalmatinchen
look into my eyes ...


Verfasst am:
01. Feb 2005, 16:19
Rufname:
Wohnort: Steiermark/Österreich

AW: Abhängige Kombinationsfelder und NotInList Problem! - AW: Abhängige Kombinationsfelder und NotInList Problem!

Nach oben
       

Hallo "svmuelle"!

Genau dieses Problem hatte ich ja auch (siehe oben).
Mit "Eintrag automatisch ergänzen" im Eigenschaftsfenster des Kombinationsfeldes wird der neue Eintrag nicht abgespeichert, deswegen benötigist du einen VB-Code (siehe oben).

LG Dalmatinchen

_________________
FEEDBACK nützt jedem!
+++ Auf meiner Homepage findet Ihr zahlreiche Access-Beispiele als Download mit Erklärung! +++
lothi
c#, .Net


Verfasst am:
01. Feb 2005, 16:20
Rufname:
Wohnort: Birgisch

AW: Abhängige Kombinationsfelder und NotInList Problem! - AW: Abhängige Kombinationsfelder und NotInList Problem!

Nach oben
       

Hallo

Wenn du uns sagt wie deine Tabelle heist und wie die Felder heissen die du
aendern willst können wir den Code anpassen.

Dieser Code kommt in das Ereignis Bei Nicht in Liste des Kombifeldes und fügt dir einen neuen DS in der Tabelle tbl_strassen an:
Code:
Private Sub Strasse_NotInList(NewData As String, Response As Integer)
    Dim rs As New ADODB.Recordset     

    rs.Open "tbl_Strassen", CurrentProject.Connection, adOpenKeyset, _
            adLockOptimistic
    rs.AddNew
    rs!Strasse = NewData
    'erstes Ort bezieht sich auf Tabelle,
    'zweites auf Kombinationsfeld im Formular,
    'der ID-Wert wird dabei übernommen
    rs!Ort = Me!Ort.Column(0)   
    rs.Update
    Response = acDataErrAdded
    rs.Close
    Set rs = Nothing
End Sub

_________________
Gruss Lothi, der Bastler
Feedback ist die beste Möglichkeit mir zu sagen ob die Antwort geholfen hat!
AC2002, WinXP, Office XP
svmuelle
Im Profil kannst Du frei den Rang ändern


Verfasst am:
01. Feb 2005, 16:43
Rufname:

AW: Abhängige Kombinationsfelder und NotInList Problem! - AW: Abhängige Kombinationsfelder und NotInList Problem!

Nach oben
       

So langsam dämmert es mir.
Also die Tabelle wohin die Daten dann kommen sollen ist
Firmen
dort gibt es FirmID (Autowert) und das wichtige Feld Fname (Textfeld).
In der Tabelle Buchungen, wo die Daten eingegeben werden sollen heisst das Kombifeld BFirma

Grüße
Sven
lothi
c#, .Net


Verfasst am:
01. Feb 2005, 17:22
Rufname:
Wohnort: Birgisch

AW: Abhängige Kombinationsfelder und NotInList Problem! - AW: Abhängige Kombinationsfelder und NotInList Problem!

Nach oben
       

Dann sollte der Code so aussehen:
Code:
Private Sub BFirma_NotInList(NewData As String, Response As Integer)
    Dim rs As New ADODB.Recordset

    rs.Open "Firmen", CurrentProject.Connection, adOpenKeyset, _
            adLockOptimistic
    rs.AddNew
    rs!Fname = NewData
    rs.Update
    Response = acDataErrAdded
    rs.Close
    Set rs = Nothing
End Sub

Und im Ereignis Nach Aktualisieren des Kombifeldes:
Code:
Private Sub BFirma_AfterUpdate()
    Me!BFirma.Requery
End Sub

_________________
Gruss Lothi, der Bastler
Feedback ist die beste Möglichkeit mir zu sagen ob die Antwort geholfen hat!
AC2002, WinXP, Office XP
Dalmatinchen
look into my eyes ...


Verfasst am:
01. Feb 2005, 17:31
Rufname:
Wohnort: Steiermark/Österreich

AW: Abhängige Kombinationsfelder und NotInList Problem! - AW: Abhängige Kombinationsfelder und NotInList Problem!

Nach oben
       

Hallo "svmuelle"!

Ich glaube, ganz habe ich deine 2 Tabellen noch nicht überrissen.

Du hast eine Tabelle wo deine Buchungen eingetragen werden und ein Feld davon beinhaltet den Firmennamen.

Gibt es nur bei bestimmten Buchungen einen bestimmten Firmennamen? Oder kommen alle Firmennamen bei allen Buchungen vor?

Ich hab die zwei Tabellen - wie du sie geschildert hast - mal so aufgestellt ...

Tabelle "Firmen": Firm_ID (Autowert, Primärschlüssel), FName (Text)
Tabelle "Buchungen": Buch_ID (Autowert, Primärschlüssel), BFirma (Zahl, Nachschlagefunktion zur Tabelle "Firmen")

Soweit so gut oder?

Wenn alle Firmen bei allen Buchungen dabei sein können, dann schreib folgenden Code beim Kombinationsfeld "Firmen" bei NichtInListe ...
Code:
Private Sub BFirma_NotInList(NewData As String, Response As Integer)
    Dim rs As New ADODB.Recordset

    rs.Open "Firmen", CurrentProject.Connection, adOpenKeyset, _
            adLockOptimistic
    rs.AddNew
    rs!BFirma = NewData
    rs.Update
    Response = acDataErrAdded
    rs.Close
    Set rs = Nothing
End Sub

Wenn bestimmte Firmen nur bei bestimmten Buchungen auftauchen sollen, dann bräuchtest du irgendein Kriterium, warum nur bestimmte Firmen erscheinen dürfen im Kombinationsfeld.

Hmm ... kannst du deine Datenbank genauer beschreiben?

_________________
FEEDBACK nützt jedem!
+++ Auf meiner Homepage findet Ihr zahlreiche Access-Beispiele als Download mit Erklärung! +++
Thunderbird
Anwender mit guten VBA-Kenntnissen


Verfasst am:
01. Feb 2005, 17:52
Rufname:


AW: Abhängige Kombinationsfelder und NotInList Problem! - AW: Abhängige Kombinationsfelder und NotInList Problem!

Nach oben
       

Manchmal hilft eine kleine Datei weiter.

Zieh dir mal diese Datei: ergaenzen.zip - für dich interessant ist das Formular frm_Kunden (Dalmatinchen kennt das ja schon ) Razz
Du musst dann den darin enthaltenen Code einfach noch mit den Ergänzungen aus diesem Thread und natürlich mit deinen Feldern anpassen aber vielleicht wird das ganze dann etwas klarer.

@lothi:
Vielen Dank für die Anmerkung ADO und DAO. Manchmal sieht man halt den Wald vor lauter Bäumen nicht Very Happy
Werde bei mir den Beispielcode nachträglich anpassen.

_________________
Gruss Thunderbird

Tipp erhalten, der Hilfreich war ? Dein Feedback hilft uns allen. Danke
Meine Tipps & Tricks basieren auf Office 2003. Andere Officeversionen nur auf Anfrage
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Gehe zu Seite 1, 2  Weiter
Diese Seite Freunden empfehlen

Seite 1 von 2
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Access Tabellen & Abfragen: Mehrere Kombinationsfelder nach Datenimport ausfüllen 1 vrosin 292 29. Jan 2013, 14:39
Gast Mehrere Kombinationsfelder nach Datenimport ausfüllen
Keine neuen Beiträge Access Tabellen & Abfragen: Abhängige Abfrage 0 BZler 90 23. Sep 2012, 20:59
BZler Abhängige Abfrage
Keine neuen Beiträge Access Tabellen & Abfragen: gegenseitig von einander abhäng. Werte a.Kombinationsfelder 8 Metma 388 20. Sep 2012, 22:42
Marmeladenglas gegenseitig von einander abhäng. Werte a.Kombinationsfelder
Keine neuen Beiträge Access Tabellen & Abfragen: Abhängige Tabellenspalten aus Abfragen herausfinden 4 Hilfesuchender Neuling 399 03. Dez 2009, 11:57
Hilfesuchender Neuling Abhängige Tabellenspalten aus Abfragen herausfinden
Keine neuen Beiträge Access Tabellen & Abfragen: Abhänige Kombinationsfelder. Hilfe! 1 Toffel84 406 04. März 2009, 01:44
Willi Wipp Abhänige Kombinationsfelder. Hilfe!
Keine neuen Beiträge Access Tabellen & Abfragen: abhängige Überschrift in Abfrage 3 BLBGünter 599 27. Feb 2007, 11:58
Thomas2007 abhängige Überschrift in Abfrage
Keine neuen Beiträge Access Tabellen & Abfragen: Wie verbinde ich Kombinationsfelder 1 derschlager 691 19. Feb 2007, 12:42
blicki Wie verbinde ich Kombinationsfelder
Keine neuen Beiträge Access Tabellen & Abfragen: Abhängige Auswahlfelder 3 bfdhd 3011 10. Apr 2006, 14:46
rita2008 Abhängige Auswahlfelder
Keine neuen Beiträge Access Formulare: Auswahl über 2 Kombinationsfelder, Anzeige im Unterformular 4 Odsch 1610 27. Aug 2005, 10:41
n' User Auswahl über 2 Kombinationsfelder, Anzeige im Unterformular
Keine neuen Beiträge Access Formulare: access2002 problem mit kombinationsfelder 3 daniel26 701 19. Jul 2005, 11:52
daniel26 access2002 problem mit kombinationsfelder
Keine neuen Beiträge Access Formulare: Abhängige Kombinationsfelder im UFOs 1 Tobias_G 681 07. Apr 2005, 18:30
faßnacht(IT); Abhängige Kombinationsfelder im UFOs
Keine neuen Beiträge Access Formulare: [A2k] abhängige combobox-nachträgl.änderung verhindern 4 PeterP 688 18. Jan 2005, 14:12
PeterP [A2k] abhängige combobox-nachträgl.änderung verhindern
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: Macromedia Dreamweaver