Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Datenübernahme von Messgerät weiterverarbeiten
zurück: SVerweis ?? weiter: Scrollbereich festlegen Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Feedback Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
JGeier
Neuling


Verfasst am:
16. Okt 2008, 21:06
Rufname:
Wohnort: Wien

Datenübernahme von Messgerät weiterverarbeiten - Datenübernahme von Messgerät weiterverarbeiten

Nach oben
       Version: Office 2003

Einen schönen guten Abend,

ich benötige ein wenig Hilfe. Ich übernehme Werte von 3 Messgeräten über eine USB Funkschnittstelle. Mein Problem

Ich bekomme alle Daten in die Spalten wo mein Eingabefeld steht (zb.: A und B)

Spalte A sind die Daten welches Messgerät zb.: SBO1.1, SBO1.2 und SBO1.3

Spalte B werden die Messwerte ausgegeben Zahlen zwischen -1000000 und +10000000

SBO1.1 1,73
SBO1.1 11,96
SBO1.2 35,99
SBO1.2 25,53
SBO1.3 31,16
SBO1.3 38,11

Ich möchte wenn Daten gesendet werden, zb. in die Spalte A1 und B1 das dieser überprüft ob es vom Messgerät SBO1.1 kommt und diesen dann automatisch in die Spalte E1-E2-E3 vortlaufen einträgt. Das Eingabefeld soll dann automatisch gelöscht werden, und wieder in der Spalte A1 stehen. Wenn vom Messgerät SBO1.2 Daten kommen sollen diese in die Spalte G eingetragen werden, und so weiter.

ist das überhaupt zu machen?

Danke für die Hilfe
Bamberg
Excel/Access mit VBA


Verfasst am:
17. Okt 2008, 00:18
Rufname: Gerd

AW: Datenübernahme von Messgerät weiterverarbeiten - AW: Datenübernahme von Messgerät weiterverarbeiten

Nach oben
       Version: Office 2003

Hallo JGeier,

ohne VBA wird das sicher nichts. Ich hab mich mal hingesetzt und ein paar Zeilen geschrieben.

Prämisse:
Bei externen "Geräten" bin ich immer sehr vorsichtig. Oft gibt es da eine zeitliche Komponente, welche im Code nicht berücksichtigt wird. Daher hab ich mal etwas "Wartezeit" eingebaut.

Sobald etwas in Spalte A eingetragem wird, läuft der Code an. (Versuch es selbst einmal und kopiere mehrere Zeilen gleichzeitig in de Spalte A)

Hier mal der Code und im Anhang dann noch eine Mustermappe.
zum Codebereich des Klassenmodules Tabelle1
Option Explicit 
 
Private Sub Worksheet_Change(ByVal Target As Range) 
    If Not Intersect(Target, Range("A:A")) Is Nothing Then 
        Dim Bereich As Range 
        Set Bereich = Me.Range("A1:A" & Me.Range("A65536").End(xlUp).Row) 
        If Not Aktiv And _
           Bereich.Cells.Count <> WorksheetFunction.CountBlank(Bereich) Then 
            Application.OnTime Now + TimeValue("00:00:03"), "Versetzen" 
        End If 
        Set Bereich = Nothing 
    End If 
End Sub 
in ein allgemeines Modul, z.B. Modul1
Option Explicit 
 
Public Aktiv As Boolean 
 
Public Sub Versetzen() 
Dim Geraete As Object, Wert As String 
Dim Bereich As Range, Zelle As Range 
Dim Ziel As Range, WS As Worksheet 
Dim Fehler As Boolean 
 
Aktiv = True 
Set Geraete = CreateObject("Scripting.Dictionary") 
 
Geraete("SBO1.1") = "E" 
Geraete("SBO1.2") = "G" 
Geraete("SBO1.3") = "I" 
 
Set WS = ThisWorkbook.Sheets("Tabelle1")  'TabellenName anpassen 
 
Set Bereich = WS.Range("A1:A" & WS.Range("A65536").End(xlUp).Row) 
 
 
If WorksheetFunction.CountBlank(Bereich) < Bereich.Cells.Count Then 
    For Each Zelle In Bereich 
        Wert = Trim(Zelle.Text) 
        If Wert <> "" Then 
            If Geraete.Exists(Wert) Then 
                Set Ziel = WS.Range(Geraete(Wert) & "65536").End(xlUp) 
                If Not IsEmpty(Ziel) Then Set Ziel = Ziel.Offset(1, 0) 
                Ziel.Resize(1, 2).Value = Zelle.Resize(1, 2).Value 
                Zelle.Resize(1, 2).ClearContents 
            Else 
                Zelle.Resize(1, 2).Interior.Color = vbYellow 
                Fehler = True 
            End If 
        End If 
    Next Zelle 
