Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Workshop: Stil der Zitate in Word '07 anpassen (XSL-Datei)
zurück: Online-Handbuch Word 2007 im Vergleich zu Word 2003 weiter: Word 2007 - Hotfix für die deutsche Silbentrennung in Off Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Antwort Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
vanilla
Im Profil kannst Du frei den Rang ändern


Verfasst am:
30. Mai 2008, 23:12
Rufname:

Workshop: Stil der Zitate in Word '07 anpassen (XSL-Datei) - Workshop: Stil der Zitate in Word '07 anpassen (XSL-Datei)

Nach oben
       Version: Office 2007

Hi, dies ist mein erster Beitrag, der keine Frage ist Very Happy

Ich schreibe gerade meine Diplomarbeit mit Word 2007 und nutze dabei das Feature für Quellen und Zitate. Wie viele andere war auch ich genervt davon, dass sich der Stil der Zitate und des Literaturverzeichnisses nicht ohne weiteres anpassen lässt.
Also habe ich mir ein Herz gefasst und mich in das Thema XSL etwas eingelesen und mir nun schließlich eine eigene XSL-Datei gebaut (und aus anderen Vorlagen zusammenkopiert), welche ich nun für meinen Diplomarbeit verwende.
Dabei habe ich den ganzen Kram für andere Sprachen rausgenommen, sodass die Zeilenzahl auf lächerliche 731 Zeilen (inkl Kommentare) zusammengeschrumpft ist Very Happy

Damit andere auch was davon haben, hab ich die Datei einigermaßen ausführlich kommentiert und werde den Code nun hier posten. Auf dieser Basis sollte es nun auch für Nicht-XSL-Kenner einigermaßen möglich sein, die Datei nach eigenen Vorstellungen anzupassen.

Die Datei besteht aus den folgenden sieben Abschnitten:
Abschnitt 0: Grundlegende Einstellungen zur Style-Datei.
Abschnitt 1: Hier wird festgelegt, wie das Formular aussehen soll, wenn eine neue Quelle angelegt wird (vorausgesetzt, dass die Option "Alle Literaturverzeichnisfelder anzeigen" aktiviert ist.)
Abschnitt 2: Hier wird festgelegt, wie die einzelnen Quellen im Literaturverzeichnis ausgegeben werden sollen. Hier sind jedoch noch nicht alle Arten von Quellen eingetragen. Ggf. müssen die entsprechenden Quellenarten noch hinzugefügt werden.
Abschnitt 3: Hier wird festgelegt, wie das gesamte Literaturverzeichnis ausgegeben wird.
Abschnitt 4: Hier wird festgelegt, wie einzelne Zitate ausgegeben werden.
Abschnitt 5: Hier wird festgelegt, wie die verschieden langen Autoren- bzw- Interviewpartnerlisten ausgegeben werden.
Abschnitt 6: Hier wird festgelegt, wie der Name einer Einzelnen Person aufgebaut ist.

Den folgenden Code kopiert in eine leere Datei und speichert diese dann als meinCoolerStyle.xsl in den Ordner [install.-Pfad Office]\Office12\Bibliography\Style

Ihr solltet dann nach einem Neustart von Word 2007 eine neue Formatvorlage mit dem Namen "Vanilla Style" haben.

Diese Datei ist sicher noch nicht perfekt. Ich hoffe jedoch, dass sie dem einen oder anderen eine Basis für die eigene Entwicklung bieten kann.
Für Rookies: Am besten lässt sich so eine Datei übrigens mit einem XML-Editor mit Syntax-Highlighting betrachten, wie z.B. dem kostenlosen Notepad++ oder auch dem nicht kostenlosen Visual Studio.

So, lange Rede kurzer Sinn. Hier kommt jetzt der Code:
Code:
<?xml version="1.0" ?>

