Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Exportieren nach neu erstellte Excelmappe
zurück: Leerzeilen in Kombinationsfeld entfernen weiter: Navigationsleiste zählt im Formular & Unterformular Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Feedback Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
Cataal
Gast


Verfasst am:
23. Jul 2007, 15:28
Rufname:

Exportieren nach neu erstellte Excelmappe - Exportieren nach neu erstellte Excelmappe

Nach oben
       Version: Office 2k (2000)

Hallo Leute,

Vielleicht könnt ihr mir weiter helfen? Folgender Code lauft Super aber ich hätte lieber dass gefragt wird wo ich speichern möchte. Die Excelmappe sollte dabei neu erstellt werden. Weiss aber leider nicht wie anpassen. Vielleicht könnt ihr da helfen? Gruss, Robert
Code:
Private Sub cmdExport_Click()
    ' Netzwerkpfad für export
    Const ExcelDateiName = "U:\Optionen\Desktop\mappe2.xls"
' Abfrage wird automatisch erzeugt und wieder gelöscht
    Const tmpAbfrage = "KUNDEN"
    Dim sSQL As String
    Dim qdf As DAO.QueryDef
   
    If Me!AUSWERTUNG.Form.Filter > "" Then
        sSQL = "SELECT * " & _
                 "FROM " & Me!AUSWERTUNG.Form.RecordSource & _
               " WHERE " & Me!AUSWERTUNG.Form.Filter
      Else
        sSQL = "SELECT * " & _
                 "FROM " & Me!AUSWERTUNG.Form.RecordSource
    End If
    MsgBox sSQL
    Debug.Print sSQL
' evtl. alte Abfrage löschen
    On Error Resume Next
    DoCmd.DeleteObject acQuery, tmpAbfrage
    On Error GoTo 0
    Set qdf = CurrentDb.CreateQueryDef(tmpAbfrage, sSQL)
    DoCmd.TransferSpreadsheet acExport, 8, tmpAbfrage, ExcelDateiName, True
'    DoCmd.DeleteObject acQuery, "tmpAbfrage"
End Sub
Nouba
nicht ganz unwissend :)


Verfasst am:
23. Jul 2007, 22:43
Rufname:
Wohnort: Berlin

AW: Exportieren nach neu erstellte Excelmappe - AW: Exportieren nach neu erstellte Excelmappe

Nach oben
       Version: Office 2k (2000)

Hallo,

Du könntest einen Dateiauswahldialog implementieren.

Code:
'Kode in globalem Modul ablegen
Option Explicit