End If 
 
If Fehler Then 
    MsgBox "Geraet nicht angelegt", , "Fehlermeldung" 
End If 
 
Geraete.RemoveAll 
Set Geraete = Nothing: Set Ziel = Nothing 
Set Bereich = Nothing: Set Zelle = Nothing: Set WS = Nothing 
Aktiv = True 
Application.OnTime Now + TimeValue("00:00:01"), "Zurücksetzen" 
End Sub 
 
Public Sub Zurücksetzen() 
Aktiv = False 
End Sub 
  
LG Gerd

_________________
NIPSILD = Nicht In Problemen, Sondern In Lösungen Denken



JGeier.xls
 Beschreibung:

Download
 Dateiname:  JGeier.xls
 Dateigröße:  30 KB
 Heruntergeladen:  12 mal

JGeier
Neuling


Verfasst am:
17. Okt 2008, 11:40
Rufname:
Wohnort: Wien


AW: Datenübernahme von Messgerät weiterverarbeiten - AW: Datenübernahme von Messgerät weiterverarbeiten

Nach oben
       Version: Office 2003

Hallo Gerd!

Danke erst einmal für das File, ich werde es mir gleich anséhen und ausprobieren.
Ich gebe dir heute noch info ob es so funkt.

Danke dir
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Diese Seite Freunden empfehlen

Seite 1 von 1
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Excel Formeln: Zelladresse + Formelergebnis weiterverarbeiten 7 spinnifex 124 21. Aug 2013, 23:25
spinnifex Zelladresse + Formelergebnis weiterverarbeiten
Keine neuen Beiträge Excel Formeln: Vergleichen von Werten mit Datenübernahme 2 sabine906090 88 11. Sep 2012, 15:08
sabine906090 Vergleichen von Werten mit Datenübernahme
Keine neuen Beiträge Excel Formeln: Datenübernahme 1 Klixxer 87 14. Aug 2012, 09:53
< Peter > Datenübernahme
Keine neuen Beiträge Excel Formeln: Datenübernahme+Kalkulation in Abh. v. Datum 0 Dodomir 294 05. Jul 2010, 09:35
Dodomir Datenübernahme+Kalkulation in Abh. v. Datum
Keine neuen Beiträge Excel Formeln: Formel nach Datenübernahme löschen 2 Heiiiinz 196 09. Dez 2009, 07:57
< Peter > Formel nach Datenübernahme löschen
Keine neuen Beiträge Excel Formeln: Datenübernahme eines 2ten Excelblattes 11 Olimat 291 30. Apr 2009, 15:18
abcde12345 Datenübernahme eines 2ten Excelblattes
Keine neuen Beiträge Excel Formeln: einmalige Datenübernahme 3 doubleo 303 24. März 2009, 10:57
Rüüd einmalige Datenübernahme
Keine neuen Beiträge Excel VBA (Makros): gefilterte Tabelle mit For-Next weiterverarbeiten HILFE! 1 Calvinstefan 614 06. März 2009, 18:32
Calvinstefan gefilterte Tabelle mit For-Next weiterverarbeiten HILFE!
Keine neuen Beiträge Excel VBA (Makros): Datenübernahme und Überprüfung 23 McM 822 06. März 2009, 17:40
Phelan XLPH Datenübernahme und Überprüfung
Keine neuen Beiträge Excel Formate: Automatische Datenübernahme in mehrere Tabellenblätter 7 Allgaier 1026 30. Jan 2009, 01:03
urs Automatische Datenübernahme in mehrere Tabellenblätter
Keine neuen Beiträge Excel VBA (Makros): Fehler bei der Datenübernahme aus UserForm 14 Bernd d.R. 392 09. Nov 2008, 19:19
Nepumuk Fehler bei der Datenübernahme aus UserForm
Keine neuen Beiträge Excel Formeln: Datenübernahme auf mehrere Tabellen 2 ich123456 297 07. Okt 2008, 19:27
Gast Datenübernahme auf mehrere Tabellen
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: HTML CSS