Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Formular öffnen mit Datumseinschränkung
Gehe zu Seite 1, 2  Weiter
zurück: ergebniss automatisch in 2. formular oder tabelle speichern weiter: Uhrzeit ohne Datum Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Feedback Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
highjumper83
VBA-einsteiger


Verfasst am:
12. Jun 2007, 13:08
Rufname:
Wohnort: Bautzen

Formular öffnen mit Datumseinschränkung - Formular öffnen mit Datumseinschränkung

Nach oben
       Version: Office 2003

Hallo ich möchte aus einem Formular heraus ein anderes öffnen und dabei Diverse Einschränkungen haben.
Es sollen nur Datensätze in einem bestimmten Datumsraum (als Startdatum und Enddatum) gefiltert werden und zusätlich noch Werte aus einem Integerfeld.
Nun wollte ich dieses Link-Kriterium nach und nach aufbauen, allerdings scheitert es schon beim Startdatum. Ich habe bis jetzt:
Code:
    stLinkCriteria = "[Datum]=#" & Me![Datum_von] & "#"
und da kommt der Fehler:
Zitat:
Syntax error in number in query expression '[Datum]=12.12.2006'.
Was mache ich falsch? Da müsste ich dann auch noch mit < und > arbeiten, bekomme ich da noch mehr Probleme?

Viele Grüße

highjumper83
Willi Wipp
Moderator


Verfasst am:
12. Jun 2007, 14:30
Rufname:
Wohnort: Raum Wiesbaden


Re: Formular öffnen mit Datumseinschränkung - Re: Formular öffnen mit Datumseinschränkung

Nach oben
       Version: Office 2003

Hi highjumper83,

da koennte Dir das Thema VBA und SQL Datum sicher weiter helfen Wink

_________________
Eine kurze Rueckmeldung waere nett
SL Willi Wipp

(Anleitung fuer das Anhaengen von Dateien: Klicke links auf [www], Gaeste muessen sich dafuer anmelden)
highjumper83
VBA-einsteiger


Verfasst am:
12. Jun 2007, 15:44
Rufname:
Wohnort: Bautzen

AW: Formular öffnen mit Datumseinschränkung - AW: Formular öffnen mit Datumseinschränkung

Nach oben
       Version: Office 2003

Mhh, ich hab das mal versucht umzusetzen, aber leider hab ichs nicht geschaft.
Bis jetzt hab ich:
Code:
    Dim stDocName As String
    Dim stLinkCriteria As String
    Dim DatSQL As String
   
    DatSQL = Format(CDate(Me!Datum_von), "\#mm\/dd\/yyyy\#")
    stDocName = "_F_Konto"
    'stLinkCriteria = "[Datum]=" & "#" & Me![Datum_von] & "#"
    stLinkCriteria = "[Datum]=" & DatSQL
    DoCmd.OpenForm stDocName, , , stLinkCriteria
Und das gibt mir ein "Fehler beim Kompilieren". Was ist da Falsch?
Muss ich da mein Datum-Feld auch noch Formatieren?
Bin für Hilfe dankbar.
Willi Wipp
Moderator


Verfasst am:
12. Jun 2007, 19:30
Rufname:
Wohnort: Raum Wiesbaden

Re: Formular öffnen mit Datumseinschränkung (II) - Re: Formular öffnen mit Datumseinschränkung (II)

Nach oben
       Version: Office 2003

Hi highjumper83,

und wenn Du uns dann noch mitteilst wo diese Meldung kommt, dann faellt und vielleicht was dazu ein Wink
Code:
    Dim stDocName As String
    Dim stLinkCriteria As String
    Dim DatSQL As String
   
    Debug.Print Me!Datum_von 'Ausgabe im Direktbereich (Strg+G; Testfenster)
    DatSQL = Format(CDate(Me!Datum_von), "\#mm\/dd\/yyyy\#")
    Debug.Print DatSQL
    stDocName = "_F_Konto"
    'stLinkCriteria = "[Datum]=" & "#" & Me![Datum_von] & "#"
    stLinkCriteria = "[Datum]=" & DatSQL
    DoCmd.OpenForm stDocName, , , stLinkCriteria

_________________
Eine kurze Rueckmeldung waere nett
SL Willi Wipp

