Office Forum
www.Office-Loesung.de
Access :: Excel :: Outlook :: PowerPoint :: Word :: Office :: Wieder Online ---> provisorisches Office Forum <-
Code 128 (Barcode) TrueTypeFont Freeware
zurück: excel daten in .csv konvertieren.... weiter: Balkendiagramme mit einer Formel einfärben Unbeantwortete Beiträge anzeigen
Neues Thema eröffnen   Neue Antwort erstellen     Status: Feedback Facebook-Likes Diese Seite Freunden empfehlen
Zu Browser-Favoriten hinzufügen
Autor Nachricht
RobertAleman
Excel-Kenner mit VBA, kein Profi


Verfasst am:
06. Mai 2007, 15:51
Rufname:
Wohnort: Mexico City

Code 128 (Barcode) TrueTypeFont Freeware - Code 128 (Barcode) TrueTypeFont Freeware

Nach oben
       Version: Office XP (2002)

Hallo,
ich kann zwar den Code128 als Funktion in einer Zelle berechnen, aber mir fehlt noch die TTF Schriftart.
Gibt es dafür freeware, die nicht verkrüppelt, unvollständig oder sündhaft teuer ist?
Gruß
Robert
worf
zone-bit-ranger


Verfasst am:
08. Jun 2007, 11:18
Rufname:


AW: Code 128 (Barcode) TruyTypeFont Freeware - AW: Code 128 (Barcode) TruyTypeFont Freeware

Nach oben
       Version: Office XP (2002)

Hi Robert,

probier doch mal die freien Bar-Code-Fonds von dieser Seite und berichte uns hinterher:
{Link nicht mehr aktiv! Edit by Willi Wipp}

Schönen Gruß, Worf
Gast



Verfasst am:
07. Nov 2007, 09:59
Rufname:

AW: Code 128 (Barcode) TruyTypeFont Freeware - AW: Code 128 (Barcode) TruyTypeFont Freeware

Nach oben
       Version: Office XP (2002)

Diese Seite ist nicht mehr aktiv und einen Bericht kam leider auch nicht zu stande...
schade!
Thomas Ramel
Microsoft Excel-MVP


Verfasst am:
07. Nov 2007, 10:13
Rufname: Thom
Wohnort: Glashütten - CH

AW: Code 128 (Barcode) TruyTypeFont Freeware - AW: Code 128 (Barcode) TruyTypeFont Freeware

Nach oben
       Version: Office XP (2002)

Grüezi Gast

Du kannst ja einen Bericht schreiben....

...oder aber mit den Stichworten 'Barcode Font Excel' eine Google-Suche starten.

Ich bin dabei auf die folgenden Seiten gestossen:

Free Barcode Font - Code 39
IDAutomation Free Barcode Font Download

_________________
Mit freundlichen Grüssen

Thomas Ramel
[Vista Ultimate SP-1 / xl2007 SP-2]
dirk123
Gast


Verfasst am:
16. Jul 2008, 15:44
Rufname:


AW: Code 128 (Barcode) TruyTypeFont Freeware - AW: Code 128 (Barcode) TruyTypeFont Freeware

Nach oben
       

hier gibt es einen Barcodefont code128: Le code 128
Pammi5
Gast


Verfasst am:
11. Sep 2008, 17:19
Rufname:

AW: Code 128 (Barcode) TrueTypeFont Freeware - AW: Code 128 (Barcode) TrueTypeFont Freeware

Nach oben
       Version: Office XP (2002)

Ist das freeware?

Kann kein Französisch und nur schlecht englisch.

Torsten
Thomas Ramel
Microsoft Excel-MVP


Verfasst am:
11. Sep 2008, 21:58
Rufname: Thom
Wohnort: Glashütten - CH

AW: Code 128 (Barcode) TrueTypeFont Freeware - AW: Code 128 (Barcode) TrueTypeFont Freeware

Nach oben
       Version: Office XP (2002)

Grüezi Torsten

Ja, soweit ich das beurteilen kann sind das Links zu Freeware-Fonts.

_________________
Mit freundlichen Grüssen

Thomas Ramel
[Vista Ultimate SP-1 / xl2007 SP-2]
Gast



