Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Textfeld aus Formular in neue Textdatei kopieren
Gehe zu Seite Zurück  1, 2
zurück: Suchfunktion im Formular weiter: Label ändern per VBA ! Funktioniert nicht..... Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Feedback Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
Willi Wipp
Moderator


Verfasst am:
11. Okt 2007, 15:03
Rufname:
Wohnort: Raum Wiesbaden

Re: Textfeld aus Formular in neue Textdatei kopieren (II) - Re: Textfeld aus Formular in neue Textdatei kopieren (II)

Nach oben
       Version: Office 2003

Hi jonnyb2006,

ein Blick in die Online-Hilfe hat noch nie geschadet Wink
MS in der OH hat folgendes geschrieben:
Bei vbBinaryCompare basieren die Ergebnisse eines Zeichenfolgenvergleichs auf der Sortierreihenfolge, die durch die interne binäre Darstellung der Zeichen festgelegt ist. Die Sortierreihenfolge wird unter Microsoft Windows durch die Code-Seite festgelegt. Das folgende Beispiel zeigt eine typische binäre Sortierreihenfolge:

A < B < E < Z < a < b < e < z < À < Ê < Ø < à < ê < ø

vbTextCompare führt zu Zeichenfolgenvergleichen, bei denen die im Gebietsschema des Systems festgelegte Sortierreihenfolge für Zeichen verwendet wird (ohne Unterschiede in der Groß- oder Kleinschreibung zu berücksichtigen). Die oben dargestellten Zeichen würden beim Sortieren mit vbTextCompare folgende Reihenfolge erhalten:

(A=a) < ( À=à) < (B=b) < (E=e) < (Ê=ê) < (Z=z) < (Ø=ø)

vbDatabaseCompare kann nur in Microsoft Access verwendet werden. Mit ihr können Zeichenfolgenvergleiche basierend auf der Sortierreihenfolge durchgeführt werden, die durch die Gebiets-ID der Datenbank bestimmt wird, in der die Zeichenfolgenvergleiche durchgeführt werden.
Leicht abgewandeltes Option Compare-Zitat
==> Ohne vbBinaryCompare ist ä = Ä / Mit vbBinaryCompare ist ä <> Ä

_________________
Eine kurze Rueckmeldung waere nett
SL Willi Wipp

(Anleitung fuer das Anhaengen von Dateien: Klicke links auf [www], Gaeste muessen sich dafuer anmelden)
jonnyb2006
VBA Dummie


Verfasst am:
11. Okt 2007, 22:04
Rufname:
Wohnort: Kassel


AW: Textfeld aus Formular in neue Textdatei kopieren - AW: Textfeld aus Formular in neue Textdatei kopieren

Nach oben
       Version: Office 2003

Hallo,
so hier ist nun mein fertig funktionierender Code:
Code:
Option Compare Database
Option Explicit