(Anleitung fuer das Anhaengen von Dateien: Klicke links auf [www], Gaeste muessen sich dafuer anmelden)
highjumper83
VBA-einsteiger


Verfasst am:
12. Jun 2007, 19:50
Rufname:
Wohnort: Bautzen


AW: Formular öffnen mit Datumseinschränkung - AW: Formular öffnen mit Datumseinschränkung

Nach oben
       Version: Office 2003

Die Fehlermeldung erscheind sofort nach Aufruf des Privat Sub.
Der Spring nicht mal bis zur Zeile:
Code:
    Debug.Print Me!Datum_von 'Ausgabe im Direktbereich (Strg+G; Testfenster)
(Hab ich mit nem Haltepunkt überprüft)

War das die richtige Antwort auf deine Frage? Wenn nicht dann frag nochmal nach!

Gruß higjumper
Willi Wipp
Moderator


Verfasst am:
12. Jun 2007, 19:55
Rufname:
Wohnort: Raum Wiesbaden

Re: Formular öffnen mit Datumseinschränkung (II) - Re: Formular öffnen mit Datumseinschränkung (II)

Nach oben
       Version: Office 2003

Hi highjumper83,

welche Zeile wird noch markiert, ausser dem Prozedurkopf?
Code:
    Dim stDocName As String
    Dim stLinkCriteria As String
    Dim DatSQL As String
       
    If Not IsDate(Me!Datum_von) Then
        MsgBox "Kein Datum!", vbExclamation
        Exit Function ' oder Sub
    End If
    Debug.Print Me!Datum_von 'Ausgabe im Direktbereich (Strg+G; Testfenster)
    DatSQL = Format(CDate(Me!Datum_von), "\#mm\/dd\/yyyy\#")
    Debug.Print DatSQL
    stDocName = "_F_Konto"
    'stLinkCriteria = "[Datum]=" & "#" & Me![Datum_von] & "#"
    stLinkCriteria = "[Datum]=" & DatSQL
    DoCmd.OpenForm stDocName, , , stLinkCriteria

_________________
Eine kurze Rueckmeldung waere nett
SL Willi Wipp

(Anleitung fuer das Anhaengen von Dateien: Klicke links auf [www], Gaeste muessen sich dafuer anmelden)
highjumper83
VBA-einsteiger


Verfasst am:
12. Jun 2007, 20:21
Rufname:
Wohnort: Bautzen

AW: Formular öffnen mit Datumseinschränkung - AW: Formular öffnen mit Datumseinschränkung

Nach oben
       Version: Office 2003

Keine. Ich hab den Stop in die erste Programmzeile nach den Dimensionierungen gestellt und da kommt der gar nicht hin. Das ist echt kommisch, der springt sofort zu
Code:
Exit_F_Konto_Datum_Click:
    Exit Function
runter.
Willi Wipp
Moderator


Verfasst am:
12. Jun 2007, 23:24
Rufname:
Wohnort: Raum Wiesbaden

Re: Formular öffnen mit Datumseinschränkung (III) - Re: Formular öffnen mit Datumseinschränkung (III)

Nach oben
       Version: Office 2003

Hi highjumper83,

und wo bitte hast Du jetzt ploetzlich die Fehlerbehandlung her?
Ist es auch wirklich eine Function oder vielleicht eine Sub?
Welche Fehlermeldung kommt jetzt genau, vollstaendig?
Zeig mal die ganze Prozedur/Funktion in der der Fehler kommt.
Kommentiere die Fehlerbehandlung aus, sonst bekommst Du Fehlerstelle nicht sauber markiert.

_________________
Eine kurze Rueckmeldung waere nett
SL Willi Wipp

(Anleitung fuer das Anhaengen von Dateien: Klicke links auf [www], Gaeste muessen sich dafuer anmelden)
highjumper83
VBA-einsteiger


Verfasst am:
13. Jun 2007, 12:01
Rufname:
Wohnort: Bautzen

AW: Formular öffnen mit Datumseinschränkung - AW: Formular öffnen mit Datumseinschränkung

Nach oben
       Version: Office 2003