Verfasst am:
14. Jul 2009, 09:14
Rufname:

AW: Code 128 (Barcode) TrueTypeFont Freeware - AW: Code 128 (Barcode) TrueTypeFont Freeware

Nach oben
       Version: Office XP (2002)

hallo!

wäre es möglich, uns die funktion zur verfügung zu stellen?

ich habe das makro von der oben genannten französischen seite. aber seit nem bestimmten office update, geht eine funktion darin nicht mehr. das ist von MS offiziell so bestätigt.

vielen dank!!!!
Thomas Ramel
Microsoft Excel-MVP


Verfasst am:
14. Jul 2009, 20:43
Rufname: Thom
Wohnort: Glashütten - CH

AW: Code 128 (Barcode) TrueTypeFont Freeware - AW: Code 128 (Barcode) TrueTypeFont Freeware

Nach oben
       Version: Office XP (2002)

Grüezi Gast

Hmmm, das ist etwas schwer zu beurteilen, ob das nicht mehr klappt und seit wann.

Kannst Du uns da bitte nähere Informationen und Links liefern?


Eine Möglichkeit wäre es, das Update wieder zu entfernen.

Ansonsten bin ich nicht so sicher wie Du denkst, dass wir dir weiterhelfen könnten....


Vielleicht kannst Du ja mit dem folgenden Link noch etwas mehr anfangen, da gibt es sogar ein AddIn für Excel:

http://freebarcodefonts.dobsonsw.com/

_________________
Mit freundlichen Grüssen

Thomas Ramel
[Vista Ultimate SP-1 / xl2007 SP-2]
Gast



Verfasst am:
15. Jul 2009, 17:26
Rufname:

AW: Code 128 (Barcode) TrueTypeFont Freeware - AW: Code 128 (Barcode) TrueTypeFont Freeware

Nach oben
       Version: Office XP (2002)

hallo thomas,

danke.

update entfernen geht nicht.. ich weiss nicht welches. unsere systeme updaten sich automatisch.

diese funktion geht nicht mehr: Mid$

hier das makro:


Code:


Public Function code128$(chaine$)
  'Cette fonction est régie par la Licence Générale Publique Amoindrie GNU (GNU LGPL)
  'This function is governed by the GNU Lesser General Public License (GNU LGPL)
  'V 2.0.0
  'Paramètres : une chaine
  'Parameters : a string
  'Retour : * une chaine qui, affichée avec la police CODE128.TTF, donne le code barre
  '         * une chaine vide si paramètre fourni incorrect
  'Return : * a string which give the bar code when it is dispayed with CODE128.TTF font
  '         * an empty string if the supplied parameter is no good
  Dim i%, checksum&, mini%, dummy%, tableB As Boolean
  code128$ = ""
  If Len(chaine$) > 0 Then
  'Vérifier si caractères valides
  'Check for valid characters
    For i% = 1 To Len(chaine$)
      Select Case Asc(Mid$(chaine$, i%, 1))
      Case 32 To 126, 203
      Case Else
        i% = 0
        Exit For
      End Select
    Next
    'Calculer la chaine de code en optimisant l'usage des tables B et C
    'Calculation of the code string with optimized use of tables B and C
    code128$ = ""
    tableB = True
    If i% > 0 Then
      i% = 1 'i% devient l'index sur la chaine / i% become the string index
      Do While i% <= Len(chaine$)
        If tableB Then
          'Voir si intéressant de passer en table C / See if interesting to switch to table C
          'Oui pour 4 chiffres au début ou à la fin, sinon pour 6 chiffres / yes for 4 digits at start or end, else if 6 digits
          mini% = IIf(i% = 1 Or i% + 3 = Len(chaine$), 4, 6)
          GoSub testnum
          If mini% < 0 Then 'Choix table C / Choice of table C
            If i% = 1 Then 'Débuter sur table C / Starting with table C
              code128$ = Chr$(210)
            Else 'Commuter sur table C / Switch to table C
              code128$ = code128$ & Chr$(204)
            End If
            tableB = False
          Else
            If i% = 1 Then code128$ = Chr$(209) 'Débuter sur table B / Starting with table B
          End If
        End If
        If Not tableB Then
          'On est sur la table C, essayer de traiter 2 chiffres / We are on table C, try to process 2 digits
          mini% = 2
          GoSub testnum
          If mini% < 0 Then 'OK pour 2 chiffres, les traiter / OK for 2 digits, process it
            dummy% = Val(Mid$(chaine$, i%, 2))
            dummy% = IIf(dummy% < 95, dummy% + 32, dummy% + 105)
            code128$ = code128$ & Chr$(dummy%)
            i% = i% + 2
          Else 'On n'a pas 2 chiffres, repasser en table B / We haven't 2 digits, switch to table B
            code128$ = code128$ & Chr$(205)
            tableB = True
          End If
        End If
        If tableB Then
          'Traiter 1 caractère en table B / Process 1 digit with table B
          code128$ = code128$ & Mid$(chaine$, i%, 1)
          i% = i% + 1
        End If
      Loop
      'Calcul de la clé de contrôle / Calculation of the checksum
      For i% = 1 To Len(code128$)
        dummy% = Asc(Mid$(code128$, i%, 1))
        dummy% = IIf(dummy% < 127, dummy% - 32, dummy% - 105)
        If i% = 1 Then checksum& = dummy%
        checksum& = (checksum& + (i% - 1) * dummy%) Mod 103
      Next
      'Calcul du code ASCII de la clé / Calculation of the checksum ASCII code
      checksum& = IIf(checksum& < 95, checksum& + 32, checksum& + 105)
      'Ajout de la clé et du STOP / Add the checksum and the STOP
      code128$ = code128$ & Chr$(checksum&) & Chr$(211)
    End If
  End If
  Exit Function