Private Sub eSB_Auftrag_an_MJ_Click()
    Dim oDatNum As Integer
    Dim ol As Object, mail As Object
    Dim AusgDat As String
    Dim strIRMInfo1 As String
    Dim strIRMInfo2 As String
   
    AusgDat = "d:\Kundendienst\eServicebericht\eSB_" & Me![A_Projekt] & _
              "A" & Format([Auftragsart], "00") & _
              Format(Me![o_gebiet], "00") & "-" & Format(Me![Datum], "yy") & _
              Format(Me![Nr], "0000") & ".xfdf"
    Close ' in testphase
    oDatNum = FreeFile
    Open AusgDat For Output As oDatNum
    Print #oDatNum, "<?xml version=" & Chr(34) & "1.0" & Chr(34) & _
                    " encoding=" & Chr(34) & "UTF-8" & Chr(34) & " ?>"
    Print #oDatNum, "<xfdf xmlns=" & Chr(34) & "http://ns.adobe.com/xfdf/" & _
                    Chr(34) & " xml:space=" & Chr(34) & "preserve" & _
                    Chr(34) & ">"
    Print #oDatNum, Space(3) & "<ids original=" & Chr(34) & Chr(34) & _
                    " modified=" & Chr(34) & Chr(34) & "></ids>"
    Print #oDatNum, Space(3) & "<fields>"
    Print #oDatNum, Space(6) & "<field name=" & Chr(34) & "A_Projekt" & _
                    Chr(34) & ">"
    Print #oDatNum, Space(9) & "<value>" & fncUmlaute(Me![A_Projekt]) & _
                    "</value>"
    Print #oDatNum, Space(6) & "</field>"
    Print #oDatNum, Space(6) & "<field name=" & Chr(34) & "o_name1" & _
                    Chr(34) & ">"
    Print #oDatNum, Space(9) & "<value>" & fncUmlaute(Me![o_name1]) & _
                    "</value>"
    Print #oDatNum, Space(6) & "</field>"
    Print #oDatNum, Space(6) & "<field name=" & Chr(34) & "o_strasse" & _
                    Chr(34) & ">"
    Print #oDatNum, Space(9) & "<value>" & fncUmlaute(Me![o_strasse]) & _
                    "</value>"
    Print #oDatNum, Space(6) & "</field>"
    Print #oDatNum, Space(6) & "<field name=" & Chr(34) & "o_plz" & _
                    Chr(34) & ">"
    Print #oDatNum, Space(9) & "<value>" & fncUmlaute(Me![o_plz]) & _
                    "</value>"
    Print #oDatNum, Space(6) & "</field>"
    Print #oDatNum, Space(6) & "<field name=" & Chr(34) & "o_ort" & _
                    Chr(34) & ">"
    Print #oDatNum, Space(9) & "<value>" & fncUmlaute(Me![o_ort]) & _
                    "</value>"
    Print #oDatNum, Space(6) & "</field>"
    Print #oDatNum, Space(6) & "<field name=" & Chr(34) & "o_person1" & _
                    Chr(34) & ">"
    Print #oDatNum, Space(9) & "<value>" & fncUmlaute(Me![o_person1]) & _
                    "</value>"
    Print #oDatNum, Space(6) & "</field>"
    Print #oDatNum, Space(6) & "<field name=" & Chr(34) & "o_person1_tel" & _
                    Chr(34) & ">"
    Print #oDatNum, Space(9) & "<value>" & fncUmlaute(Me![o_person1_tel]) & _
                    "</value>"
    Print #oDatNum, Space(6) & "</field>"
    Print #oDatNum, Space(6) & "<field name=" & Chr(34) & "o_person1_fax" & _
                    Chr(34) & ">"
    Print #oDatNum, Space(9) & "<value>" & fncUmlaute(Me![o_person1_fax]) & _
                    "</value>"
    Print #oDatNum, Space(6) & "</field>"
    Print #oDatNum, Space(6) & "<field name=" & Chr(34) & "o_person1_mob" & _
                    Chr(34) & ">"
    Print #oDatNum, Space(9) & "<value>" & fncUmlaute(Me![o_person1_mob]) & _
                    "</value>"
    Print #oDatNum, Space(6) & "</field>"
    Print #oDatNum, Space(6) & "<field name=" & Chr(34) & "cabMailCto" & _
                    Chr(34) & ">"
    Print #oDatNum, Space(9) & "<value>" & fncUmlaute(Me![o_person1_mail]) & _
                    "</value>"
    Print #oDatNum, Space(6) & "</field>"
    Print #oDatNum, Space(6) & "<field name=" & Chr(34) & "AN_1" & Chr(34) & _
                    ">"
    Print #oDatNum, Space(9) & "<value>" & _
                    fncUmlaute(Format(Me![Auftragsart], "00") & _
                    Format(Me![o_gebiet], "00")) & "</value>"
    Print #oDatNum, Space(6) & "</field>"
    Print #oDatNum, Space(6) & "<field name=" & Chr(34) & "AN_2" & Chr(34) & _
                    ">"
    Print #oDatNum, Space(9) & "<value>" & _
                    fncUmlaute(Format(Me![Datum], "yy") & _
                    Format(Me![Nr], "0000")) & "</value>"
    Print #oDatNum, Space(6) & "</field>"
    Print #oDatNum, Space(6) & "<field name=" & Chr(34) & "typ1" & Chr(34) & _
                    ">"
    Print #oDatNum, Space(9) & "<value>" & fncUmlaute(Me![typ1]) & "</value>"
    Print #oDatNum, Space(6) & "</field>"
    Print #oDatNum, Space(6) & "<field name=" & Chr(34) & "Auftragsart" & _
                    Chr(34) & ">"
    Print #oDatNum, Space(9) & "<value>" & _
                    fncUmlaute(Format(Me![Auftragsart], """AA""#")) & _
                    "</value>"
    Print #oDatNum, Space(6) & "</field>"
    Print #oDatNum, Space(6) & "<field name=" & Chr(34) & "o_zone" & _
                    Chr(34) & ">"
    Print #oDatNum, Space(9) & "<value>" & _
                    fncUmlaute(Format(Me![o_zone], """ZO""#")) & "</value>"
    Print #oDatNum, Space(6) & "</field>"
    Print #oDatNum, Space(6) & "<field name=" & Chr(34) & "Bem_Techniker" & _
                    Chr(34) & ">"
    Print #oDatNum, Space(9) & "<value>" & fncUmlaute(Me![Bem_Techniker]) & _
                    "</value>"
    Print #oDatNum, Space(6) & "</field>"
    Print #oDatNum, Space(6) & "<field name=" & Chr(34) & "Bem_KDC" & _
                    Chr(34) & ">"
    Print #oDatNum, Space(9) & "<value>" & fncUmlaute(Me![Bem_KDC]) & _
                    "</value>"
    Print #oDatNum, Space(6) & "</field>"
    Print #oDatNum, Space(3) & "</fields>"
    Print #oDatNum, "</xfdf>"
    Close oDatNum
    'eMail an Mxxxxx Jxxxxx
    'Code by BS, 11.10.2007
    strIRMInfo1 = "Hallo Markus," & vbCrLf & _
                  "mit dieser Mail senden wir Dir folgenden Auftrag:" & _
                  vbCrLf & vbCrLf & "Auftragsnummer: " & [Text77] & _
                  " (<<<< bitte stets angeben!)" & vbCrLf & _
                  "Projektnummer: " & [A_Projekt] & _
                  " (<<<< bitte stets angeben!)" & vbCrLf & _
                  "------------------------------------------------------" & _
                  "------------------------------------------------------" & _
                  "----------------" & vbCrLf & "Benutze die xfdf Datei " & _
                  "Anhang um Deinen elektronischen Servicebericht " & _
                  "auszufüllen!" & vbCrLf & "Benutze als Dateinamen für " & _
                  "den eSERVICEBERICHT bitte:" & vbCrLf & "eSB_" & _
                  Me![A_Projekt] & "_" & Me![Text77] & "_" & _
                  Format$(Me![Datum], "ddmmyy") & "_MJ_.pdf" & vbCrLf & _
                  "------------------------------------------------------" & _
                  "------------------------------------------------------" & _
                  "----------------" & vbCrLf & "Objektanschrift:" & _
                  vbCrLf & Me![o_name1] & vbCrLf & Me![o_strasse] & vbCrLf & _
                  Me![o_plz] & " " & [o_ort] & vbCrLf & vbCrLf & _
                  "Ansprechpartner:" & Me![o_person1] & vbCrLf & _
                  "Telefon:" & Me![o_person1_tel] & vbCrLf
    strIRMInfo1 = strIRMInfo1 & _
                  "Telefax:" & Me![o_person1_fax] & vbCrLf & "Mobil:" & _
                  Me![o_person1_mob] & vbCrLf & "eMail:" & _
                  Me![o_person1_mail] & vbCrLf & "-----------------------" & _
                  "------------------------------------------------------" & _
                  "-----------------------------------------------" & vbCrLf
    strIRMInfo2 = "Anlagendaten:" & vbCrLf & "Bezeichnung der Anlage: " & _
                  Me![typ1] & vbCrLf & "Durchmesser der Anlage: " & _
                  Me![typ1_d] & "mm" & vbCrLf & "Datum der Abnahme: " & _
                  Me![typ1_a] & vbCrLf & "-------------------------------" & _
                  "------------------------------------------------------" & _
                  "---------------------------------------" & vbCrLf & _
                  "Störungsmeldung:" & Me![Bem_Techniker] & vbCrLf & _
                  "Weitere Details:" & Me![Bem_KDC] & vbCrLf & vbCrLf & _
                  "Viel Erfolg bei der Durchführung ;-)" & vbCrLf & vbCrLf & _
                  "------------------------------------------------------" & _
                  "------------------------------------------------------" & _
                  "----------------" & vbCrLf & "ttttttt zzzz GmbH" & _
                  vbCrLf & "Kundendienst" & vbCrLf & "wwwwwwwStr.1" & _
                  vbCrLf & "3XXX9 xxxxxxausen" & vbCrLf & _
                  "Tel.0xxxxx-5x 2xx x1" & vbCrLf & "Fax.0xxxx-5x xxx x0" & _
                  vbCrLf & "Mail.kxx@xxxxxx.de" & vbCrLf & vbCrLf & _
                  "------------------------------------------------------" & _
                  "------------------------------------------------------" & _
                  "----------------" & vbCrLf & "------------------------" & _
                  "------------------------------------------------------" & _
                  "---------------------------------------------------" & _
                  vbCrLf & "eSERVICEBERICHT" & Chr(174)
    strIRMInfo2 = strIRMInfo2 & _
                  "  - Code generated by BS, copyright" & Chr(169) & _
                  " by xxxxxxxxx GmbH 2007" & vbCrLf & "-----------------" & _
                  "------------------------------------------------------" & _
                  "------------------------------------------------------" & _
                  "----" & vbCrLf
    Set ol = CreateObject("Outlook.Application")
    Set mail = ol.CreateItem(0)
    mail.Subject = "kdc !eSB! /A" & Format$(Me![Auftragsart], "00") & _
                   Format$(Me![o_gebiet], "00") & "-" & _
                   Format$(Me![Datum], "yy") & Format$(Me![Nr], "0000") & _
                   " | " & Me![A_Projekt] & " | " & Me![o_name1] & " | " & _
                   Me![o_strasse] & " | " & Me![o_plz] & " " & Me![o_ort] & _
                   " | " & Me![o_person1] & " / " & Me![o_person1_tel] & _
                   " > " & Me![Bem_Techniker]
    mail.To = "bs@bexxxxxx.de; bs-sms@bexxxxxx.de"
    mail.CC = "bs@bexxxxxx.de"
    mail.BCC = "reserve@jxxxxx.info"
    mail.Body = strIRMInfo1 & strIRMInfo2
    mail.Attachments.Add "d:\Kundendienst\eServicebericht\" & "eSB_" & _
                         Me![A_Projekt] & "_A" & _
                         Format(Me![Auftragsart], "00") & _
                         Format(Me![o_gebiet], "00") & "-" & _
                         Format(Me![Datum], "yy") & _
                         Format(Me![Nr], "0000") & ".xfdf"
    mail.Display
    '   mail.Send
End Sub
Der Aufruf geschieht über einen Button und ist für einen Mitarbeiter gedacht, da wir aber 10 haben die diese Mail bekommen sollen, würde ich jetzt 10 verschiedene Buttons mit 10 verschiedenen Codes erstellen. Geht das auch einfacher z.B. über ein KombiFeld wo ich die 10 Mitarbeiter in eine Werteliste eintrage und beim öffnen und auswählen wird immer der gleiche Code aufgerufen mit unterschiedlichen Parametern (Kürzl, Name, eMail usw.)....
Kann mir jemand einen Lösungsansatz geben ?

gruß

Bernd
edit jens05: Mailadressen verfremdet und Telnr. weiter verfremdet.

_________________
gruß
Bernd


Du mußt Deinen Traum finden dann wird der Weg leicht!
derArb
getting better


Verfasst am:
11. Okt 2007, 23:17
Rufname: derArb
Wohnort: Berlin

AW: Textfeld aus Formular in neue Textdatei kopieren - AW: Textfeld aus Formular in neue Textdatei kopieren

Nach oben
       Version: Office 2003

hallo,

schau Dir mal die Möglichkeiten von Select Case in der VBA-OL Hilfe an
Du musst Deinen code dahingehend überlegen, die sich verändernden Werte pro Mitarbeiter in Variablen abzulegen und über Select Case die variablen Mitarbeiterwerte einzusetzen

mfg
derArb

_________________
MfG
derArb

Scio me nihil scire...Εν οίδα οτι ουδέν οίδα... Ich weiss, dass ich nichts weiss (Sokrates)
Ich bevorzuge Beiträge mit korrekter deutscher Grammatik.
Nouba
nicht ganz unwissend :)


Verfasst am:
12. Okt 2007, 02:34
Rufname:
Wohnort: Berlin

AW: Textfeld aus Formular in neue Textdatei kopieren - AW: Textfeld aus Formular in neue Textdatei kopieren

Nach oben
       Version: Office 2003

Hallo,

hier ist eine Variante mit der MSXML-Bibliothek. Der Kode ist nur dadurch etwas lang geworden, um die Zeilen für's Auge einzurücken, was man in einer Produktivumgebung nicht benötigt.

Code:
Option Explicit

'folgende Verweise sind in VBA zu setzen:
'Microsoft XML Version >=4.0
'Microsoft ActiveX Data Objects Library Version >= 2.5
Sub CreateXFDF()
  Dim objDocument     As New MSXML2.DOMDocument
  Dim objElement      As MSXML2.IXMLDOMElement
  Dim objNode         As MSXML2.IXMLDOMNode
  Dim objRoot         As MSXML2.IXMLDOMElement
  Dim objFieldElement As MSXML2.IXMLDOMElement
 
  'nur zum Formatieren der Ausgabe - eigentlich unnötig
  Dim objReader       As New MSXML2.SAXXMLReader40
  Dim objWriter       As New MSXML2.MXXMLWriter40
  'um eine UTF-8 Ausgabe zu erzielen
  Dim objStream       As New ADODB.Stream
  Dim strXml          As String

  'unsere Beispieldaten
  Dim vFields         As Variant
  'Zählvariable für das Datenfeld
  Dim v               As Variant

  'unsere Beispieldaten
  vFields = Array( _
            Array("A_Projekt", "251.006"), _
            Array("o_name1", "Einkaufzentrum Müggelpark"), _
            Array("o_stras_se", "Am Müggelpark 10 - 12"), _
            Array("o_plz", "15537"), _
            Array("o_ort", "Gosadsen"), _
            Array("Bem_Techniker", "Festtermin am 12.06.07"), _
            Array("typ1", "DTqa 2000"), _
            Array("o_person1", "Herr Pihl"), _
            Array("o_person1_tel", "02232-82380"), _
            Array("AN_1", "0301"), _
            Array("o_zone", "Anfahrtzone 3"), _
            Array("AN_2", "071040"), _
            Array("AA", "WARTUNG") _
            )

  'xml-Deklaration erstellen
  Set objNode = objDocument.createProcessingInstruction("xml", "version='1.0'")
  'und an den Anfang des Dokuments stellen
  objDocument.insertBefore objNode, objDocument.childNodes(0)
  'Wurzel <xfdf> des Dokuments erstellen
  Set objRoot = objDocument.createElement("xfdf")
  'und ins Dokument einfügen
  Set objDocument.documentElement = objRoot
  'Namespace für dir Wurzel definieren
  objRoot.setAttribute "xmlns", "http://ns.adobe.com/xfdf/"
  objRoot.setAttribute "xml:space", "preserve"
  '<ids>-Element erstellen
  Set objNode = objDocument.createElement("ids")
  Set objElement = objNode
  'Attribute für das <ids>-Element festlegen
  objElement.setAttribute "original", ""
  objElement.setAttribute "modified", ""
  '<ids>-Element in Dokument einfügen
  objRoot.appendChild objNode
  '<fields>-Element erstellen
  Set objNode = objDocument.createElement("fields")
  'und dem Dokument anfügen
  objRoot.appendChild objNode
  Set objElement = objNode
  'für unsere Daten im Beispiel-Datenfeld
  For Each v In vFields
    '<field>-Element erstellen
    Set objNode = objDocument.createElement("field")
    Set objFieldElement = objNode
    'name-Attribut erstellen
    objFieldElement.setAttribute "name", v(0)
    'und innerhalb des <fields>-Element einfügen
    objElement.appendChild objNode
    '<value>-Element erstellen
    Set objNode = objDocument.createElement("value")
    'text aus dem Datenfeld eintragen
    objNode.Text = v(1)
    'und innerhalb des <field>-Elements stellen
    objFieldElement.appendChild objNode
  Next
  'wir sind fertig - allerdings fehlen Einrückungen und Zeilenumbrüche
  'vermutlich reicht das hier und kann das Dokument einfach schreiben
  'einfach einmal ausprobieren
  'objDocument.Save "DeinAusgabepfad"
  Debug.Print objDocument.XML

  'mit dem SAXX-Writer und SAXX-Reader tranformieren wir das Dokument
  With objWriter
    .omitXMLDeclaration = False
    .byteOrderMark = True
    .Encoding = "UTF-8"
    .Indent = True
    'wir brauchen einen ADODB-Stream, um das Dokument in UTF-8 Encoding
    'schreiben zu können. VBA verwendet BStrings die immer UTF-16 sind
    objStream.Open
    objStream.Charset = "UTF-8"
    .output = objStream
  End With

  'unser Dokument parsen
  With objReader
    Set .contentHandler = objWriter
    Set .dtdHandler = objWriter
    Set .errorHandler = objWriter
    .putProperty "http://xml.org/sax/properties/lexical-handler", objWriter
    .putProperty "http://xml.org/sax/properties/declaration-handler", objWriter
    .parse objDocument
  End With
 
  'das Schreiben in den Stream komplettieren
  objWriter.flush
  'XML-Datei schreiben
  objStream.SaveToFile "c:\Temp\test.xml", adSaveCreateOverWrite
  'Stream schließen
  objStream.Close
  'Ausgabe im Standard-Programm (Internet Explorer?) öffnen
  FollowHyperlink "file://c:/temp/test.xml"
End Sub

_________________
mit freundlichen Grüssen Nouba

Wenn beim Lesen eines Beitrags der Eindruck entsteht, dass sich der Fragesteller wenig Mühe gegeben hat, so erhöht das nicht unbedingt die Motivation, eine Antwort zu verfassen.
jonnyb2006
VBA Dummie


Verfasst am:
12. Okt 2007, 07:28
Rufname:
Wohnort: Kassel


Re: AW: Textfeld aus Formular in neue Textdatei kopieren - Re: AW: Textfeld aus Formular in neue Textdatei kopieren

Nach oben
       Version: Office 2003

Hallo Arb,
kann ich so damit beginnen:
Code:
    Select Case Mitarbeiter
       Case "Vorname1 NachName1", "Vorname2 NachName2"
    End Select
...nur wie gehts weiter?
_________________
gruß
Bernd


Du mußt Deinen Traum finden dann wird der Weg leicht!
SGast
Gast


Verfasst am:
12. Okt 2007, 08:58
Rufname:

AW: Textfeld aus Formular in neue Textdatei kopieren - AW: Textfeld aus Formular in neue Textdatei kopieren

Nach oben
       Version: Office 2003

Hallo,
ich würde eine (Hilfs)-Tabelle mit den Daten erstellen.
Über ein Kombifeld (mit Datenherkunft Hilfstabelle) kannst du dann den entsprechenden Mitarbeiter auswählen und die zugehörigen variablen Werte ermitteln.

Gruß Steffen
jonnyb2006
VBA Dummie


Verfasst am:
12. Okt 2007, 09:23
Rufname:
Wohnort: Kassel

AW: Textfeld aus Formular in neue Textdatei kopieren - AW: Textfeld aus Formular in neue Textdatei kopieren

Nach oben
       Version: Office 2003

Hallo Steffen,
hab ich grade getan!
Datenherkunft:
Code:
SELECT   id, tblma_name, tblma_vorname, tblma_mail, tblma_sms
FROM     tbl_mitarbeiter
ORDER BY tblma_name;
Nur mir ist absolut nicht klar wie ich da bei einer Auswahl die gewünschte Funktion aufrufen kann bzw. auch die entsprechenden Werte weitergebe!
;-(
gruß
Bernd

_________________
gruß
Bernd


Du mußt Deinen Traum finden dann wird der Weg leicht!
SGast
Gast


Verfasst am:
12. Okt 2007, 09:36
Rufname:

AW: Textfeld aus Formular in neue Textdatei kopieren - AW: Textfeld aus Formular in neue Textdatei kopieren

Nach oben
       Version: Office 2003

Hallo,
du kannst per Code auf einzelnen Werte des Kombifeldes zugreifen:
Bsp:
Code:
    MsgBox Me!cbNameDeinKombi.Column(0)  ' ausgewählter Wert in 1. Spalte
    MsgBox Me!cbNameDeinKombi.Column(1)  ' ausgewählter Wert in 2. Spalte

Gruß Steffen
jonnyb2006
VBA Dummie


Verfasst am:
12. Okt 2007, 10:44
Rufname:
Wohnort: Kassel

Re: AW: Textfeld aus Formular in neue Textdatei kopieren - Re: AW: Textfeld aus Formular in neue Textdatei kopieren

Nach oben
       Version: Office 2003

Geil, das war genau der Ansatz den ich gesucht habe Wink
Toll nun brauche ich den Code nur einmal und kann alle Werte übergeben, danke für die hilfe Wink)))