Ich hab mir nochmal nen neuen Button erstellt und die Funktion neu aufgebaut und auf einmal funktioniert es. Wer weiß was das war.
Allerdings stehe ich schon vor dem nächsten Problem. Ich hab jetzt da so schöne If-Anweisungen geschrieben, dass der nur bestimmte Filter setzt wenn einige Felder leer sind.
Code:
    If Me!Verbuchungsort = Null Then
        If Me!Datum_von = Null Then
            If Me!Datum_bis = Null Then
                MsgBox "Du musst ein  Wert in" & Chr(13) & _
                       "Verbuchungsort, von oder bis eingeben"
              Else
                DatSQL_bis = Format(CDate(Me!Datum_bis), "\#mm\/dd\/yyyy\#")
                stLinkCriteria = "[Datum]<" & DatSQL_bis
            End If
          Else
            If Me!Datum_bis = Null Then
                DatSQL_von = Format(CDate(Me!Datum_von), "\#mm\/dd\/yyyy\#")
                stLinkCriteria = "[Datum]>" & DatSQL_von
              Else
                DatSQL_von = Format(CDate(Me!Datum_von), "\#mm\/dd\/yyyy\#")
                DatSQL_bis = Format(CDate(Me!Datum_bis), "\#mm\/dd\/yyyy\#")
                stLinkCriteria = "[Datum]<" & DatSQL_bis & _
                            " AND [Datum]>" & DatSQL_von
            End If
        End If
      Else
        If Me!Datum_von = Null Then
            If Me!Datum_bis = Null Then
                stLinkCriteria = "[Verbuchungsort]=" & Me![Verbuchungsort]
              Else
                DatSQL_bis = Format(CDate(Me!Datum_bis), "\#mm\/dd\/yyyy\#")
                stLinkCriteria = "[Datum]<" & DatSQL_bis & _
                            " AND [Verbuchungsort]>" & Me![Verbuchungsort]
            End If
          Else
            If Me!Datum_bis = Null Then
                DatSQL_von = Format(CDate(Me!Datum_von), "\#mm\/dd\/yyyy\#")
                stLinkCriteria = "[Datum]>" & DatSQL_von & _
                            " AND [Verbuchungsort]>" & Me![Verbuchungsort]
              Else
                DatSQL_von = Format(CDate(Me!Datum_von), "\#mm\/dd\/yyyy\#")
                DatSQL_bis = Format(CDate(Me!Datum_bis), "\#mm\/dd\/yyyy\#")
                stLinkCriteria = "[Datum]<" & DatSQL_bis & _
                            " AND [Datum]>" & DatSQL_von & _
                            " AND [Verbuchungsort] =" & Me![Verbuchungsort]
            End If
        End If
   End If
Allerdings springt der mir über die If-Anweisungen drüber zur else auch wenn mein Feld leer ist.

Bsp.: Ich lasse das Feld Me!Verbuchungsort leer (Null) dann müsste der an der Zeile
Code:
        If Me!Verbuchungsort = Null Then
erkennen Null=Null (das erkennt er auch) und in die nächste Zeile springen.
Code:
        If Me!Datum_von = Null Then
Hier springt das Programm aber nicht hin sondern zum Else-Befehl der ersten Anweisung. (Als wenn der Verbuchungsort nicht leer wäre.)

Dieses Phänomän tritt in allen If-Anweisungen auf. Er erkennt immer richtig, dass das Feld leer ist und tut aber so als wäre es gefült.

Warum?

Grüße Highjumper
Willi Wipp
Moderator


Verfasst am:
13. Jun 2007, 14:21
Rufname:
Wohnort: Raum Wiesbaden

Re: Formular öffnen mit Datumseinschränkung (IV) - Re: Formular öffnen mit Datumseinschränkung (IV)

Nach oben
       Version: Office 2003

Hi highjumper83,

das wird Anderen die das Thema lesen sicher weiterhelfen Confused
Ich gehe davon aus es lag an dem End Function in einer Prozedur (Sub).
Das sollte aber aus der vollstaendicgen Fehlermeldung ersichtlich sein.

Mann kann nicht auf = Null pruefen.
Verwende entweder die Funktion IsNull oder fange Null-Werte mit Nz ab.

_________________
Eine kurze Rueckmeldung waere nett
SL Willi Wipp

(Anleitung fuer das Anhaengen von Dateien: Klicke links auf [www], Gaeste muessen sich dafuer anmelden)
highjumper83
VBA-einsteiger