testnum:
  'si les mini% caractères à partir de i% sont numériques, alors mini%=0
  'if the mini% characters from i% are numeric, then mini%=0
  mini% = mini% - 1
  If i% + mini% <= Len(chaine$) Then
    Do While mini% >= 0
      If Asc(Mid$(chaine$, i% + mini%, 1)) < 48 Or Asc(Mid$(chaine$, i% + mini%, 1)) > 57 Then Exit Do
      mini% = mini% - 1
    Loop
  End If
Return
End Function




viele grüße
sascha
Gast



Verfasst am:
20. Jul 2009, 13:49
Rufname:

AW: Code 128 (Barcode) TrueTypeFont Freeware - AW: Code 128 (Barcode) TrueTypeFont Freeware

Nach oben
       Version: Office XP (2002)

lösung:

VBA. vor Mid$ schreiben
Thomas Ramel
Microsoft Excel-MVP


Verfasst am:
20. Jul 2009, 16:11
Rufname: Thom
Wohnort: Glashütten - CH

AW: Code 128 (Barcode) TrueTypeFont Freeware - AW: Code 128 (Barcode) TrueTypeFont Freeware

Nach oben
       Version: Office XP (2002)

Grüezi Gast

Oder noch besser, das Übel gleich an der Wurzel packen und im VBA-Editor unter Extras/Verweise aufräumen - dort gibt es mit Sicherheit solche, die mit 'NICHT GEFUNDEN' markiert sind.
Lösche diese und prüfe dann die funktionen des Codes nochmal.

_________________
Mit freundlichen Grüssen

Thomas Ramel
[Vista Ultimate SP-1 / xl2007 SP-2]
Gast



Verfasst am:
24. Jan 2014, 13:32
Rufname:

AW: Code 128 (Barcode) TrueTypeFont Freeware - AW: Code 128 (Barcode) TrueTypeFont Freeware

Nach oben
       Version: Office XP (2002)

Ich habe den code der französischen Seite so angepasst das er mit dem Font von der Seite http://www.zoll.de/DE/Fachthemen/Zoelle/ATLAS/ATLAS-Publikationen/Sonstiges/sonstiges.html funktioniert
Vielleicht kann es ja jemand brauchen.
LG,

Public Function code128$(chaine$)
'This function is governed by the GNU Lesser General Public License (GNU LGPL)
'V 2.0.0
'Parameters : a string
'Return : * a string which give the bar code when it is dispayed with CODE128.TTF font
' * an empty string if the supplied parameter is no good
'Adapted to work with the font from the webpage: http://www.zoll.de/DE/Fachthemen/Zoelle/ATLAS/ATLAS-Publikationen/Sonstiges/sonstiges.html