Hab noch ein weiterführendes "kleines" Problem mit einem JS Code in einem PDF Formular (ich weiß das gehört hier nicht hin aber vielleicht hat einer einen Tipp):
Ich speichere das PDF so:
Code:
    this.saveAs("D:/Kundendienst/eServicebericht/eSB_A0"+
      this.getField("AN_1").value + "-" + 
      this.getField("AN_2").value + "_" + 
      this.getField("A_Projekt").value +  "_" +
      this.getField("Datum_SB").value  + "_MJ_.pdf");
Das Feld "Datum_SB" ist ein datum feld und soll so ausgegeben werden: ddmmjj, leider ist die Ausgabe immer: dd.mm.jj, wie binde ich das gewünschte Format richtig ein?
gruß
Bernd

_________________
gruß
Bernd


Du mußt Deinen Traum finden dann wird der Weg leicht!
Nouba
nicht ganz unwissend :)


Verfasst am:
12. Okt 2007, 12:43
Rufname:
Wohnort: Berlin

AW: Textfeld aus Formular in neue Textdatei kopieren - AW: Textfeld aus Formular in neue Textdatei kopieren

Nach oben
       Version: Office 2003

Hallo,

schau mal, ob this.getField("Datum_SB").value.split('.').join('') die Punkte eliminiert.