Verfasst am:
13. Jun 2007, 17:44
Rufname:
Wohnort: Bautzen

AW: Formular öffnen mit Datumseinschränkung - AW: Formular öffnen mit Datumseinschränkung

Nach oben
       Version: Office 2003

highjumper83 am 13. Jun 2007 um 17:31 hat folgendes geschrieben:
Ok, zum besseren Nachvollziehen hier noch mal der alte, nicht funktionstüchtige code:
Code:
Private Sub F_Konto_Datum_Click()
On Error GoTo Err_F_Konto_Datum_Click
    Dim stDocName As String
    Dim stLinkCriteria As String
    Dim DatSQL As String
   
    Debug.Print Me!Datum_von 'Ausgabe im Direktbereich (Strg+G; Testfenster)
    DatSQL = Format(CDate(Me!Datum_von), "\#mm\/dd\/yyyy\#")
    Debug.Print DatSQL
    stDocName = "_F_Konto"
    'stLinkCriteria = "[Datum]=" & "#" & Me![Datum_von] & "#"
    stLinkCriteria = "[Datum]=" & DatSQL
    DoCmd.OpenForm stDocName, , , stLinkCriteria
Exit_F_Konto_Datum_Click:
    Exit Function
Err_F_Konto_Datum_Click:
    MsgBox Err.Description
    Resume Exit_F_Konto_Datum_Click
End Function
Am richtigen bastel ich noch.

So nun der korriegierte Code:
Code:
Private Sub test_öffnen_Click()
On Error GoTo Err_test_öffnen_Click
    Dim stDocName As String
    Dim stLinkCriteria As String
    Dim Verbuchungsort As Boolean, Datum_von As Boolean, Datum_bis As Boolean
   
    stDocName = "F_Konto"
    Verbuchungsort = IsNull(Me!Verbuchungsort)
    Datum_von = IsNull(Me!Datum_von)
    Datum_bis = IsNull(Me!Datum_bis)
    If Verbuchungsort = True Then                        'Leer: Berbuchungsort
        If Datum_von = True Then                    'Leer: Berbuchungsort, Von
            If Datum_bis = True Then           'Leer: Berbuchungsort, Von, Bis
                MsgBox "Du musst ein  Wert in" & Chr(13) & _
                       "Verbuchungsort, VON oder BIS eingeben"
              Else                                  'Leer: Berbuchungsort, Von
                DatSQL_bis = Format(CDate(Me!Datum_bis), "\#mm\/dd\/yyyy\#")
                stLinkCriteria = "[Datum]<" & DatSQL_bis
                DoCmd.OpenForm stDocName, , , stLinkCriteria
            End If
          Else
            If Datum_bis = True Then                'Leer: Berbuchungsort, Bis
                DatSQL_von = Format(CDate(Me!Datum_von), "\#mm\/dd\/yyyy\#")
                stLinkCriteria = "[Datum]>" & DatSQL_von
                DoCmd.OpenForm stDocName, , , stLinkCriteria
              Else                                       'Leer: Berbuchungsort
                DatSQL_von = Format(CDate(Me!Datum_von), "\#mm\/dd\/yyyy\#")
                DatSQL_bis = Format(CDate(Me!Datum_bis), "\#mm\/dd\/yyyy\#")
                stLinkCriteria = "[Datum]<" & DatSQL_bis & _
                            " AND [Datum]>" & DatSQL_von
                DoCmd.OpenForm stDocName, , , stLinkCriteria
            End If
        End If
      Else
        If Datum_von = True Then
            If Datum_bis = True Then                           'Leer: Von, Bis
                stLinkCriteria = "[Verbuchungsort]=" & Me![Verbuchungsort]
                DoCmd.OpenForm stDocName, , , stLinkCriteria
              Else                                                  'Leer: Von
                DatSQL_bis = Format(CDate(Me!Datum_bis), "\#mm\/dd\/yyyy\#")
                stLinkCriteria = "[Datum]<" & DatSQL_bis & _
                            " AND [Verbuchungsort]=" & Me![Verbuchungsort]
                DoCmd.OpenForm stDocName, , , stLinkCriteria
            End If
          Else
            If Datum_bis = True Then                                'Leer: Bis
                DatSQL_von = Format(CDate(Me!Datum_von), "\#mm\/dd\/yyyy\#")
                stLinkCriteria = "[Datum]>" & DatSQL_von & _
                            " AND [Verbuchungsort]=" & Me![Verbuchungsort]
                DoCmd.OpenForm stDocName, , , stLinkCriteria
              Else
                DatSQL_von = Format(CDate(Me!Datum_von), "\#mm\/dd\/yyyy\#")
                DatSQL_bis = Format(CDate(Me!Datum_bis), "\#mm\/dd\/yyyy\#")
                stLinkCriteria = "[Datum]<" & DatSQL_bis & _
                            " AND [Datum]>" & DatSQL_von & _
                            " AND [Verbuchungsort] =" & Me![Verbuchungsort]
                DoCmd.OpenForm stDocName, , , stLinkCriteria
            End If
        End If
    End If