Function SaveFileWH(Optional DialogTitle As String = "Datei speichern", _
                    Optional ButtonCaption As String = "Speichern", _
                    Optional InitialFolder As String, _
                    Optional Filter As String = "Alle Dateien (*.*)") As String
  Static LastFolder      As String

  'weitere Beschreibung unter: _
   http://www.team-moeller.de/access/tiptrick/wizhook/getfilename.html
   
  On Error GoTo SaveFileWH_Fehler
  WizHook.Key = &H311A68F
  If Not CBool(Len(InitialFolder)) Then
    If CBool(Len(LastFolder)) Then
      InitialFolder = LastFolder
    Else
      InitialFolder = CurrentProject.Path
    End If
  End If
  If WizHook.GetFileName(hWndAccessApp, "Microsoft Access", DialogTitle, _
                         ButtonCaption, SaveFileWH, InitialFolder, Filter, _
                         0, 0, 4, False) = 0 Then
    LastFolder = Left$(SaveFileWH, InStrRev(SaveFileWH, "\"))
  Else
    SaveFileWH = vbNullString
  End If

  Exit Function

SaveFileWH_Fehler:
  MsgBox Err.Description & " in SaveFileWH", , "Fehler-Nr.: " & Err.Number
End Function

'Kode für das Formular-Klassenmodul
Private Sub cmdExport_Click()
  'Standard-Netzwerkpfad für Export
  Const ExcelPfad = "U:\Optionen\Desktop"

  ' Abfrage wird automatisch erzeugt und wieder gelöscht
  Const tmpAbfrage = "KUNDEN"

  Dim sSQL               As String
  Dim qdf                As DAO.QueryDef
  Dim sFileName          As String

  On Error GoTo cmdExport_Click_Fehler

  sFileName = SaveFileWH(DialogTitle:="Abfrage als Excel-Datei speichern", _
                         InitialFolder:=ExcelPfad, _
                         Filter:="MicrosoftOffice Excel (*.xls)")
  If Len(sFileName) = 0 Then Exit Sub

  With Me!AUSWERTUNG.Form
    sSQL = "SELECT * FROM " & "[" & .RecordSource & "]"
    If CBool(Len(.Filter)) Then
      sSQL = sSQL & " WHERE " & .Filter
    End If
  End With

  'MsgBox sSQL
  'Debug.Print sSQL
  ' evtl. alte Abfrage löschen
  On Error Resume Next
  DoCmd.DeleteObject acQuery, tmpAbfrage
  On Error GoTo cmdExport_Click_Fehler
  Set qdf = CurrentDb().CreateQueryDef(tmpAbfrage, sSQL)
  DoCmd.TransferSpreadsheet acExport, , tmpAbfrage, ExcelDateiName

  'DoCmd.DeleteObject acQuery, "tmpAbfrage"
  Exit Sub

cmdExport_Click_Fehler:
  MsgBox Err.Description & " in cmdExport_Click", , "Fehler-Nr.: " & Err.Number
End Sub

_________________
mit freundlichen Grüssen Nouba

Wenn beim Lesen eines Beitrags der Eindruck entsteht, dass sich der Fragesteller wenig Mühe gegeben hat, so erhöht das nicht unbedingt die Motivation, eine Antwort zu verfassen.
Cataal
Gast


Verfasst am:
26. Jul 2007, 15:35
Rufname:


AW: Exportieren nach neu erstellte Excelmappe - AW: Exportieren nach neu erstellte Excelmappe

Nach oben
       Version: Office 2k (2000)

Hallo Nouba,

Sorry dass ich erst jetzt antworte. Du hast mir sehr geholfen! Habe das Ganze bei mir implementiert und nach ein paar kleinere Änderungen laufts einwandfrei.
Einfach SUPER!

Vielen Dank und Grüsse, Robert
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Diese Seite Freunden empfehlen

Seite 1 von 1
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Access Tabellen & Abfragen: Datenbank in eine Textdatei exportieren? 1 Dominik C. 503 13. Okt 2008, 17:46
rita2008 Datenbank in eine Textdatei exportieren?
Keine neuen Beiträge Access Tabellen & Abfragen: Zugriff auf erstellte Tabelle in Mehrbenutzerumgebung 3 Smmmile 681 25. Jul 2008, 22:41
Smmmile Zugriff auf erstellte Tabelle in Mehrbenutzerumgebung
Keine neuen Beiträge Access Tabellen & Abfragen: 2 Tabellen auslesen und als excel exportieren 0 Hobo2k 392 27. Nov 2007, 10:50
Hobo2k 2 Tabellen auslesen und als excel exportieren
Keine neuen Beiträge Access Tabellen & Abfragen: Abfrage exportieren 3 oliver198 499 25. Apr 2007, 09:37
SGast Abfrage exportieren
Keine neuen Beiträge Access Tabellen & Abfragen: Formularabfrage in Excel exportieren 1 ChristophT 702 13. Feb 2007, 13:54
ChristophT Formularabfrage in Excel exportieren
Keine neuen Beiträge Access Tabellen & Abfragen: SQL-Abfrage (VBA) nach Excel exportieren 2 _hoschi_ 9567 19. Dez 2006, 10:03
_hoschi_ SQL-Abfrage (VBA) nach Excel exportieren
Keine neuen Beiträge Access Tabellen & Abfragen: Abfrageergebnis in txt/csv exportieren ABER: aneinanderger. 3 marco_delitz 801 03. Nov 2006, 10:22
Nouba Abfrageergebnis in txt/csv exportieren ABER: aneinanderger.
Keine neuen Beiträge Access Tabellen & Abfragen: Tabelle bzw Abfrage neu nummerieren? A03 4 Gast 1003 19. Jul 2006, 11:03
Willi Wipp Tabelle bzw Abfrage neu nummerieren? A03
Keine neuen Beiträge Access Tabellen & Abfragen: 5000 als 5.000,0 als Zahl nach Excel exportieren 4 OlliWirr 1196 06. Jul 2006, 20:51
Gast 5000 als 5.000,0 als Zahl nach Excel exportieren
Keine neuen Beiträge Access Tabellen & Abfragen: Daten mit AutoWert exportieren 8 Frankie 888 22. Jun 2006, 13:25
Frankie Daten mit AutoWert exportieren
Keine neuen Beiträge Access Tabellen & Abfragen: nachträglich erstellte Tabelle im Frm. mit einbinden 4 Tom72 1000 29. Mai 2006, 18:48
Tom72 nachträglich erstellte Tabelle im Frm. mit einbinden
Keine neuen Beiträge Access Tabellen & Abfragen: access abfragen zu mysql/php exportieren 0 death2dadas 1110 28. März 2006, 19:14
death2dadas access abfragen zu mysql/php exportieren
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: Word VBA