_________________
mit freundlichen Grüssen Nouba

Wenn beim Lesen eines Beitrags der Eindruck entsteht, dass sich der Fragesteller wenig Mühe gegeben hat, so erhöht das nicht unbedingt die Motivation, eine Antwort zu verfassen.
jonnyb2006
VBA Dummie


Verfasst am:
12. Okt 2007, 13:03
Rufname:
Wohnort: Kassel

Re: AW: Textfeld aus Formular in neue Textdatei kopieren - Re: AW: Textfeld aus Formular in neue Textdatei kopieren

Nach oben
       Version: Office 2003

Hey, das geht Wink)))

Vielen Dank das war nun noch das "i" Tüpfelchen .....tolles Forum!!!!!!!!!!!!!!

gruß
Bernd

_________________
gruß
Bernd


Du mußt Deinen Traum finden dann wird der Weg leicht!
LindaDeMol
Gast


Verfasst am:
21. Jun 2009, 14:51
Rufname:

AW: Textfeld aus Formular in neue Textdatei kopieren - AW: Textfeld aus Formular in neue Textdatei kopieren

Nach oben
       Version: Office 2k (2000)

Hallo Nouba,

habe Deinen Code mal testen wollen, habe aber das Problem, dass ein Fehler an dieser Stelle auftritt:

.output = objStream

Laufzeitfehler 5
Ungültiger Prozeduraufruf oder ungültiges Argument.

Habe mir die ADO 2.5 vorher installiert und den Verweis darauf gesetzt !
Hast Du vielleicht eine Erklärung dafür ?

Viele Grüße
Nouba
nicht ganz unwissend :)


Verfasst am:
24. Jun 2009, 12:43
Rufname:
Wohnort: Berlin


AW: Textfeld aus Formular in neue Textdatei kopieren - AW: Textfeld aus Formular in neue Textdatei kopieren

Nach oben
       Version: Office 2003

Hallo LindaDeMol,

ich weiß nicht, was da bei Dir hakt. Bei mir läuft der Kode durch, wenn ich die im Kommentar angegeben Verweise setze.

_________________
mit freundlichen Grüssen Nouba

Wenn beim Lesen eines Beitrags der Eindruck entsteht, dass sich der Fragesteller wenig Mühe gegeben hat, so erhöht das nicht unbedingt die Motivation, eine Antwort zu verfassen.
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Gehe zu Seite Zurück  1, 2
Diese Seite Freunden empfehlen

Seite 2 von 2
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Access Tabellen & Abfragen: Formeln vom Formular, werden in der Abfrage nicht angezeigt 4 maddes 895 23. Nov 2004, 12:38
Skogafoss Formeln vom Formular, werden in der Abfrage nicht angezeigt
Keine neuen Beiträge Access Tabellen & Abfragen: Textlänge in einem Textfeld 4 brauchehilfe@office 2425 30. Okt 2004, 00:05
brauchehilfe@office Textlänge in einem Textfeld
Keine neuen Beiträge Access Tabellen & Abfragen: Importspezifikationen kopieren 1 Barbara 4336 26. Okt 2004, 11:23
Skogafoss Importspezifikationen kopieren
Keine neuen Beiträge Access Tabellen & Abfragen: In Abfrage nachträglich neue Tabelle einfügen 2 Chris79 498 13. Okt 2004, 22:18
Gast In Abfrage nachträglich neue Tabelle einfügen
Keine neuen Beiträge Access Tabellen & Abfragen: Zeile der Dateneingabe (*) in einem Formular verschieben 2 Albertus 790 08. Okt 2004, 09:17
Albertus Zeile der Dateneingabe (*) in einem Formular verschieben
Keine neuen Beiträge Access Tabellen & Abfragen: Suchfunktion mit mehreren Kriterien aus Formular 5 Danny G. 2218 09. Sep 2004, 11:08
Danny G. Suchfunktion mit mehreren Kriterien aus Formular
Keine neuen Beiträge Access Tabellen & Abfragen: Tabelle, Formular, Abfrage...und nun ? 3 Gags 790 29. Aug 2004, 22:05
lothi Tabelle, Formular, Abfrage...und nun ?
Keine neuen Beiträge Access Tabellen & Abfragen: Abfragefeld nachträglich in Formular 3 Sebbl 1705 05. Aug 2004, 15:14
mabe38 Abfragefeld nachträglich in Formular
Keine neuen Beiträge Access Tabellen & Abfragen: 24 felder aus 1 DS in 24 versch. Datensätze kopieren. 3 Mirko 593 30. Jul 2004, 13:55
Willi Wipp 24 felder aus 1 DS in 24 versch. Datensätze kopieren.
Keine neuen Beiträge Access Tabellen & Abfragen: Formular aus Endlosformular öffnen ? 10 G-Markus 1619 20. Jul 2004, 15:38
Gast Formular aus Endlosformular öffnen ?
Keine neuen Beiträge Access Tabellen & Abfragen: in einem Textfeld letztes Zeichen löschen? 2 mokona.s 1923 19. Jul 2004, 13:24
mokona.s in einem Textfeld letztes Zeichen löschen?
Keine neuen Beiträge Access Tabellen & Abfragen: Kreuztabellenabfrage für neue Tabelle nutzen 3 WaterMan 805 06. Jul 2004, 14:39
mabe38 Kreuztabellenabfrage für neue Tabelle nutzen
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: MS Frontpage