Exit_test_öffnen_Click:
    Exit Sub
Err_test_öffnen_Click:
    MsgBox Err.Description
    Resume Exit_test_öffnen_Click
End Sub
Willi Wipp
Moderator


Verfasst am:
13. Jun 2007, 18:05
Rufname:
Wohnort: Raum Wiesbaden

Re: Formular öffnen mit Datumseinschränkung (V) - Re: Formular öffnen mit Datumseinschränkung (V)

Nach oben
       Version: Office 2003

Hi highjumper83,

oder so Wink
Code:
Private Sub test_öffnen_Click()
On Error GoTo Err_test_öffnen_Click
    Dim stDocName As String
    Dim stLinkCriteria As String
   
    stDocName = "F_Konto"
    stLinkCriteria
    If IsDate(CDate(Me!Datum_bis)) Then                       'Nicht Leer: Bis
        stLinkCriteria = stLinkCriteria & _
                         " AND [Datum] <" & Format(CDate(Me!Datum_bis), _
                                                   "\#mm\/dd\/yyyy\#")
    End If
    If IsDate(CDate(Me!Datum_von)) Then                       'Nicht Leer: Von
        stLinkCriteria = stLinkCriteria & _
                         " AND [Datum] >" & Format(CDate(Me!Datum_von), _
                                                   "\#mm\/dd\/yyyy\#")
    End If
    If Trim(Nz(Verbuchungsort, 0)) <> 0 Then       'Nicht Leer: Berbuchungsort
        stLinkCriteria = stLinkCriteria & _
                         " AND [Verbuchungsort] =" & Me![Verbuchungsort]
    End If
    If stLinkCriteria = "" Then
        MsgBox "Du musst ein  Wert in" & Chr(13) & _
               "Verbuchungsort, VON oder BIS eingeben"
      Else
        stLinkCriteria = Mid$(stLinkCriteria, 6)
        DoCmd.OpenForm stDocName, , , stLinkCriteria
    End If

Exit_test_öffnen_Click:
    Exit Sub
Err_test_öffnen_Click:
    MsgBox Err.Description
    Resume Exit_test_öffnen_Click
End Sub

_________________
Eine kurze Rueckmeldung waere nett
SL Willi Wipp

(Anleitung fuer das Anhaengen von Dateien: Klicke links auf [www], Gaeste muessen sich dafuer anmelden)
highjumper83
VBA-einsteiger


Verfasst am:
13. Jun 2007, 19:00
Rufname:
Wohnort: Bautzen

AW: Formular öffnen mit Datumseinschränkung - AW: Formular öffnen mit Datumseinschränkung

Nach oben
       Version: Office 2003

Hab noch eine erstaunliche Eigenschaft festgestellt.

Die Funktion
Code:
    Verbuchungsort = IsNull(Me!Verbuchungsort)
gibt mir Wahr oder Falsch aus. Wenn ich aber dies dann in folgender Gleichung einsetze muss ich mit True oder False arbeiten.

Code:
    If Verbuchungsort = True Then
Wahrscheinlich auf eine unvollständige Übersetzung von Microsoft zurück zu führen. Sieht nur lustig aus wenn Wahr=True akzeptiert wird.

Gruß highjumper83
Willi Wipp
Moderator


Verfasst am:
13. Jun 2007, 20:07
Rufname:
Wohnort: Raum Wiesbaden