Dim i%, checksum&, mini%, dummy%, tableB As Boolean
code128$ = ""
If Len(chaine$) > 0 Then
'Check for valid characters
For i% = 1 To Len(chaine$)
Select Case Asc(Mid$(chaine$, i%, 1))
Case 33 To 126, 223
Case 32
chaine$ = Replace(chaine$, " ", "ß")
Case Else
i% = 0
Exit For
End Select
Next
'Calculation of the code string with optimized use of tables B and C
code128$ = ""
tableB = True
If i% > 0 Then
i% = 1 'i% become the string index
Do While i% <= Len(chaine$)
If tableB Then
'See if interesting to switch to table C
'yes for 4 digits at start or end, else if 6 digits
mini% = IIf(i% = 1 Or i% + 3 = Len(chaine$), 4, 6)
GoSub testnum
If mini% < 0 Then 'Choice of table C
If i% = 1 Then 'Starting with table C
code128$ = Chr$(194)
Else 'Switch to table C
code128$ = code128$ & Chr$(196)
End If
tableB = False
Else
If i% = 1 Then code128$ = Chr$(193) 'Starting with table B
End If
End If
If Not tableB Then
'We are on table C, try to process 2 digits
mini% = 2
GoSub testnum
If mini% < 0 Then 'OK for 2 digits, process it
dummy% = Val(Mid$(chaine$, i%, 2))
Select Case Val(Mid$(chaine$, i%, 2))
Case 0
dummy% = dummy% + 223
Case 1 To 94
dummy% = dummy% + 32
Case 95
dummy% = dummy% + 85
Case 96
dummy% = dummy% + 132
Case 97
dummy% = dummy% + 149
Case 98
dummy% = dummy% + 154
Case 99
dummy% = dummy% + 97
End Select
code128$ = code128$ & Chr$(dummy%)
i% = i% + 2
Else 'We haven't2 digits, switch to table B
code128$ = code128$ & Chr$(214)
tableB = True
End If
End If
If tableB Then
'Process 1 digit with table B
code128$ = code128$ & Mid$(chaine$, i%, 1)
i% = i% + 1
End If
Loop
'Calculation of the checksum
For i% = 1 To Len(code128$)
dummy% = Asc(Mid$(code128$, i%, 1))
Select Case Asc(Mid$(code128$, i%, 1))
Case Is < 127
dummy% = dummy% - 32
Case 191 To 195
dummy% = dummy% - 89
Case 196
dummy% = dummy% - 97
Case 223
dummy% = dummy% - 223
Case 214
dummy% = dummy% - 114
Case 180
dummy% = dummy% - 85
Case 228
dummy% = dummy% - 132
Case 252
dummy% = dummy% - 154
Case 246
dummy% = dummy% - 149

End Select
If i% = 1 Then checksum& = dummy%
checksum& = (checksum& + (i% - 1) * dummy%) Mod 103
Next
'Calculation of the checksum ASCII code
Select Case checksum&
Case 1 To 94
checksum& = checksum& + 32
Case 96
checksum& = checksum& + 132
Case 97
checksum& = checksum& + 149
Case 98
checksum& = checksum& + 154
Case 99
checksum& = checksum& + 97
Case 100
checksum& = checksum& + 114
Case 101
checksum& = checksum& + 119
Case 102
checksum& = checksum& + 79
Case 0
checksum& = checksum& + 223
Case 95
checksum& = checksum& + 85
End Select
'Add the checksum and the STOP
code128$ = code128$ & Chr$(checksum&) & Chr$(200)
End If
End If
Exit Function
testnum:
'if the mini% characters from i% are numeric, then mini%=0
mini% = mini% - 1
If i% + mini% <= Len(chaine$) Then
Do While mini% >= 0
If Asc(Mid$(chaine$, i% + mini%, 1)) < 48 Or Asc(Mid$(chaine$, i% + mini%, 1)) > 57 Then Exit Do
mini% = mini% - 1
Loop
End If
Return
End Function
Gast



Verfasst am:
24. Jan 2014, 22:01
Rufname:

AW: Code 128 (Barcode) TrueTypeFont Freeware - AW: Code 128 (Barcode) TrueTypeFont Freeware

Nach oben
       Version: Office XP (2002)

Dich schickt der Himmel genau das hab ich diese Woche gesucht Very Happy
OfficeR83
bei deiner Freundin im Schrank


Verfasst am:
27. Jan 2014, 13:37
Rufname: Sam
Wohnort: Göttingen (NDS)


AW: Code 128 (Barcode) TrueTypeFont Freeware - AW: Code 128 (Barcode) TrueTypeFont Freeware

Nach oben
       Version: Office XP (2002)

hallo,

brauchst beu google doch nur folgendes eingeben:

free font barcode

dann bekommste zb auf myfont.com da ist auch dein code128

oder weitre seiten wie:

barcodesinc.com
dafont.com
schriftenkostenlos.eu

usw.

bei programmen und macros von unbekannten seiten wäre ich vorsichtig. besser nur die fonts alleine.

_________________
Gruß
OfficeR
Neues Thema eröffnen   Neue Antwort erstellen Alle Zeiten sind
GMT + 1 Stunde

Diese Seite Freunden empfehlen

Seite 1 von 1
Gehe zu:  
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum nicht posten
Du kannst Dateien in diesem Forum herunterladen

Verwandte Themen
Forum / Themen   Antworten   Autor   Aufrufe   Letzter Beitrag 
Keine neuen Beiträge Excel Formeln: Code für Tabellenblatt zur VBA Aktivierung 2 Harald_Hamburg 101 09. Nov 2013, 16:11
Harald_Hamburg Code für Tabellenblatt zur VBA Aktivierung
Keine neuen Beiträge Excel Formate: Aus 10-stelligem Code 5 Stellen loeschen? 2 hesteketi 91 02. Sep 2013, 16:50
hesteketi Aus 10-stelligem Code 5 Stellen loeschen?
Keine neuen Beiträge Excel Formeln: Makro Code/ Belohung PSC 1 ShadowTwinBlade 94 08. Jul 2013, 11:06
Alterweg Makro Code/ Belohung PSC
Keine neuen Beiträge Excel Formate: Barcode erzeugen mit Excel 1 weisshuhn 1973 14. Apr 2013, 03:45
hddiesel Barcode erzeugen mit Excel
Keine neuen Beiträge Excel Formeln: Werte (nach code soriert) aus verschiedenen Tabs addieren 4 Phil90 106 18. März 2013, 13:53
Phil90 Werte (nach code soriert) aus verschiedenen Tabs addieren
Keine neuen Beiträge Excel Formeln: Code für kallenderwoche 20 Eins5und60 291 17. März 2013, 17:36
< Peter > Code für kallenderwoche
Dieses Thema ist gesperrt, du kannst keine Beiträge editieren oder beantworten. Excel Formeln: Wenn 1-28 dann wert aus g5-g33 3 TommyDog16121973 190 06. Feb 2012, 22:10
< Peter > Wenn 1-28 dann wert aus g5-g33
Keine neuen Beiträge Excel Formeln: Worksheet.Function.Average bei Variablen im VBA Code 0 Jwk 1211 23. Jan 2011, 15:47
Jwk Worksheet.Function.Average bei Variablen im VBA Code
Dieses Thema ist gesperrt, du kannst keine Beiträge editieren oder beantworten. Excel Formeln: Farbumschlag über Code (ALT+11) formatieren 2 Viper85 897 24. Sep 2010, 08:33
Thomas Ramel Farbumschlag über Code (ALT+11) formatieren
Keine neuen Beiträge Excel Formeln: CODE Sammlung 5 charlybrown 1863 08. Dez 2008, 03:35
charlybrown CODE Sammlung
Keine neuen Beiträge Excel Formeln: bestimmten code suchen 4 Gast 296 06. Dez 2008, 14:50
Gast bestimmten code suchen
Keine neuen Beiträge Excel Formeln: EAN Barcode lesen mit Sverweis 9 chrisbln 4160 11. Aug 2008, 17:12
chrisbln EAN Barcode  lesen mit Sverweis
 

----> Diese Seite Freunden empfehlen <------ Impressum - Besuchen Sie auch: Microsoft-Excel Diagramme