<!--Externe Ressourcen, die referenziert werden -->
<xsl:stylesheet
     version = "1.0"
     xmlns:xsl = "http://www.w3.org/1999/XSL/Transform"
     xmlns:b = "http://schemas.openxmlformats.org/officeDocument/2006/bibliography">

 
  <!--### Abschnitt 0: Grundlegende Einstellungen zur Style-Datei.###-->
 
  <!--Ausgabe als HTML -->
  <xsl:output method = "html" encoding = "us-ascii"/>

  <!--Das Wurzel-Element weitergeben -->
  <xsl:template match = "/">
    <xsl:apply-templates select = "*"/>
  </xsl:template>

  <!-- Hier kann eine Versionsnummer für das gesamte Dokument gesetzt werden (Optional)-->
  <xsl:template match = "b:version">
    <xsl:text>Version 1.0</xsl:text>
  </xsl:template>

  <!--Hier wird der Name festgelegt, der in Word 2007 erscheinen soll -->
  <xsl:template match = "b:StyleName">
    <xsl:text>Vanilla Style</xsl:text>
  </xsl:template>


  <!--### Abschnitt 1: Hier wird festgelegt, wie das Formular aussehen soll,
    wenn eine neue Quelle angelegt wird (vorausgesetzt, dass die Option
    "Alle Literaturverzeichnisfelder anzeigen" aktiviert ist.) ###-->

  <xsl:template match = "b:GetImportantFields">
    <b:ImportantFields>
      <xsl:choose>

        <!--für Bücher-->
        <xsl:when test="b:SourceType='Book'">
          <b:ImportantField>
            <xsl:text>b:Author/b:Author/b:NameList</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Title</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Year</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:City</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Publisher</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:StandardNumber</xsl:text>
          </b:ImportantField>
        </xsl:when>

        <!--für Buchabschnitte-->
        <xsl:when test="b:SourceType='BookSection'">
          <b:ImportantField>
            <xsl:text>b:Author/b:Author/b:NameList</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Title</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Author/b:BookAuthor/b:NameList</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:BookTitle</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Year</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:City</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Publisher</xsl:text>
          </b:ImportantField>
        </xsl:when>

        <!--Für Zeitungsartikel-->
        <xsl:when test="b:SourceType='JournalArticle'">
          <b:ImportantField>
            <xsl:text>b:Author/b:Author/b:NameList</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Title</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Year</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:City</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Publisher</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Volume</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Issue</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:StandardNumber</xsl:text>
          </b:ImportantField>
        </xsl:when>

        <!--für Artikel einer Zeitschrift-->
        <xsl:when test="b:SourceType='ArticleInAPeriodical'">
          <b:ImportantField>
            <xsl:text>b:Author/b:Author/b:NameList</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Title</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:PeriodicalTitle</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Year</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Edition</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Volume</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Issue</xsl:text>
          </b:ImportantField>
        </xsl:when>

        <!--Für Konferenzprotokolle-->
        <xsl:when test="b:SourceType='ConferenceProceedings'">
          <b:ImportantField>
            <xsl:text>b:Author/b:Author/b:NameList</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Title</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Year</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:City</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Publisher</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:StandardNumber</xsl:text>
          </b:ImportantField>
        </xsl:when>

        <!--Für Berichte-->
        <xsl:when test="b:SourceType='Report'">
          <b:ImportantField>
            <xsl:text>b:Author/b:Author/b:NameList</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Title</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Year</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:City</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Publisher</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:StandardNumber</xsl:text>
          </b:ImportantField>
        </xsl:when>

        <!--Für Tonaufnahmen-->
        <xsl:when test="b:SourceType='SoundRecording'">
          <b:ImportantField>
            <xsl:text>b:Author/b:Artist/b:NameList</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Title</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:AlbumTitle</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:ProductionCompany</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Year</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Medium</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:City</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:StandardNumber</xsl:text>
          </b:ImportantField>
        </xsl:when>

        <!--Für Aufführungen-->
        <xsl:when test="b:SourceType='Performance'">
          <b:ImportantField>
            <xsl:text>b:Author/b:Writer/b:NameList</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Title</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:ProductionCompany</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Theater</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Year</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:City</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:StandardNumber</xsl:text>
          </b:ImportantField>
        </xsl:when>

        <!--Für Kunst-->
        <xsl:when test="b:SourceType='Art'">
          <b:ImportantField>
            <xsl:text>b:Author/b:Artist/b:NameList</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Title</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Institution</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Year</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:City</xsl:text>
          </b:ImportantField>
        </xsl:when>

        <!--Für Dokumente von Webseiten-->
        <xsl:when test="b:SourceType='DocumentFromInternetSite'">
          <b:ImportantField>
            <xsl:text>b:Author/b:Author/b:NameList</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Title</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:InternetSiteTitle</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Year</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Month</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Day</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:YearAccessed</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:MonthAccessed</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:DayAccessed</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:URL</xsl:text>
          </b:ImportantField>
        </xsl:when>

        <!--Für Webseiten-->
        <xsl:when test="b:SourceType='InternetSite'">
          <b:ImportantField>
            <xsl:text>b:Author/b:Author/b:NameList</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Title</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:InternetSiteTitle</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Year</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Month</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Day</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:YearAccessed</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:MonthAccessed</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:DayAccessed</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:URL</xsl:text>
          </b:ImportantField>
        </xsl:when>

        <!--Für Filme-->
        <xsl:when test="b:SourceType='Film'">
          <b:ImportantField>
            <xsl:text>b:Author/b:Director/b:NameList</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Title</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:ProductionCompany</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Year</xsl:text>
          </b:ImportantField>
        </xsl:when>

        <!--Für Interviews-->
        <xsl:when test="b:SourceType='Interview'">
          <b:ImportantField>
            <xsl:text>b:Author/b:Interviewee/b:NameList</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Title</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:BroadcastTitle</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Year</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Month</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Day</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Broadcaster</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Station</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:City</xsl:text>
          </b:ImportantField>
        </xsl:when>

        <!--Für Patente-->
        <xsl:when test="b:SourceType='Patent'">
          <b:ImportantField>
            <xsl:text>b:Author/b:Inventor/b:NameList</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Title</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Year</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Month</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Day</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:CountryRegion</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Type</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:PatentNumber</xsl:text>
          </b:ImportantField>
        </xsl:when>

        <!--Für elektronische Quellen-->
        <xsl:when test="b:SourceType='ElectronicSource'">
          <b:ImportantField>
            <xsl:text>b:Author/b:Author/b:NameList</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Title</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:City</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:ProductionCompany</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Medium</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Year</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:StandardNumber</xsl:text>
          </b:ImportantField>
        </xsl:when>

        <!--Für Fälle-->
        <xsl:when test="b:SourceType='Case'">
          <b:ImportantField>
            <xsl:text>b:Author/b:Author/b:NameList</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Title</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:CaseNumber</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:City</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Court</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Year</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:AbbreviatedCaseNumber</xsl:text>
          </b:ImportantField>
        </xsl:when>

        <!--Für "Verschiedenes"-->
        <xsl:when test="b:SourceType='Misc'">
          <b:ImportantField>
            <xsl:text>b:Author/b:Author/b:NameList</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Title</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:PublicationTitle</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Year</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:City</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Publisher</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Volume</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:Issue</xsl:text>
          </b:ImportantField>
          <b:ImportantField>
            <xsl:text>b:StandardNumber</xsl:text>
          </b:ImportantField>
        </xsl:when>

      </xsl:choose>
    </b:ImportantFields>
  </xsl:template>


  <!--### Abschnitt 2: Hier wird festgelegt, wie die einzelnen Quellen im Literaturverzeichnis
    ausgegeben werden sollen. Hier sind noch nicht alle Arten von Quellen eingetragen.
    Ggf. müssen die entsprechenden Quellenarten noch hinzugefügt werden.###-->

  <!--So werden Interviews ausgegeben -->
  <!--Beispiel: [Tag01] Name Vorname (Sender) zum Thema: Titel_des_Themas (12. Mai 2008).-->
  <!--Anmerkung: Das Feld "Sender"wurde hier benutzt, um die Position im Unternehmen zu beschreiben)-->
  <xsl:template match = "b:Source[b:SourceType = 'Interview']">
    <p style="font-family: Arial, Helvetica, sans-serif; font-size: 11pt;">
      <span style="font-weight: bold; ">
        <xsl:text>[</xsl:text>
        <xsl:value-of select = "b:Tag"/>
        <xsl:text>] </xsl:text>
      </span>
      <!-- Autorenliste-->
      <xsl:apply-templates select="b:Author/b:Interviewee" mode="IntervieweeNamelistFull" />
      <!--Sender (hier: Position)-->
      <xsl:text> (</xsl:text>
      <xsl:value-of select = "b:Station"/>
      <!--Thema-->
      <xsl:text>) zum Thema: </xsl:text>
      <xsl:value-of select = "b:Title"/>
      <!--Datum-->
      <xsl:text> (</xsl:text>
      <xsl:value-of select = "b:Day"/>
      <xsl:text>. </xsl:text>
      <xsl:value-of select = "b:Month"/>
      <xsl:text> </xsl:text>
      <xsl:value-of select = "b:Year"/>
      <xsl:text>).</xsl:text>
    </p>
  </xsl:template>

  <!--So werden Bücher, Berichte und elektronische Quellen ausgegeben -->
  <!--Beispiel: [Tag01] Vorname Nachname, Vorname Nachname: Titel (12. Mai 2008).-->
  <xsl:template match = "b:Source[b:SourceType = 'Book'] | b:Source[b:SourceType = 'Report'] | b:Source[b:SourceType = 'ElectronicSource']">
    <p style="font-family: Arial, Helvetica, sans-serif; font-size: 11pt;">
      <span style="font-weight: bold; ">
        <xsl:text>[</xsl:text>
        <xsl:value-of select = "b:Tag"/>
        <xsl:text>] </xsl:text>
      </span>
      <!--Autorenliste-->
      <xsl:apply-templates select="b:Author/b:Author" mode="AuthorNamelistFull" />
      <xsl:text>: </xsl:text>
      <!--Titel-->
      <xsl:value-of select = "b:Title"/>
      <!--Datum-->
      <xsl:text> (</xsl:text>
      <xsl:value-of select = "b:City"/>
      <xsl:text>, </xsl:text>
      <xsl:value-of select = "b:Year"/>
      <xsl:text>).</xsl:text>
    </p>
  </xsl:template>

  <!--So werden Webseiten und Dokumente von Webseiten ausgegeben -->
  <!--Beispiel: [Tag01] Autor: Titel (12. Mai 2008)
                [www.vanillav_kann_xsl.de] (Zugriff am: 12. Mai 2008).-->
  <xsl:template match = "b:Source[b:SourceType = 'InternetSite'] | b:Source[b:SourceType = 'DocumentFromInternetSite']">
    <p style="font-family: Arial, Helvetica, sans-serif; font-size: 11pt;">
      <span style="font-weight: bold;">
        <xsl:text>[</xsl:text>
        <xsl:value-of select = "b:Tag"/>
        <xsl:text>] </xsl:text>
      </span>
      <!--Autorenliste-->
      <xsl:apply-templates select="b:Author/b:Author" mode="AuthorNamelistFull" />
      <!--Titel-->
      <xsl:text>: </xsl:text>
      <xsl:value-of select = "b:Title"/>
      <!--Datum-->
      <xsl:text> (</xsl:text>
      <xsl:value-of select = "b:Year"/>
      <xsl:text>) </xsl:text>
      <br />
      <!--URL-->
      <span style="font-size: 10pt; color: #0000FF;">
        <xsl:text>[</xsl:text>
        <xsl:value-of select = "b:URL"/>
        <xsl:text>]</xsl:text>
      </span>
      <!--Zugriffs-Datum-->
      <span style="font-size: 10pt;">
        <xsl:text> (Zugriff: </xsl:text>
        <xsl:value-of select = "b:DayAccessed"/>
        <xsl:text>. </xsl:text>
        <xsl:value-of select = "b:MonthAccessed"/>
        <xsl:text> </xsl:text>
        <xsl:value-of select = "b:YearAccessed"/>
        <xsl:text>).</xsl:text>
      </span>
    </p>
  </xsl:template>


  <!--### Abschnitt 3: Hier wird festgelegt, wie das gesamte Literaturverzeichnis ausgegeben wird.###-->

  <xsl:template match = "b:Bibliography">
    <html xmlns = "http://www.w3.org/TR/REC-html40">
      <body>
        <!--Zuerst kommen Bücher, Berichte und Elektronische Quellen-->
        <xsl:apply-templates select = "b:Source[b:SourceType = 'Book'] | b:Source[b:SourceType = 'Report'] | b:Source[b:SourceType = 'ElectronicSource']">
          <xsl:sort select="b:Tag" order="ascending"/>
        </xsl:apply-templates>
        <br/>

        <!--Anschließend sind Onlinequellen dran-->
        <xsl:text>Onlinequellen</xsl:text>
        <xsl:apply-templates select = "b:Source[b:SourceType = 'InternetSite'] | b:Source[b:SourceType = 'DocumentFromInternetSite']">
          <xsl:sort select="b:Tag" order="ascending"/>
        </xsl:apply-templates>
        <br/>

        <!--Zum Schluss kommen noch Interviews-->
        <xsl:text>Verzeichnis der Interviewpartner</xsl:text>
        <xsl:apply-templates select = "b:Source[b:SourceType = 'Interview']">
          <xsl:sort select="b:Tag" order="ascending"/>
        </xsl:apply-templates>
        <br/>
      </body>
    </html>
  </xsl:template>


  <!--### Abschnitt 4: Hier wird festgelegt, wie einzelne Zitate ausgegeben werden.###-->

  <xsl:template match = "b:Citation/b:Source">
    <html xmlns = "http://www.w3.org/TR/REC-html40">
      <body>
        <!--Zu erst kommt das Tag, Bsp: [VanV]-->
        <span style="font-weight:bold">
          <xsl:text>[</xsl:text>
          <xsl:value-of select = "b:Tag"/>
          <xsl:text>] </xsl:text>
        </span>
        <!-- Anschließend kommen der/die Autoren-->
        <!--Anmerkung: Wie die Liste genau aufgebaut ist, steht in Abschnitt 5-->
        <xsl:apply-templates select="b:Author/b:Author" mode="AuthorNamelistVeryShort" />
        <xsl:apply-templates select="b:Author/b:Interviewee" mode="AuthorNamelistVeryShort" />
        <!--Schließlich kommt das Datum-->
        <xsl:text>, </xsl:text>
        <xsl:value-of select = "b:Year"/>
        <!--und noch die Seiten, wenn sie angegeben wurden-->
        <xsl:if test="../b:Pages != ''">
          <xsl:text>, S. </xsl:text>
          <xsl:value-of select = "../b:Pages"/>
        </xsl:if>
      </body>
    </html>
  </xsl:template>

  <!--### Abschnitt 5: Hier wird festgelegt, wie die verschieden langen Autoren- bzw- Interviewpartnerlisten ausgegeben werden.###-->

  <!-- Vollständige Interviewpartnerliste -->
  <xsl:template match="b:Interviewee" mode="IntervieweeNamelistFull">
    <xsl:for-each select="b:NameList/b:Person">
      <xsl:apply-templates select="."/>
      <xsl:if test="position() != last()">
        <xsl:text>, </xsl:text>
      </xsl:if>
    </xsl:for-each>
    <xsl:value-of select="b:Corporate"/>
  </xsl:template>

  <!-- Vollständige Autorenliste -->
  <xsl:template match="b:Author" mode="AuthorNamelistFull">
    <xsl:for-each select="b:NameList/b:Person">
      <xsl:apply-templates select="."/>
      <xsl:if test="position() != last()">
        <xsl:text>, </xsl:text>
      </xsl:if>
    </xsl:for-each>
    <xsl:value-of select="b:Corporate"/>
  </xsl:template>

  <!-- Kurze Autorenliste (wenn mehr als 3 Autoren vorhanden sind, dann wird "et al." hinzugefügt)-->
  <xsl:template match="b:Author" mode="AuthorNamelistShort">
    <xsl:for-each select="b:NameList/b:Person">
      <xsl:choose>
        <xsl:when test="position() = 3">
          <xsl:choose>
            <xsl:when test="last() > 3">
              <xsl:text>et al.</xsl:text>
            </xsl:when>
            <xsl:otherwise>
              <xsl:apply-templates select="."/>
            </xsl:otherwise>
          </xsl:choose>
        </xsl:when>
        <xsl:when test="position() > 3">
        </xsl:when>
        <xsl:otherwise>
          <xsl:apply-templates select="."/>
          <xsl:if test="position() != last()">
            <xsl:text>, </xsl:text>
          </xsl:if>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:for-each>
    <xsl:value-of select="b:Corporate"/>
  </xsl:template>

  <!-- Sehr kurze Autorenliste(wenn mehr als 1 Autor vorhanden ist, dann wird "et al." hinzugefügt -->
  <xsl:template match="b:Author" mode="AuthorNamelistVeryShort">
    <xsl:for-each select="b:NameList/b:Person">
      <xsl:choose>
        <!--Wenn die Liste mehr als einen Autor enthält-->
        <xsl:when test="last() > 1">
          <xsl:choose>
            <!--Wenn die Position = 1 ist, wird der Autor geschrieben-->
            <xsl:when test="position() = 1">
              <xsl:apply-templates select="."/>
            </xsl:when>
            <!--Wenn die Position = 2 ist, wird " et al." geschrieben-->
            <xsl:when test="position() = 2">
              <xsl:text> et al.</xsl:text>
            </xsl:when>
            <!--Sonst passiert nichts!-->
          </xsl:choose>
        </xsl:when>
        <!--Sonst wird einfach nur der Autor geschrieben-->
        <xsl:otherwise>
          <xsl:apply-templates select="."/>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:for-each>
    <xsl:value-of select="b:Corporate"/>
  </xsl:template>

  <!--### Abschnitt 6: Hier wird festgelegt, wie der Name einer Einzelnen Person aufgebaut ist.###-->
  <!-- Beispiel: "Vorname Vorname2 Nachname" -->
  <xsl:template match="b:Person">
    <xsl:if test="b:First != ''">
      <xsl:value-of select = "b:First"/>
      <xsl:text> </xsl:text>
    </xsl:if>
    <xsl:if test="b:Middle != ''">
      <xsl:value-of select = "b:Middle"/>
      <xsl:text> </xsl:text>
    </xsl:if>
    <xsl:if test="b:Last != ''">
      <xsl:value-of select = "b:Last"/>
    </xsl:if>
  </xsl:template>

  <xsl:template match = "text()"/>
</xsl:stylesheet>

So denn, ich hoffe, dies hat etwas geholfen. Über ne positive Bewertung würd ich mich auch noch freuen Very Happy Very Happy Very Happy
Office-Freak
Man tut was man kann!


Verfasst am:
10. Jan 2009, 13:13
Rufname:
Wohnort: Legendäre Officeland


AW: Stil der Zitate verändern? (Word 2007) - AW: Stil der Zitate verändern? (Word 2007)

Nach oben
       Version: Office 2007

Hi,

da es offensichtlich immer mal Schwierigkeiten gibt, den Code über Kopieren in eine funktionierende Datei zu speichern:

Hier mal der Code in einer funktionierenden xsl-Datei.a

Sonst einen Hinweis:
Die 1. Zeile des Codes ggf. verändern in diese Zeile:

Code:
<?xml version="1.0" encoding="ISO-8859-1"?>


Vor dieser Zeile darf nichts stehen - auch kein Kommentar!

Sollte der Stil nicht in der Liste in Word nach einem Neustart von Word aufgeführt werden, so hat die Datei einen Fehler im Code selbst.


Für weitere Ergänzungen oder Änderungen in den einzelen Themen hier im Forum antworten....

Stil der Zitate verändern

Zitieren mehrerer Quellen

Word07 - Zitate



Und hier und noch Hinweis:
http://www.office-loesung.de/ftopic262710_0_0_asc.php


Gruß
Office-Freak



Vanilla_Style_Office_Loesung.zip
 Beschreibung:
Der Code von Vanilla in einer xsl-Datei

Download
 Dateiname:  Vanilla_Style_Office_Loesung.zip
 Dateigröße:  3.33 KB
 Heruntergeladen:  6198 mal

Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Diese Seite Freunden empfehlen

Seite 1 von 1
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Word Formate: Silbentrennung und Rand anpassen 1 Gast 95 28. Dez 2013, 18:21
SpecialTrooper Silbentrennung und Rand anpassen
Keine neuen Beiträge Word Formate: Inhaltsverzeichnis anpassen 1 Logi 80 06. Dez 2013, 01:22
EPsi1 Inhaltsverzeichnis anpassen
Keine neuen Beiträge Word Formate: Abbildungsnummerierung im Text automatisch anpassen? 9 Gast 5064 26. Sep 2013, 18:30
KikiOTrocks Abbildungsnummerierung im Text automatisch anpassen?
Keine neuen Beiträge Word Formate: zitate einrücken word 2010 1 zimmer 1098 22. Feb 2013, 00:07
Ute-S zitate einrücken word 2010
Keine neuen Beiträge Word Formate: Wie vorgegebenen Text bei Inhaltssteuerelementen anpassen? 2 BenC 389 26. Nov 2012, 13:42
BenC Wie vorgegebenen Text bei Inhaltssteuerelementen anpassen?
Keine neuen Beiträge Word Formate: Stil der Zitate in Word 2010 anpassen 2 Gungi26 1907 20. Jun 2012, 13:45
Amazeroth1983 Stil der Zitate in Word 2010 anpassen
Keine neuen Beiträge Word Formate: Active x-Elemente anpassen 3 dawatec 492 12. Feb 2012, 13:38
dawatec Active x-Elemente anpassen
Keine neuen Beiträge Word Formate: Formatvorlage Literaturverzeichnis anpassen 0 Office2012 1002 06. Sep 2011, 16:03
Office2012 Formatvorlage Literaturverzeichnis anpassen
Keine neuen Beiträge Word Formate: Zitate formatieren 1 floppse 3642 11. Jul 2011, 18:29
isa_112 Zitate formatieren
Keine neuen Beiträge Word Formate: Style.xsl für Literaturverzeichnis und Zitate anpassen 0 eidbrainstorm 2515 08. Jun 2011, 17:46
eidbrainstorm Style.xsl für Literaturverzeichnis und Zitate anpassen
Keine neuen Beiträge Word Formate: Bildnummerierung an Kapitelnummer anpassen 3 eta 2201 13. Jan 2011, 15:01
eta Bildnummerierung an Kapitelnummer anpassen
Keine neuen Beiträge Word Formate: Formatvorlagen anpassen 1 gast user 606 10. Nov 2010, 20:02
CaBe Formatvorlagen anpassen
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: Expression Web