Re: Formular öffnen mit Datumseinschränkung (VI) - Re: Formular öffnen mit Datumseinschränkung (VI)

Nach oben
       Version: Office 2003

Hi highjumper83,

das liegt daran das Access versucht Dir die Arbeit zu erleichtern in dem es die Woerter uebersetzt.
Intern wir immer mit den "Englischen Begriffen" gearbeitet.
Bei der Ausgabe im Direktbereich wird es aber uebersetzt.
Das gleiche Verhalten hast Du bei Kommazahlen. In VBA muss es der Punkt sein.
Im Direktfenster wird aber das Komma angezeigt.

_________________
Eine kurze Rueckmeldung waere nett
SL Willi Wipp

(Anleitung fuer das Anhaengen von Dateien: Klicke links auf [www], Gaeste muessen sich dafuer anmelden)
highjumper83
VBA-einsteiger


Verfasst am:
13. Jun 2007, 20:29
Rufname:
Wohnort: Bautzen


AW: Formular öffnen mit Datumseinschränkung - AW: Formular öffnen mit Datumseinschränkung

Nach oben
       Version: Office 2003

Naja, ist die Frage ob das Arbeitserleichterung ist. Ich bin ja der Meinung alles Einheitlich, also alles Deutsch, oder was wahrscheinlich einfacher ist alles Englisch!
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Gehe zu Seite 1, 2  Weiter
Diese Seite Freunden empfehlen

Seite 1 von 2
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Access Tabellen & Abfragen: Abfrage von Formular zu mehreren Tabellen gleichzeitig 5 Friedel 1237 22. Mai 2005, 11:06
jens05 Abfrage von Formular zu mehreren Tabellen gleichzeitig
Keine neuen Beiträge Access Tabellen & Abfragen: Formular --> Tabelle ? 6 AlexisM 835 27. Apr 2005, 10:56
AlexisM Formular --> Tabelle ?
Keine neuen Beiträge Access Tabellen & Abfragen: Anzahl der Datensätze zählen (im Formular oder Bericht) ? 3 anna-bolika 3756 31. März 2005, 12:50
Dalmatinchen Anzahl der Datensätze zählen (im Formular oder Bericht) ?
Keine neuen Beiträge Access Tabellen & Abfragen: Formular: Groesse? 1 Gast 732 24. März 2005, 13:35
Sanne Formular: Groesse?
Keine neuen Beiträge Access Tabellen & Abfragen: Feld wird nicht in Formular angezeigt 1 Chef_1 528 12. März 2005, 21:27
stpimi Feld wird nicht in Formular angezeigt
Keine neuen Beiträge Access Tabellen & Abfragen: Automatische Aktualisierung von generiertem Wert im Formular 9 GandalfTCM 1041 09. Feb 2005, 17:40
lothi Automatische Aktualisierung von generiertem Wert im Formular
Keine neuen Beiträge Access Tabellen & Abfragen: Wert übernehmen von einem Formular in das andere 2 mactoolz 1244 03. Feb 2005, 17:46
ralphkr Wert übernehmen von einem Formular in das andere
Keine neuen Beiträge Access Tabellen & Abfragen: Abfrage mit Formular gestalten 3 HBurmei 1977 03. Dez 2004, 22:17
mapet Abfrage mit Formular gestalten
Keine neuen Beiträge Access Tabellen & Abfragen: Formular für mehrere Abfragen benutzen 2 Oli aus Bonn 1262 21. Nov 2004, 01:30
Oli aus Bonn Formular für mehrere Abfragen benutzen
Keine neuen Beiträge Access Tabellen & Abfragen: Wert eines Feldes aus Formular in Tabelle speichern 18 kave78 13710 16. Okt 2004, 13:40
Ming Wert eines Feldes aus Formular in Tabelle speichern
Keine neuen Beiträge Access Tabellen & Abfragen: Standardwert in Formular aus einer Abfrage? 3 Gast 1777 04. Okt 2004, 12:53
Pfobeman Standardwert in Formular aus einer Abfrage?
Keine neuen Beiträge Access Tabellen & Abfragen: Suchen in Formular 1 Sumo_Racer 1092 28. Mai 2004, 21:59
lothi Suchen in Formular
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: Dreamweaver Forum